home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / CLIPPER / MISC / EMXLIB8F.ZIP / EMX / LIB / STR / BCOPY.S < prev    next >
Encoding:
Text File  |  1993-01-02  |  1.3 KB  |  61 lines
  1. / bcopy.s (emx+gcc) -- Copyright (c) 1990-1993 by Eberhard Mattes
  2.  
  3.         .globl _bcopy
  4.  
  5. / void bcopy (const void *s1, void *s2, size_t n)
  6. / {
  7. /   size_t i;
  8. / 
  9. /   if ((size_t)s1 < (size_t)s2)
  10. /     for (i = n; i > 0; --i)
  11. /       ((char *)s2)[i-1] = ((char *)s1)[i-1];
  12. /   else
  13. /     for (i = 0; i < n; ++i)
  14. /       ((char *)s2)[i] = ((char *)s1)[i];
  15. / }
  16.  
  17. / assumes ds=es!
  18.  
  19.         .text
  20.  
  21.         .align  2, 0x90
  22.  
  23. _bcopy:
  24.         pushl   %esi
  25.         pushl   %edi
  26.         movl    3*4(%esp), %esi         / s1
  27.         movl    4*4(%esp), %edi         / s2
  28.         movl    5*4(%esp), %ecx         / n
  29.         jecxz   9f
  30.         cmpl    %edi, %esi
  31.         jb      2f
  32.         shrl    $2, %ecx
  33.         rep
  34.         movsl
  35.         movl    5*4(%esp), %ecx         / n
  36.         andl    $3, %ecx
  37.         rep
  38.         movsb
  39.         jmp     9f
  40.  
  41.         .align  2, 0x90
  42.  
  43. 2:      addl    %ecx, %esi
  44.         addl    %ecx, %edi
  45.         subl    $4, %esi
  46.         subl    $4, %edi
  47.         std
  48.         shrl    $2, %ecx
  49.         rep
  50.         movsl
  51.         addl    $3, %esi
  52.         addl    $3, %edi
  53.         movl    5*4(%esp), %ecx         / n
  54.         andl    $3, %ecx
  55.         rep
  56.         movsb
  57.         cld
  58. 9:      popl    %edi
  59.         popl    %esi
  60.         ret
  61.