home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / CLIPPER / MISC / BIPL.ZIP / PROCS.ZIP / ANSI.ICN < prev    next >
Encoding:
Text File  |  1993-01-27  |  5.6 KB  |  213 lines
  1. ############################################################################ 
  2. # 
  3. #    File:     ansi.icn
  4. # 
  5. #    Subject:  Procedures for ANSI-based terminal control
  6. # 
  7. #    Author:   Ralph E. Griswold and Richard Goerwitz
  8. #
  9. #    Date:     February 8, 1992
  10. # 
  11. ########################################################################### 
  12. #
  13. #    Version:  1.4
  14. #
  15. ###########################################################################
  16. # 
  17. #     This package of procedures implements a subset of the ANSI terminal
  18. #  control sequences.  The names of the procedures are taken directly from
  19. #  the ANSI names.  If it is necessary to use these routines with non-ANSI
  20. #  devices, link in iolib.icn, and (optionally) iscreen.icn as well.  Use
  21. #  will be made of whatever routines are made available via either of these
  22. #  libraries.  Be careful of naming conflicts if you link in iscreen.icn.
  23. #  It contains procedures like "clear" and "boldface."
  24. #
  25. #     CUB(i)        Moves the cursor left i columns
  26. #     CUD(i)        Moves the cursor down i rows
  27. #     CUF(i)        Moves the cursor right i columns
  28. #     CUP(i,j)    Moves the cursor to row i, column j
  29. #     CUU(i)        Moves the cursor up i rows
  30. #     ED(i)        Erases screen: i = 0, cursor to end; i = 1,
  31. #               beginning to cursor; i = 2, all (default 2)
  32. #     EL(i)        Erases data in cursor row: i = 0, cursor to
  33. #               end; i = 1, beginning to cursor; i = 2, all
  34. #               (default 0)
  35. #     SGR(i)        Sets video attributes: 0 = off; 1 = bold; 4 =
  36. #               underscore; 5 = blink; 7 = reverse (default
  37. #               0)    
  38. #
  39. #     Note that not all so-called ANSI terminals support every ANSI
  40. #  screen control sequence - not even the limited subset included in
  41. #  this file.
  42. #
  43. #     If you plan on using these routines with non-ANSI magic-cookie
  44. #  terminals (e.g. a Wyse-50) then it is strongly recommended that you
  45. #  link in iolib or itlib *and* iscreen (not just iolib or itlib by
  46. #  itself).  The routines WILL WORK with most magic cookie terminals;
  47. #  they just don't always get all the modes displayed (because they
  48. #  are basically too busy erasing the cookies).
  49. #
  50. ############################################################################ 
  51. #
  52. # links: iolib or itlib, iscreen (all optional)
  53. #
  54. # see also: ansi.icn
  55. #
  56. ############################################################################ 
  57.  
  58. # For DOS, or any system using ANSI-conformant output devices, there
  59. # is no need to link any routines in.
  60.  
  61. # For UNIX systems, you may choose to link in itlib or iolib, and (if
  62. # desired) iscreen as well.  Some of these may be in the IPL.  You can
  63. # get any that aren't from Richard Goerwitz (goer@sophist.uchicago.edu).
  64.  
  65. # link iolib, iscreen
  66.  
  67. procedure _isANSI()
  68.     static isANSI
  69.     initial {
  70.     if find("MS-DOS",&features) then {
  71.         isANSI := 1
  72.     } else {
  73.         if proc(getname) then {
  74.         if find("ansi",map(getname())) | getname() == "li"
  75.         then isANSI := 1
  76.         else isANSI := &null
  77.         } else {
  78.         # We'll take a chance on the user knowing what he/she
  79.         # is doing.
  80.         isANSI := 1
  81.         # If you're not so confident, comment out the following
  82.         # line:
  83.         # stop("_isANSI:  you need to link itlib or iolib")
  84.         }
  85.     }
  86.     }
  87.     return \isANSI
  88. end
  89.  
  90. procedure CUD(i)
  91.     if _isANSI()
  92.     then writes("\^[[",i,"B")
  93.     else {
  94.     iputs(igoto(getval("DO"),i)) | {
  95.         every 1 to i do
  96.         iputs(getval("do")) | stop("CUD:  no do capability")
  97.     }
  98.     }
  99.     return
  100. end
  101.  
  102. procedure CUB(i)
  103.     if _isANSI()
  104.     then writes("\^[[",i,"D")
  105.     else {
  106.     iputs(igoto(getval("LE"),i)) | {
  107.         every 1 to i do
  108.         iputs(getval("le")) | stop("CUB:  no le capability")
  109.     }
  110.     }
  111.     return
  112. end
  113.  
  114. procedure CUF(i)
  115.     if _isANSI()
  116.     then writes("\^[[",i,"C")
  117.     else {
  118.     iputs(igoto(getval("RI"),i)) | {
  119.         every 1 to i do
  120.         iputs(getval("nd")) | stop("CUF:  no nd capability")
  121.     }
  122.     }
  123.     return
  124. end
  125.  
  126. procedure CUP(i,j)
  127.     if _isANSI()
  128.     then writes("\^[[",i,";",j,"H")
  129.     else iputs(igoto(getval("cm"), j, i)) | stop("CUP:  no cm capability")
  130.     return
  131. end
  132.  
  133. procedure CUU(i)
  134.     if _isANSI()
  135.     then writes("\^[[",i,"A")
  136.     else {
  137.     iputs(igoto(getval("UP"),i)) | {
  138.         every 1 to i do
  139.         iputs(getval("up")) | stop("CUU:  no up capability")
  140.     }
  141.     }
  142.     return
  143. end
  144.  
  145. procedure ED(i)
  146.     /i := 2
  147.     if _isANSI() then {
  148.     writes("\^[[",i,"J")
  149.     } else {
  150.     case i of {
  151.         0:  iputs(getval("cd")) | stop("ED:  no cd capability")
  152.         1:  stop("ED:  termcap doesn't specify capability")
  153.         2:  {
  154.         if proc(emphasize) then clear()
  155.         else iputs(getval("cl")) | stop("ED:  no cl capability")
  156.         }
  157.         default:  stop("ED:  unknown clear code, ",i)
  158.     }
  159.     }
  160.    return
  161. end
  162.  
  163. procedure EL(i)
  164.     /i := 0
  165.     if _isANSI() then {
  166.     if i = 0
  167.     then writes("\^[[K")
  168.     else writes("\^[[",i,"K")
  169.     } else {
  170.     case i of {
  171.         0:  iputs(getval("ce")) | stop("EL:  no ce capability")
  172.         1:  stop("EL:  termcap doesn't specify capability")
  173.         2:  stop("EL:  try using CUP to go to col 1, then EL(0)")
  174.         default:  stop("EL:  unknown line clear code, ",i)
  175.     }
  176.     }
  177.    return
  178. end
  179.  
  180. procedure SGR(i)
  181.  
  182.     static isISCR
  183.     initial {
  184.     if proc(emphasize)
  185.     then isISCR := 1
  186.     }
  187.  
  188.     /i := 0
  189.     if _isANSI() then {
  190.     writes("\^[[",i,"m")
  191.     } else {
  192.     case i of {
  193.         0: (\isISCR, normal()) | {
  194.         every iputs(getval("me"|"se"|"ue"))
  195.         }
  196.         1: (\isISCR, boldface()) | {
  197.         iputs(getval("md"|"so"|"us"))
  198.         }
  199.         4: (\isISCR, underline()) | {
  200.         iputs(getval("us"|"md"|"so"))
  201.         }
  202.         5: (\isISCR, blink()) | {
  203.         iputs(getval("mb"|"us"|"md"|"so"))
  204.         }
  205.         7: (\isISCR, emphasize()) | {
  206.         iputs(getval("so"|"md"|"us"))
  207.         }
  208.         default:  stop("SGR:  unknown mode, ",i)
  209.     }
  210.     }
  211.    return
  212. end
  213.