home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Professional / OS2PRO194.ISO / os2 / prgramer / asm / argc.asm next >
Encoding:
Assembly Source File  |  1988-09-13  |  2.7 KB  |  87 lines
  1.         title   ARGC --- return argument count
  2.         page    55,132
  3.         .286
  4.  
  5. ;
  6. ; ARGC.ASM:     Return count of command line arguments.
  7. ;               Treats blanks and tabs as whitespace.
  8. ;
  9. ; OS/2 version Copyright (C) 1987 Ray Duncan
  10. ; 
  11. ; Call with:    N/A
  12. ;
  13. ; Returns:      AX    = argument count (always >=1)
  14. ;
  15. ; Uses:         nothing (other registers preserved)
  16. ;
  17.  
  18. tab     equ     09h             ; ASCII tab
  19. blank   equ     20h             ; ASCII space character
  20.  
  21.         extrn   DosGetEnv:far
  22.  
  23. _TEXT   segment word public 'CODE'
  24.  
  25.         assume  cs:_TEXT
  26.  
  27.         public  argc            ; make ARGC available to Linker
  28.  
  29.                                 ; local variables
  30. envseg  equ     [bp-2]          ; environment segment
  31. cmdoffs equ     [bp-4]          ; command line offset   
  32.  
  33. argc    proc    near
  34.  
  35.         enter   4,0             ; make room for local variables
  36.  
  37.         push    es              ; save original ES,BX, and CX
  38.         push    bx
  39.         push    cx
  40.  
  41.         push    ss              ; get selector for environment 
  42.         lea     ax,envseg       ; and offset of command line 
  43.         push    ax
  44.         push    ss
  45.         lea     ax,cmdoffs
  46.         push    ax
  47.         call    DosGetEnv       ; transfer to OS/2      
  48.         or      ax,ax           ; check operation status
  49.         mov     ax,1            ; force argc >= 1
  50.         jnz     argc3           ; inexplicable failure
  51.  
  52.         mov     es,envseg       ; set ES:BX = command line
  53.         mov     bx,cmdoffs
  54.  
  55. argc0:  inc     bx              ; ignore useless first field
  56.         cmp     byte ptr es:[bx],0      
  57.         jne     argc0
  58.  
  59. argc1:  mov     cx,-1           ; set flag = outside argument
  60.  
  61. argc2:  inc     bx              ; point to next character 
  62.         cmp     byte ptr es:[bx],0
  63.         je      argc3           ; exit if null byte
  64.         cmp     byte ptr es:[bx],blank
  65.         je      argc1           ; outside argument if ASCII blank
  66.         cmp     byte ptr es:[bx],tab    
  67.         je      argc1           ; outside argument if ASCII tab
  68.  
  69.                                 ; otherwise not blank or tab,
  70.         jcxz    argc2           ; jump if already inside argument
  71.  
  72.         inc     ax              ; else found argument, count it
  73.         not     cx              ; set flag = inside argument
  74.         jmp     argc2           ; and look at next character
  75.  
  76. argc3:  pop     cx              ; restore original BX, CX, ES
  77.         pop     bx
  78.         pop     es
  79.         leave                   ; discard local variables
  80.         ret                     ; return AX = argument count
  81.  
  82. argc    endp
  83.  
  84. _TEXT   ends
  85.  
  86.         end     
  87.