home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / CLIPPER / DATABASE / FOXDDE.ZIP / DDEWORD2.PRG < prev    next >
Encoding:
Text File  |  1993-04-16  |  3.7 KB  |  104 lines
  1. *                DDEWORD2.PRG
  2. * 
  3. * This simple program shows some more DDE basics.
  4. * It demonstrates some more resilient code for
  5. * starting a DDE conversation using DDESetOption, 
  6. * and shows the DDEExecute command being used 
  7. * with Word to open a file and insert text.
  8. * 
  9. * *************************************************
  10. * 
  11. * When initiating a DDE conversation, DDEInitiate
  12. * will try and start the server program if it is
  13. * not already running.  If you wish to suppress the
  14. * resulting message, you can turn it off using the
  15. * DDESetOption function.  Then you can use RUN to
  16. * start the program yourself.  The following code 
  17. * shows how you might do it:
  18.  
  19. = DDESetOption("SAFETY", .F.)
  20. channel = DDEInitiate("WinWord", "System")
  21. if channel = -1
  22.   exe = locfile("winword.exe", "exe", "Where is winword.exe?")
  23.   if exe == ""
  24.     wait window "Could not find winword.exe"
  25.     cancel
  26.   endif
  27.   RUN /N7 &exe
  28.   channel = DDEInitiate("WinWord", "System")
  29.   if channel = -1
  30.     wait window "DDE Error " + str(DDELastError())+" with Word"
  31.     cancel
  32.   endif
  33. endif
  34.  
  35. * Notice the use of the /N7 option on the RUN 
  36. * command.  This makes Word minimized and 
  37. * inactive.
  38. * 
  39. * Now that Word is running and we have a 
  40. * conversation established, we can send it commands
  41. * with the DDEExecute function.  Notice how the
  42. * topic we used was "System".  This is the topic
  43. * usually used when you wish to send commands to a 
  44. * server.
  45. * 
  46. * The exact commands permitted depend totally on
  47. * what the server supports.  Even the format of the
  48. * commands is server dependent.  Typically, 
  49. * however, the server will accept the same commands
  50. * that it allows in the programming language it may
  51. * support.  Word has a built in macro programming
  52. * language, and we can send commands to it by using
  53. * valid macro commands and surrounding them with 
  54. * square brackets, '[' and ']'.  For example, the
  55. * following will tell Word to open a given
  56. * file.  Notice that we use double quotes
  57. * to surround the file name.  Unlike FoxPro,
  58. * Word is very particular about which quotes you
  59. * use.  Only double quotes will work.  This means
  60. * therefore, that you need to use single quotes for
  61. * the strings that you're building.
  62.  
  63. file = sys(2003)+ "\" + "myfile.doc"
  64. cmd = '[FileOpen .name=' + '"' + file + '"]'
  65. ? "Cmd = " + cmd
  66.  
  67. ? DDEExecute(channel, cmd)
  68.  
  69. * Notice that you need to provide the full path
  70. * to the Word file.  You don't really know
  71. * what directory Word will have as its working
  72. * directory, so its easier to be sure.  Once we 
  73. * have the Word file open, we can establish a 
  74. * conversation with it.  After opening the channel
  75. * the following code will insert a bookmark, a 
  76. * field for the current date, and then some text.
  77. * (See the Word macro language online help for the
  78. * gory details of WordBasic)
  79.  
  80. myfilechan = DDEInitiate("WinWord", file)
  81. ? DDEExecute(myfilechan, '[insertbookmark .name="test"]')
  82. ? DDEExecute(myfilechan, '[insertfield .field="createdate \@ mm/dd/yy"]')
  83. ? DDEPoke(myfilechan, "test", "This is some text inserted on ")
  84. ? DDEExecute(myfilechan, "[insertpara]")
  85. WAIT WINDOW "Switch to Word to see the results..."
  86. ? DDEExecute(myfilechan, "[fileclose 2]")
  87.  
  88. ? DDETerminate(myfilechan)
  89.  
  90. * To tidy up, we can now send a command to Word
  91. * to tell it to close itself.  We could also close
  92. * individual files.  For exact details, see the
  93. * Word macro language manual.
  94.  
  95. ? DDEExecute(channel, "[FileExit]")
  96.  
  97. * Note that if we now try and close the channel
  98. * with DDETerminate, we'll get an error.  That is
  99. * ok, because we actually broke the channel when
  100. * we told Word to close.  DDELastError() confirms
  101. * that that is the problem.
  102.  
  103. ? DDETerminate(channel)
  104. ? "Error was: ", DDELastError()