home *** CD-ROM | disk | FTP | other *** search
/ Otherware / Otherware_1_SB_Development.iso / amiga / info / ioexpans.lzh / IOpatch / IOpatch.asm next >
Encoding:
Assembly Source File  |  1991-01-14  |  22.1 KB  |  966 lines
  1. *****************************************************************************
  2. * Program:  IOpatch.asm - ⌐1990 by Dan Babcock
  3. * Function: This program patches the exec OpenDevice call, and allows the
  4. *           user to select a serial or parallel unit.
  5. *
  6. * Author:   Dan Babcock
  7. * History:  02/07/90 DB V0.50 Created
  8. *           09/22/90 DB V0.51 Added code to prevent redundant requesters
  9. *                             in certain cases.
  10. *           12/10/90 JL V0.52 Added code to parse the command line, and
  11. *                             allow various arguments (outlined below).
  12. *           01/12/91 DB V0.53 Misc. enhancements
  13. *
  14. * [To all: Please don't forget to bump the revision numbers if you do *any*
  15. *          modifications at all.  -Jeff]
  16. *****************************************************************************
  17. * Program:  SelectWindow - ⌐1990 by The Puzzle Factory
  18. * Function: Get the users preference for which unit to open.
  19. *
  20. * Author:   Jeff Lavin
  21. * History:  01/29/90 JL V0.50 Created
  22. *           02/07/90 DB V0.51 Modified to include an "Internal" gadget.
  23. *           08/22/90 JL V0.52 Added borders to the gadgets.
  24. *                             Converted to Macro68 & new syntax.
  25. *           09/12/90 JL V0.53 Dynamically size everything now.
  26. *           09/26/90 JL V0.54 Fixed lores display problem.
  27. *           11/16/90 JL V0.55 Rearrainged gadgets; Gadget 0 is now full width.
  28. *
  29. * [To all: Please don't forget to bump the revision numbers if you do *any*
  30. *          modifications at all.  -Jeff]
  31. *****************************************************************************
  32.  
  33.  
  34. *****************************************************************************
  35. * NAME
  36. *     IOpatch - This program patches the exec OpenDevice call. The user
  37. *     puts this program in his startup-sequence or whereever before he runs
  38. *     his terminal progs, BBS's and whatnot - if these do not permit the
  39. *     user to change the device/unit info. If they do, this utility is not
  40. *     needed, obviously.
  41. *
  42. * INPUTS
  43. *
  44. *     1> IOpatch       ;Check OpenDevice() calls for serial & parallel device
  45. *     1> IOpatch -a    ;Check OpenDevice() calls for serial & parallel device
  46. *     1> IOpatch -s    ;Check OpenDevice() calls for serial device only
  47. *     1> IOpatch -p    ;Check OpenDevice() calls for parallel device only
  48. *     1> IOpatch -q    ;Replaces previous vector for OpenDevice() calls.
  49. *     1> IOpatch ?     ;Prints these instructions
  50. *
  51. * RESULTS
  52. *     OpenDevice() will use the either:
  53. *
  54. *          the serial.device or the newser.device
  55. *          the parallel.device or the eightbit.device
  56. *
  57. *     with the proper unit number depending on which device was to have been
  58. *     opened, and what the user selected from the requester.
  59. *
  60. * NOTES
  61. *     There is one complication: I noticed during testing that most term
  62. *     programs open and close the serial.device several times during their
  63. *     startup routines. This is rather stupid of them, of course, and it
  64. *     unfortunately results in many redundant requesters.
  65. *     This version tries its best to avoid this problem by keeping track of
  66. *     tasks that have opened the serial/parallel device and re-using
  67. *     previously specified (by the user via the requester) unit number.
  68. * 
  69. *     One last note: this program copies itself into dynamically allocated
  70. *     memory, so the user does not have to "run" it.
  71. *
  72. ******************************* tear here ***********************************
  73.  
  74. ;Set Tabs           |       |                 |       |
  75.  
  76.     ifnd    __m68
  77.     fail    'Wrong assembler!'
  78.     endc
  79.     exeobj
  80.     macfile    'Includes:IOexp.i'    ;The One & Only include file
  81.     objfile    'IOpatch'
  82.  
  83. TASKTABLESIZE    equ    32
  84.  
  85. Dispatcher    moveq    #-1,d2    ;serflag default
  86.     moveq    #-1,d3    ;parflag default
  87.     moveq    #0,d6    ;quit flag default
  88.     moveq    #0,d5    ;Clear WBenchMsg
  89.  
  90.     movea.l    (SysBase).w,a6
  91.     movea.l    (ThisTask,a6),a2
  92.     tst.l    (pr_CLI,a2)    ;Are we a child of WBench?
  93.     bne.b    FromCLI    ;Branch if no
  94.  
  95.     lea    (pr_MsgPort,a2),a0
  96.     SYS    WaitPort
  97.     lea    (pr_MsgPort,a2),a0
  98.     SYS    GetMsg
  99.     move.l    d0,d5    ;WBenchMsg
  100.     bra.w    SetPatch    ;No args from WBench
  101.  
  102. FromCLI    lea    (a0,d0.w),a1
  103. ..    cmpi.b    #' ',-(a1)    ;Eat trailing garbage
  104.     dbhi    d0,..
  105.     blt.b    SetPatch    ;If no arguments, don't parse
  106.     clr.b    (1,a1)    ;Null terminate the string
  107.  
  108. Parse    moveq    #0,d0
  109.     move.b    (a0)+,d0
  110.     beq.b    SetPatch    ;Null ends
  111.     cmpi.b    #' ',d0    ;Skip spaces
  112.     beq.b    Parse
  113.     cmpi.b    #'?',d0    ;Instruct?
  114.     beq.b    4$    ;"Usage:..."
  115.     cmpi.b    #'-',d0    ;Look for "-" char
  116.     bne.b    Parse    ;Skip til we find one
  117.     move.b    (a0)+,d0    ;Get next char
  118.     beq.b    SetPatch    ;Null ends
  119.     cmpi.b    #'a',d0    ;Convert to U/C
  120.     blo.s    1$
  121.     cmpi.b    #'z',d0
  122.     bhi.s    1$
  123.     subi.b    #$20,d0
  124.  
  125. 1$    cmpi.b    #'A',d0    ;[A]ll
  126.     bne.b    2$
  127.     seq    d2    ;serflag
  128.     seq    d3    ;parflag
  129.     bra.b    SetPatch
  130.  
  131. 2$    cmpi.b    #'S',d0    ;[S]erial only
  132.     bne.b    3$
  133.     seq    d2    ;serflag
  134.     sne    d3    ;parflag
  135.     bra.b    SetPatch
  136.  
  137. 3$    cmpi.b    #'P',d0    ;[P]arallel only
  138.     bne.b    4$
  139.     sne    d2    ;serflag
  140.     seq    d3    ;parflag
  141.     bra.b    SetPatch
  142.  
  143. 4$    cmpi.b    #'Q',d0    ;[Q]uit
  144.     bne.w    Instruct
  145.     seq    d6    ;quit flag
  146.  
  147. ;Note that multitasking is disabled (via Forbid) throughout the install
  148. ;code for 100% safety.
  149. ;First, check to see whether this program has been run before.
  150.  
  151. SetPatch    lea    (serflag,pc),a0
  152.     move.b    d2,(a0)
  153.     lea    (parflag,pc),a0
  154.     move.b    d3,(a0)
  155.  
  156.     movea.l    (SysBase).w,a6
  157.     SYS    Forbid
  158.  
  159.     lea    (portname,pc),a1
  160.     SYS    FindPort
  161.     move.l    d0,d2
  162.     tst.l    d2
  163.     bne.b    installed    ;Go if already installed
  164.  
  165. ;Not installed, so allocate memory and copy
  166.  
  167.     move.l    #enddispatchcode-startdispatchcode,d7
  168.     move.l    d7,d0
  169.     moveq    #0,d1    ;No special attributes
  170.     SYS    AllocMem
  171.     tst.l    d0
  172.     bne.b    allocok
  173.  
  174. panic    tst.l    d5    ;WBenchMsg
  175.     beq.b    1$
  176.     movea.l    d5,a1    ;We're already forbidden
  177.     SYS    ReplyMsg    ;Return msg
  178.     bra.b    2$
  179.  
  180. 1$    SYS    Permit
  181. 2$    moveq    #-1,d0
  182.     rts
  183.  
  184. allocok    movea.l    d0,a5
  185.     movea.l    d0,a1
  186.     lea    (startdispatchcode,pc),a0
  187.     move.l    d7,d0
  188.     SYS    CopyMem
  189.     lea    (panic,pc),a4
  190.     jmp    (a5)    ;Go to startdispatchcode
  191.  
  192. installed    tst.b    d6    ;Go if already installed
  193.     beq.b    quitdispatch    ;& quit flag set
  194.  
  195. ;Remove the patch (port addr in d2)
  196.  
  197.     movea.l    d2,a2
  198.     movea.l    (MP_SIZE,a2),a3    ;Get start addr of res code
  199.     lea    (newopendevice-startdispatchcode,a3),a4 ;Get addr of replacement
  200.     cmpa.l    (_LVOOpenDevice+2,a6),a4 ;Still there?
  201.     bne.b    panic    ;No, so can't deinstall
  202.     lea    (newremtask-startdispatchcode,a3),a4 ;Get addr of replacement
  203.     cmpa.l    (_LVORemTask+2,a6),a4 ;Still there?
  204.     bne.b    panic    ;No, so can't deinstall
  205.  
  206.     move.l    (oldopenvec-startdispatchcode,a3),d0
  207.     movea.w    #_LVOOpenDevice,a0
  208.     movea.l    a6,a1
  209.     SYS    SetFunction
  210.  
  211.     move.l    (oldremtask-startdispatchcode,a3),d0
  212.     movea.w    #_LVORemTask,a0
  213.     movea.l    a6,a1
  214.     SYS    SetFunction
  215.  
  216.     movea.l    a2,a1    ;Deallocate memory etc.
  217.     SYS    RemPort
  218.  
  219.     moveq    #MP_SIZE+4,d0
  220.     movea.l    a2,a1
  221.     SYS    FreeMem    ;Free message port
  222.  
  223.     move.l    #enddispatchcode-startdispatchcode,d0
  224.     movea.l    a3,a1
  225.     SYS    FreeMem    ;Free the code
  226.  
  227. quitdispatch    tst.l    d5    ;WBenchMsg
  228.     beq.b    1$
  229.     movea.l    d5,a1    ;We're already forbidden
  230.     SYS    ReplyMsg    ;Return msg
  231.     bra.b    2$
  232.  
  233. 1$    SYS    Permit
  234. 2$    moveq    #0,d0
  235.     rts
  236.  
  237. Instruct    tst.l    d5    ;WBenchMsg
  238.     beq.b    .OpenDos
  239.     addq.b    #1,(TDNestCnt,a6)    ;Forbid so WBench won't
  240.     movea.l    d5,a1    ; UnloadSeg() us
  241.     SYS    ReplyMsg    ;Return msg
  242.     bra.b    .Exit
  243.  
  244. .OpenDos    lea    (DosName,pc),a1
  245.     moveq    #0,d0
  246.     SYS    OpenLibrary    ;Open dos.library
  247.     tst.l    d0
  248.     beq.b    .Exit    ;Failed!
  249.  
  250.     move.l    a6,-(sp)
  251.     movea.l    d0,a6
  252.     SYS    Output    ;Get output filehandle
  253.     move.l    d0,d1    ;Filehandle
  254.     beq.b    .CloseDos
  255.     lea    (Help.msg,pc),a0
  256.     move.l    a0,d2    ;Buffer
  257.     move.l    #Help_Len,d3    ;Length
  258.     SYS    Write    ;Help the user
  259.  
  260. .CloseDos    movea.l    a6,a1
  261.     movea.l    (sp)+,a6
  262.     SYS    CloseLibrary    ;Close the dos.library
  263. .Exit    moveq    #0,d0
  264.     rts
  265.  
  266.  
  267. ;***** All the following code is copied into dynamically allocated mem
  268.  
  269. ;Add a port to indicate that we're installed
  270. ;Allocate memory for the port
  271.  
  272. startdispatchcode    moveq    #MP_SIZE+4,d0    ;MsgPort+4 bytes of private info
  273.     moveq    #1,d1
  274.     swap    d1    ;CLEAR parm
  275.     SYS    AllocMem
  276.     tst.l    d0
  277.     bne.b    somememleft
  278.  
  279.     move.l    d7,d0    ;Uh oh. The poor user is out of memory.
  280.     move.l    a4,-(sp)    ;Return addr
  281.     movea.l    a5,a1
  282.     jmp    (_LVOFreeMem,a6)    ;RTS takes us back to 'panic'
  283.  
  284. somememleft    movea.l    d0,a1
  285.     lea    (portname,pc),a0
  286.     move.l    a0,(LN_NAME,a1) 
  287.     move.l    a5,(MP_SIZE,a1)    ;Private info - addr of res code 
  288.     SYS    AddPort
  289.  
  290.     movea.w    #_LVOOpenDevice,a0 ;Patch into OpenDevice
  291.     movea.l    a6,a1
  292.     lea    (newopendevice,pc),a2
  293.     move.l    a2,d0
  294.     SYS    SetFunction
  295.  
  296.     lea    (oldopenvec,pc),a0
  297.     move.l    d0,(a0)
  298.  
  299.     movea.w    #_LVORemTask,a0 ;Patch into RemTask
  300.     movea.l    a6,a1
  301.     lea    (newremtask,pc),a2
  302.     move.l    a2,d0
  303.     SYS    SetFunction
  304.     lea    (oldremtask,pc),a0
  305.     move.l    d0,(a0)
  306.  
  307.     tst.l    d5    ;WBenchMsg
  308.     beq.b    1$
  309.     movea.l    d5,a1    ;We're already forbidden
  310.     SYS    ReplyMsg    ;Return msg
  311.     bra.b    2$
  312.  
  313. 1$    SYS    Permit 
  314. 2$    moveq    #0,d0
  315.     rts
  316.  
  317.  
  318. ;*** NOTE: A zero TCB (in A1) indicates self removal !!!!
  319. ;(this little fact nearly drove me nuts during debugging!)
  320.  
  321. newremtask:
  322.     move.l    a1,d0
  323.     bne.b    .L2
  324.     move.l    a1,-(sp)
  325.     SYS    FindTask
  326.     movea.l    (sp)+,a1
  327. .L2    move.l    a1,-(sp)
  328.     SYS    Forbid
  329.     movea.l    (sp)+,a1
  330.  
  331.     moveq    #TASKTABLESIZE-1,d1
  332.     lea    (sertasklist,pc),a0
  333. ..    cmp.l    (a0)+,d0
  334.     addq.l    #2,a0
  335.     dbeq    d1,..
  336.     bne.b    .L1
  337.     clr.l    (-6,a0)
  338. .L1
  339.  
  340.     moveq    #TASKTABLESIZE-1,d1
  341.     lea    (partasklist,pc),a0
  342. ..    cmp.l    (a0)+,d0
  343.     addq.l    #2,a0
  344.     dbeq    d1,..
  345.     bne.b    .L3
  346.     clr.l    (-6,a0)
  347. .L3
  348.  
  349.     move.l    a1,-(sp)
  350.     SYS    Permit
  351.     movea.l    (sp)+,a1
  352.     movea.l    (oldremtask,pc),a0
  353.     jmp    (a0)
  354.  
  355. newopendevice    movem.l d6-d7/a2-a5,-(sp)
  356.     suba.l    a5,a5    ;Sanity check
  357.     tst.l    d0    ;Check unit number
  358.     bne    oldopenjump    ;If nonzero, skip menu
  359.     lea    (serunitexists,pc),a4
  360.     lea    (serflag,pc),a2
  361.     tst.b    (a2)+    ;Want to check serial device?
  362.     beq.b    1$    ;Branch if no
  363.     movea.l    a0,a3
  364. ..    cmpm.b    (a2)+,(a3)+
  365.     bne.b    1$
  366.     tst.b    (-1,a2)
  367.     bne.b    ..
  368.     lea    (newserialname,pc),a5
  369.     moveq    #0,d5
  370.     bra.b    2$
  371.  
  372. 1$    lea    (parflag,pc),a2
  373.     tst.b    (a2)+    ;Want to check parallel device?
  374.     beq.b    2$    ;Branch if no
  375.     movea.l    a0,a3
  376. ..    cmpm.b    (a2)+,(a3)+
  377.     bne.w    nogood
  378.     tst.b    (-1,a2)
  379.     bne.b    ..
  380.     lea    (newparallelname,pc),a5
  381.     moveq    #1,d5
  382.     addq.w    #4,a4    ;Point to parunitexists
  383.  
  384. ;One last check: if this task has previously opened either the serial.device
  385. ;or the parallel.device, use the same unit number (stored in tasklist) rather
  386. ;than bothering the user.
  387.  
  388. 2$    cmpa.l    #0,a5    ;Sanity check
  389.     beq    nogood    ;User has disabled both flags!
  390.  
  391.     movem.l    d0/d1/a0/a1,-(sp)
  392.     move.l    (ThisTask,a6),d6
  393.     SYS    Forbid
  394.     moveq    #15,d7
  395.     lea    (sertasklist,pc),a2
  396.     tst.l    d5
  397.     beq.b    .skippar
  398.     lea    (partasklist,pc),a2
  399. .skippar:
  400. ..    cmp.l    (a2)+,d6    
  401.     addq.l    #2,a2
  402.     dbeq    d7,..
  403.     bne.b    popup
  404.     SYS    Permit
  405.     movem.l    (sp)+,d0/d1/a0/a1
  406.     moveq    #0,d0
  407.     move.w    (-2,a2),d0
  408.     bra.b    skipmenu
  409.  
  410. popup    SYS    Permit
  411.     movem.l    (sp)+,d0/d1/a0/a1
  412.  
  413. ;pop up a menu
  414.  
  415.     move.l    (a4),d0    ;serunitexists/parunitexists
  416.     movem.l    d1-d7/a0-a6,-(sp)
  417.     bsr    SelWin    ;Get input from the user
  418.     movem.l    (sp)+,d1-d7/a0-a6
  419.     tst.l    d0    ;Ok?
  420.     bpl.b    contdisp
  421.  
  422. ;The user is out of memory; signal an error
  423.  
  424.     moveq    #-1,d0 
  425.     move.b    d0,(IO_ERROR,a1)    ;Set error in the IO Request
  426.     bra.b    endnewopen
  427.  
  428. contdisp:
  429.  
  430. ;store the TCB ptr and the unit# in tasklist for future use
  431.  
  432. ;search for an empty slot
  433.     movem.l    d0/d1/a0/a1,-(sp)
  434.     SYS    Forbid
  435.     lea    (sertasklist,pc),a2
  436.     tst.l    d5
  437.     beq.b    .skippar
  438.     lea    (partasklist,pc),a2
  439. .skippar:
  440.     moveq    #TASKTABLESIZE-1,d7
  441. ..    tst.l    (a2)+
  442.     addq.w    #2,a2
  443.     dbeq    d7,..
  444.     bne.b    oldtask    ;Full! (not likely to happen)
  445.     SYS    Permit
  446.     movem.l    (sp)+,d0/d1/a0/a1
  447.     move.l    d6,(-6,a2)
  448.     move.w    d0,(-2,a2)    
  449.     bra.b    skipmenu
  450. oldtask:
  451.     SYS    Permit
  452.     movem.l    (sp)+,d0/d1/a0/a1
  453.  
  454. skipmenu:
  455.     tst.l    d0
  456.     beq.b    oldopenjump    ;If zero, use std device
  457.     subq.l    #1,d0
  458.  
  459. oldtask1    movea.l    a5,a0    ;newserialname/newparallelname
  460. nogood 
  461. oldopenjump    movea.l    (oldopenvec,pc),a3
  462.     jsr    (a3)
  463. endnewopen    movem.l    (sp)+,d6-d7/a2-a5
  464.     rts
  465.  
  466. oldopenvec    dl    0 
  467. oldremtask    dl    0
  468.  
  469. ;These variables should be set by the code that checks for the presence
  470. ;of units 3 and 4.  Right now, they're hard-coded to say that they exist.
  471.  
  472. serunitexists    dl    1
  473. parunitexists    dl    1
  474.  
  475. ;Note: TASKTABLESIZE entries, arranged like so:
  476. ;Ptr to TCB (longword)
  477. ;Unit number (word)
  478.  
  479. sertasklist:
  480.     dcb.l    TASKTABLESIZE,0
  481.     dcb.w    TASKTABLESIZE,0
  482. partasklist:
  483.     dcb.l    TASKTABLESIZE,0
  484.     dcb.w    TASKTABLESIZE,0
  485.  
  486. portname    cstr    'IOExp dispatcher V1.10 ⌐1990 by Dan Babcock *INSTALLED*'
  487. serflag    db    $FF    ;Default = ON
  488. oldserialname    cstr    'serial.device'
  489. newserialname    MYDEVNAME
  490. parflag    db    $FF    ;Default = ON
  491. oldparallelname    cstr    'parallel.device'
  492. newparallelname    PARDEVNAME
  493. DosName    cstr    'dos.library'
  494.  
  495. Help.msg    db    'I/O Expansion Dispatcher V1.10 ⌐1990 by Dan Babcock',10
  496.     db    'Usage:',10,10
  497.     db    ' IOpatch     ;Check OpenDevice() calls for serial & parallel device',10
  498.     db    ' IOpatch -a  ;Check OpenDevice() calls for serial & parallel device',10
  499.     db    ' IOpatch -s  ;Check OpenDevice() calls for serial device only',10
  500.     db    ' IOpatch -p  ;Check OpenDevice() calls for parallel device only',10
  501.     db    ' IOpatch -q  ;Replaces previous vector for OpenDevice() calls.',10
  502.     db    ' IOpatch ?   ;Prints these instructions',10,0
  503. Help_Len    equ    *-Help.msg
  504.     quad
  505.  
  506. *****************************************************************************
  507. * NAME
  508. *     SelectWindow - Get the users preference for which unit to open.
  509. *
  510. * SYNOPSIS
  511. *     SelectWindow (UnitExits)
  512. *          D0          D0
  513. *
  514. *     LONG  UnitExists;
  515. *
  516. * INPUTS
  517. *     UnitExists - Non-zero if units 2 and 3 exist, else 0.
  518. *
  519. * RESULTS
  520. *     A value of 0 if the user didn't select a unit and simply hit the close
  521. *     gadget (unit number then defaults to 0).
  522. *
  523. * -> A value of zero is also returned if the user selects the "Internal"
  524. * -> gadget, indicating that he wants to use "serial.device" rather than
  525. * -> "newser.device", or "parallel.device" rather than "eightbit.device".
  526. *
  527. *     A value of 1-4 is returned if the user has selected a unit.
  528. *     A return value of -1 indicates that an error has occured.
  529. *
  530. * NOTES
  531. *     SelectWindow is both relocatable, and reentrant.
  532. *     SelectWindow is Copyright ⌐1990 by The Puzzle Factory
  533. *
  534. ******************************* tear here ***********************************
  535.  
  536. MyFeatures    equ    SMART_REFRESH!NOCAREREFRESH!ACTIVATE
  537. MyGadgets    equ    WINDOWDRAG!WINDOWDEPTH!WINDOWCLOSE
  538.  
  539. MyBase    clrso        ;BSS structure
  540. Gfx_Base    so.l    1
  541. Int_Base    so.l    1
  542. FontPtr    so.l    1
  543. ScreenPtr    so.l    1
  544. HiresFlag    so.b    1
  545. LaceFlag    so.b    1
  546. MyWindow    so.b    nw_SIZE
  547. Gadget0    so.b    gg_SIZEOF
  548. Gadget1    so.b    gg_SIZEOF
  549. Gadget2    so.b    gg_SIZEOF
  550. Gadget3    so.b    gg_SIZEOF
  551. Gadget4    so.b    gg_SIZEOF
  552.  
  553. Gad0.ITxt    so.b    it_SIZEOF
  554. Gad1.ITxt    so.b    it_SIZEOF
  555. Gad2.ITxt    so.b    it_SIZEOF
  556. Gad3.ITxt    so.b    it_SIZEOF
  557. Gad4.ITxt    so.b    it_SIZEOF
  558. MyBorder    so.b    bd_SIZEOF
  559. MyCoords    so.w    10
  560. Border0    so.b    bd_SIZEOF
  561. Coords0    so.w    10
  562. Text_Attr    so.b    ta_SIZEOF
  563. MB_Sizeof    soval
  564.  
  565. SelWin    move.l    d0,d3    ;UnitExists
  566.     moveq    #0,d7    ;Default = Nothing
  567.     move.l    #MEMF_PUBLIC!MEMF_CLEAR,d1
  568.     move.l    #MB_Sizeof,d0
  569.     movea.l    (SysBase).w,a6
  570.     SYS    AllocMem
  571.     tst.l    d0
  572.     bne.b    1$
  573.     subq.l    #1,d0    ;Return -1 for error
  574.     rts
  575.  
  576. 1$    movea.l    d0,a5    ;Our relative base
  577.     lea    (GfxName,pc),a1    ;Open graphics.library
  578.     moveq    #33,d0
  579.  
  580.     SYS    OpenLibrary
  581.     move.l    d0,(Gfx_Base,a5)
  582.     beq    Error
  583.  
  584.     lea    (IntName,pc),a1    ;Open intuition.library
  585.     moveq    #33,d0
  586.     SYS    OpenLibrary
  587.     move.l    d0,(Int_Base,a5)
  588.     beq    Error
  589.     movea.l    d0,a6
  590.  
  591.     lea    (Text_Attr,a5),a1
  592.     lea    (FontName,pc),a0
  593.     move.l    a0,(ta_Name,a1)
  594.     move.w    #8,(ta_YSize,a1)
  595.     move.b    #FS_NORMAL,(ta_Style,a1)
  596.     move.b    #FPF_ROMFONT,(ta_Flags,a1)
  597.  
  598.     movea.l    (ib_ActiveScreen,a6),a0 ;Get active screen
  599.     move.l    a0,(ScreenPtr,a5)
  600.     move.w    (sc_Width,a0),d0
  601.     cmpi.w    #352,d0    ;Check horz resolution
  602.     sge    (HiresFlag,a5)
  603.     btst    #2,(sc_ViewPort+vp_Modes+1,a0)
  604.     sne    (LaceFlag,a5)
  605.  
  606.     lea    (MyBorder,a5),a1    ;Setup default border
  607.     lea    (Border0,a5),a2
  608.     clr.l    (a1)+    ;bd_LeftEdge,bd_TopEdge
  609.     clr.l    (a2)+    ;bd_LeftEdge,bd_TopEdge
  610.  
  611.     move.l    #$01000005,d0    ;bd_FrontPen,bd_BackPen,bd_DrawMode,bd_Count
  612.     move.l    d0,(a1)+
  613.     move.l    d0,(a2)+
  614.     lea    (MyCoords,a5),a0
  615.     move.l    a0,(a1)+    ;bd_XY
  616.     lea    (Coords0,a5),a0
  617.     move.l    a0,(a2)+    ;bd_XY
  618.  
  619.     lea    (Gadget0,a5),a4
  620.     lea    (Gad0.ITxt,a5),a3
  621.     lea    (GadText.tbl,pc),a2
  622.     tst.b    (HiresFlag,a5)
  623.     bne.b    3$
  624.     lea    (LoresText.tbl,pc),a2
  625. 3$    moveq    #0,d2
  626.  
  627. 4$    lea    (gg_SIZEOF,a4),a0
  628.     move.l    a0,(a4)+    ;gg_NextGadget
  629.  
  630.     moveq    #7,d0    ;0,1,3: LeftEdge=7
  631.     tst.w    d2    ;0
  632.     beq.b    5$
  633.     btst    #0,d2    ;Even or Odd?
  634.     bne.b    5$
  635.     moveq    #55,d0    ;2,4: LeftEdge=55
  636. 5$    tst.b    (HiresFlag,a5)
  637.     beq.b    6$
  638.     add.w    d0,d0
  639. 6$    move.w    d0,(a4)+    ;gg_LeftEdge
  640.  
  641.     moveq    #18,d0    ;0: TopEdge=18
  642.     tst.w    d2
  643.     beq.b    7$
  644.     addi.w    #22,d0    ;1,2: TopEdge=40
  645.     cmpi.w    #3,d2
  646.     blt.b    7$
  647.     addi.w    #22,d0    ;3,4: TopEdge=62
  648. 7$    tst.b    (LaceFlag,a5)
  649.     beq.b    8$
  650.     add.w    d0,d0
  651. 8$    move.w    d0,(a4)+    ;gg_TopEdge
  652.  
  653.     moveq    #40,d0    ;LORES
  654.     tst.w    d2    ;Gadget 0 only
  655.     bne.b    18$
  656.     addq.w    #4,d0
  657.     add.w    d0,d0
  658. 18$    tst.b    (HiresFlag,a5)
  659.     beq.b    9$
  660.     add.w    d0,d0    ;HIRES
  661. 9$    move.w    d0,(a4)+    ;gg_Width
  662.     lea    (MyCoords,a5),a0
  663.     tst.w    d2
  664.     bne.b    19$
  665.     lea    (Coords0,a5),a0    ;Gadget 0 only
  666. 19$    move.w    d0,(4,a0)    ;X border coords
  667.     move.w    d0,(8,a0)
  668.  
  669.     move.w    #18,d0    ;NORMAL
  670.     tst.b    (LaceFlag,a5)
  671.     beq.b    10$
  672.     add.w    d0,d0    ;LACE
  673. 10$    move.w    d0,(a4)+    ;gg_Height
  674.     lea    (MyCoords,a5),a0
  675.     tst.w    d2
  676.     bne.b    20$
  677.     lea    (Coords0,a5),a0    ;Gadget 0 only
  678. 20$    move.w    d0,(10,a0)    ;Y border coords
  679.     move.w    d0,(14,a0)
  680.  
  681.     move.w    #GADGHCOMP,(a4)+    ;gg_Flags
  682.     move.w    #GADGIMMEDIATE,(a4)+ ;gg_Activation
  683.     move.w    #BOOLGADGET,(a4)+    ;gg_GadgetType
  684.     lea    (MyBorder,a5),a0
  685.     tst.w    d2
  686.     bne.b    21$
  687.     lea    (Border0,a5),a0    ;Gadget 0 only
  688. 21$    move.l    a0,(a4)+    ;gg_GadgetRender
  689.     addq.w    #4,a4    ;gg_SelectRender
  690.     move.l    a3,(a4)+    ;gg_GadgetText
  691.     addq.w    #8,a4    ;gg_MutualExclude,gg_SpecialInfo
  692.     move.w    d2,(a4)+    ;gg_GadgetID
  693.     addq.w    #4,a4    ;gg_UserData
  694.  
  695.     move.l    #$01000000,(a3)+    ;it_FrontPen,it_BackPen,it_DrawMode
  696.  
  697.     moveq    #16,d0    ;Gad1-4/HIRES=16
  698.     tst.w    d2
  699.     bne.b    23$
  700.     tst.b    (HiresFlag,a5)    ;Gadget 0 only
  701.     beq.b    22$
  702.     add.w    d0,d0
  703.     add.w    d0,d0    ;Gad0/HIRES=64
  704.     bra.b    11$
  705.  
  706. 22$    addq.w    #4,d0    ;Gad0/LORES=20
  707.     bra.b    11$
  708.  
  709. 23$    tst.b    (HiresFlag,a5)    ;Gadgets 1-4
  710.     bne.b    11$
  711.     subq.w    #4,d0    ;Gad1-4/LORES=12
  712. 11$    move.w    d0,(a3)+    ;it_LeftEdge
  713.  
  714.     moveq    #14,d0
  715.     tst.b    (LaceFlag,a5)
  716.     bne.b    12$
  717.     subq.w    #8,d0
  718. 12$    move.w    d0,(a3)+    ;it_TopEdge
  719.  
  720.     lea    (Text_Attr,a5),a0
  721.     move.l    a0,(a3)+    ;it_TextFont
  722.     move.l    a2,(a3)+    ;it_Text
  723.     addq.w    #4,a3    ;it_NextText
  724.  
  725.     addq.w    #7,a2    ;Next text
  726.     addq.w    #1,d2    ;Next gadget
  727.     cmpi.w    #4,d2    ;All the gadgets done?
  728.     ble.w    4$
  729.  
  730.     clr.l    (Gadget4,a5)    ;gg_NextGadget
  731.  
  732.     lea    (Gadget0,a5),a0
  733.     ori.w    #SELECTED,(gg_Flags,a0)
  734.  
  735.     tst.l    d3    ;Units 2 & 3 exist?
  736.     bne.b    13$    ;Branch if yes
  737.     move.w    #GADGDISABLED,d0    ;Else, disable gadgets
  738.     lea    (Gadget3,a5),a0
  739.     or.w    d0,(gg_Flags,a0)
  740.  
  741.     lea    (Gadget4,a5),a0
  742.     or.w    d0,(gg_Flags,a0)
  743.  
  744. 13$    lea    (MyWindow,a5),a0
  745.     movea.l    (ScreenPtr,a5),a2 ;Get active screen
  746.     move.l    a2,(nw_Screen,a0)    ;
  747.  
  748.     move.w    #103,d0    ;LORES = 103
  749.     tst.b    (HiresFlag,a5)
  750.     beq.b    14$
  751.     add.w    d0,d0    ;HIRES = 206
  752. 14$    move.w    d0,(nw_Width,a0)
  753.     move.w    (sc_Width,a2),d1
  754.     lsr.w    #1,d1    ;Screen width / 2
  755.     lsr.w    #1,d0    ;Window width / 2
  756.     sub.w    d0,d1
  757.     move.w    d1,(a0)    ;nw_LeftEdge
  758.  
  759.     move.w    #88,d0    ;NORMAL = 88
  760.     tst.b    (LaceFlag,a5)
  761.     beq.b    15$
  762.     add.w    d0,d0    ;LACE = 176
  763. 15$    move.w    d0,(nw_Height,a0)
  764.     move.w    (sc_Height,a2),d1
  765.     lsr.w    #1,d1    ;Screen height / 2
  766.     lsr.w    #1,d0    ;Window height / 2
  767.     sub.w    d0,d1
  768.     move.w    d1,(nw_TopEdge,a0)
  769.  
  770.     move.b    #-1,(nw_DetailPen,a0)
  771.     move.b    #-1,(nw_BlockPen,a0)
  772.     move.l    #GADGETDOWN!CLOSEWINDOW,(nw_IDCMPFlags,a0)
  773.     move.l    #MyFeatures!MyGadgets,(nw_Flags,a0)
  774.     lea    (Gadget0,a5),a1
  775.     move.l    a1,(nw_FirstGadget,a0)
  776.     lea    (WindowTitle,pc),a1
  777.     tst.b    (HiresFlag,a5)
  778.     bne.b    16$
  779.     lea    (LoresTitle,pc),a1
  780. 16$    move.l    a1,(nw_Title,a0)
  781.     move.w    (sc_Flags,a2),d0
  782.     andi.w    #%00001111,d0
  783.     move.w    d0,(nw_Type,a0)
  784.     SYS    OpenWindow    ;Open window
  785.     movea.l    d0,a3    ;Save window pointer
  786.     tst.l    d0
  787.     beq.b    Error
  788.  
  789.     movea.l    (Gfx_Base,a5),a6
  790.     lea    (Text_Attr,pc),a0
  791.     SYS    OpenFont
  792.     move.l    d0,(FontPtr,a5)
  793.     beq.b    17$
  794.  
  795.     movea.l    d0,a0
  796.     movea.l    (wd_RPort,a3),a1
  797.     SYS    SetFont
  798.  
  799. 17$    moveq    #0,d6    ;Close flag
  800.     bsr.b    MainLoop
  801.     bra.b    Cleanup
  802.  
  803. ************************************************
  804. *             Termination section              *
  805. ************************************************
  806.  
  807. Error    subq.l    #1,d7
  808. Cleanup    move.l    (Gfx_Base,a5),d2
  809.     beq.b    2$
  810.     move.l    (FontPtr,a5),d0
  811.     beq.b    1$
  812.     movea.l    d0,a1
  813.     movea.l    d2,a6
  814.     SYS    CloseFont
  815.  
  816. 1$    movea.l    d2,a1
  817.     movea.l    (SysBase).w,a6
  818.     SYS    CloseLibrary
  819.  
  820. 2$    move.l    (Int_Base,a5),d2
  821.     beq.b    4$
  822.     move.l    a3,d0
  823.     beq.b    3$
  824.     movea.l d0,a0
  825.     movea.l    d2,a6
  826.     SYS    CloseWindow
  827.  
  828. 3$    movea.l    d2,a1
  829.     movea.l    (SysBase).w,a6
  830.     SYS    CloseLibrary
  831.  
  832. 4$    movea.l    a5,a1
  833.     move.l    #MB_Sizeof,d0
  834.     movea.l    (SysBase).w,a6
  835.     SYS    FreeMem
  836.     move.l    d7,d0    ;0-4, or -1 if error.
  837.     rts
  838.  
  839. ************************************************
  840. *             Main Execution Loop              *
  841. ************************************************
  842.  
  843. MainLoop    tst.w    d6    ;Flag set?
  844.     beq.b    1$
  845.     rts        ;Exit
  846.  
  847. 1$    movea.l (wd_UserPort,a3),a0
  848.     moveq    #0,d0
  849.     moveq    #0,d1
  850.     move.b    (MP_SIGBIT,a0),d1
  851.     bset    d1,d0
  852.     movea.l    (SysBase).w,a6
  853.     SYS    Wait    ;Now wait for a message
  854.  
  855. GetIMsg    movea.l (wd_UserPort,a3),a0
  856.     SYS    GetMsg
  857.     tst.l    d0
  858.     beq.b    MainLoop
  859.     movea.l d0,a1
  860.     move.l    (im_Class,a1),d2
  861.     movea.l    (im_IAddress,a1),a2
  862.     SYS    ReplyMsg
  863.  
  864.     cmpi.l    #CLOSEWINDOW,d2
  865.     bne.b    CheckGads
  866.     moveq    #-1,d6
  867.     bra.b    GetIMsg
  868.  
  869. CheckGads    cmpi.w    #GADGETDOWN,d2    ;Someone clicked on a gadget
  870.     bne.b    1$    ;Unknown class
  871.     moveq    #0,d7
  872.     move.w    (gg_GadgetID,a2),d7 ;ID = Unit number
  873.     lea    (Gadget0,a5),a1    ;1st gadget in group
  874.  
  875.     moveq    #5,d0    ;# of gadgets in group
  876.     bsr.b    MutualExclude
  877. 1$    bra.b    GetIMsg
  878.  
  879. *************************************************************************
  880. * NAME:     MutualExclude()
  881. * FUNCTION: Performs a MutualExclude function for Boolean gadgets.
  882. * INPUTS:   A3 = Window
  883. *           A2 = Currently selected gadget
  884. *           A1 = 1st gadget in group
  885. *           D0 = NumGads
  886. * RETURN:   None
  887. * SCRATCH:  D0-D1/A0-A1
  888. *************************************************************************
  889.  
  890. MutualExclude    move.l    a6,-(sp)
  891.     movea.l    (Int_Base,a5),a6
  892.     movem.l    d0/a1,-(sp)
  893.     movea.l    a3,a0    ;Window
  894.     SYS    RemoveGList
  895.     move.l    d0,d4    ;Position
  896.     movem.l    (sp),d1/a1
  897.     bra.b    3$
  898.  
  899. 1$    cmp.w    (gg_GadgetID,a1),d7 ;Is this the current gadget?
  900.     seq    d2    ;D2 = 1 if TRUE
  901.     btst    #7,(gg_Flags+1,a1)    ;Currently selected?
  902.     sne    d3    ;D3 = 1 if TRUE
  903.     eor.b    d2,d3
  904.     beq.b    2$
  905.     bchg    #7,(gg_Flags+1,a1)    ;Toggle the select flag
  906. 2$    movea.l    (a1),a1    ;gg_NextGadget
  907. 3$    dbra    d1,1$
  908.  
  909.     bsr.b    ClearScreen
  910.  
  911.     movea.l    a3,a0    ;Window
  912.     move.l    d4,d0    ;Position
  913.     movem.l    (sp),d1/a1    ;NumGads/Gadget
  914.     SYS    AddGList
  915.  
  916.     movea.l    a3,a1    ;Window
  917.     movem.l    (sp)+,d0/a0    ;NumGads/Gadget
  918.     SYS    RefreshGList
  919.     movea.l    (sp)+,a6
  920.     rts
  921.  
  922. ClearScreen    movem.l    a2/a6,-(sp)
  923.     movea.l    (Gfx_Base,a5),a6
  924.     movea.l    (wd_RPort,a3),a2
  925.     moveq    #0,d0
  926.     movea.l    a2,a1
  927.     SYS    SetAPen
  928.  
  929.     moveq    #4,d0    ;Xmin
  930.     moveq    #14,d1    ;Ymin
  931.     moveq    #0,d2
  932.     move.w    (wd_Width,a3),d2
  933.     subq.w    #4,d2    ;Xmax
  934.     moveq    #0,d3
  935.     move.w    (wd_Height,a3),d3
  936.     subq.w    #4,d3    ;Ymax
  937.     movea.l    a2,a1
  938.     SYS    RectFill
  939.  
  940.     moveq    #1,d0
  941.     movea.l    a2,a1
  942.     SYS    SetAPen
  943.     movem.l    (sp)+,a2/a6
  944.     rts
  945.  
  946. Notice    cstr    'SelectWindow ⌐1990 by The Puzzle Factory',10
  947. GfxName    cstr    'graphics.library'
  948. IntName    cstr    'intuition.library'
  949. FontName    cstr    'topaz.font'
  950. WindowTitle    cstr    'Select Unit:'
  951. LoresTitle    cstr    'Sel Unit:'
  952.  
  953. GadText.tbl    cstr    'Unit 0'
  954.     cstr    'Unit 1'
  955.     cstr    'Unit 2'
  956.     cstr    'Unit 3'
  957.     cstr    'Unit 4'
  958.  
  959. LoresText.tbl    cstr    'Unit 0'
  960.     cstr    'U1',0,0,0,0
  961.     cstr    'U2',0,0,0,0
  962.     cstr    'U3',0,0,0,0
  963.     cstr    'U4',0,0,0,0
  964.  
  965. enddispatchcode    end
  966.