home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / CLIPPER / MISC / BIPL.ZIP / PROCS.ZIP / POPEN.ICN < prev    next >
Encoding:
Text File  |  1993-01-27  |  2.0 KB  |  83 lines
  1. ########################################################################
  2. #    
  3. #    File:     popen.icn
  4. #    
  5. #    Subject:  Procedures for pipes
  6. #    
  7. #    Author:   Ronald Florence
  8. #
  9. #    Date:     September 28, 1992
  10. #
  11. ########################################################################
  12. #
  13. #    Version:  1.0
  14. #
  15. ###########################################################################
  16. #
  17. #  Contents:
  18. #
  19. #  popen(command, mode)
  20. #    mode == "w" writes to a pipe
  21. #    mode == "r" reads from a pipe
  22. #
  23. #  pclose(pipe)
  24. #
  25. #  On systems without real pipes (ms-dos), popen and pclose imitate
  26. #  pipes; pclose must be called after popen.  The code should run
  27. #  faster on ms-dos if dir in tempfile() points to a directory on a
  28. #  virtual disk.
  29. #
  30. #  On systems with real pipes, popen & pclose open and close a pipe.
  31. # 
  32. ##########################################################################
  33.  
  34. global PIPE_cmd, PIPE_fname
  35.  
  36. procedure popen(cmd, mode)
  37.   local tfn, p
  38.  
  39.   initial ("pipes" == &features) | {
  40.     PIPE_cmd := table()
  41.     PIPE_fname := table()
  42.   }
  43.   (type(PIPE_fname) ~== "table") & return open(cmd, mode || "p")
  44.   tfn := tempfile("pipe.")
  45.   upto('r', mode) & system(cmd || " > " || tfn)
  46.   p := open(tfn, mode)
  47.   PIPE_fname[p] := tfn
  48.   upto('w', mode) & PIPE_cmd[p] := cmd
  49.   return p
  50. end
  51.  
  52.  
  53. procedure pclose(pipe)
  54.   local status
  55.  
  56.   (type(PIPE_fname) ~== "table") & return close(pipe)
  57.   if \PIPE_cmd[pipe] then {
  58.     close(pipe) 
  59.     PIPE_cmd[pipe] ||:= " < " || PIPE_fname[pipe]
  60.     status := system(PIPE_cmd[pipe])
  61.   }
  62.   else status := close(pipe)
  63.   remove(PIPE_fname[pipe])
  64.   PIPE_cmd[pipe] := PIPE_fname[pipe] := &null
  65.   return status
  66. end
  67.  
  68.     # Richard Goerwitz's ever-useful generator.
  69.  
  70. procedure tempfile(template)
  71.   local temp_name
  72.   static dir
  73.  
  74.   initial {
  75.     if "UNIX" == &features then dir := "/tmp/"
  76.     else dir := ""
  77.   }
  78.   every temp_name := dir || template || right(1 to 999,3,"0") do {
  79.     close(open(temp_name)) & next
  80.     suspend \temp_name
  81.   }
  82. end
  83.