home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol255 / scan.mac < prev    next >
Encoding:
Text File  |  1986-03-22  |  5.0 KB  |  331 lines
  1.     TITLE    'Bad Sectors Scan Utility   6/May/1984  '
  2.     .SALL
  3. ;---------------------------------------------------------------;
  4. ;                                ;
  5. ;    CP/M plus  Bad Sector Scan Utility            ;
  6. ;                                ;
  7. ;    by Tetsuya Okada, Copyright (C) 1984            ;
  8. ;                                ;
  9. ;    Version 1.00    6/May/1984                ;
  10. ;                                ;
  11. ;---------------------------------------------------------------;
  12.     $INCLUDE STDINCL.LIB
  13. ;
  14.     .REQUEST STDLIB
  15.     EXTRN    DECPRI
  16. ; 
  17.     CSEG        ; PROGRAM CODE BEGIN
  18.     DEFB    'Copyright (C) 1984 by Tetsuya Okada',EOF
  19. SCAN::
  20.     LD    SP,STACK
  21. RESTART:
  22.     @MSG    <CR,LF,'SCAN - Bad Sectors Scan Utility for CP/M plus',CR,LF,CR,LF>
  23. ;     
  24. ;    CP/M VERSION CHECK
  25. ;
  26.     @BDOS    B$VERS    ;RETURN VERSION NUMBER
  27.     LD    A,H
  28.     AND    A
  29.     JR    NZ,VER$BAD    ;NOT CP/M
  30.     LD    A,L
  31.     AND    0F0H        ;IGNORE RELEASE NUMBER
  32.     CP    30H
  33.     JR    Z,VER$OK
  34. VER$BAD:
  35.     @MSG    <'ERROR: CP/M 3.X required.',CR,LF>
  36.     @STOP
  37. VER$OK:
  38. ;
  39. ;    PROMPT DRIVE NUMBER
  40. ;
  41. MAIN$LOOP:
  42.     @MSG    <'Enter Drive (A-O, or CR to end): '>
  43.     @BDOS    B$CIN
  44.     CP    CR
  45.     JP    Z,STOP
  46.     CP    'a'    ;SMALL ?
  47.     JR    C,NOT$SMALL
  48.     SUB    'a'-'A'
  49. NOT$SMALL:
  50.     LD    (DRIVE),A
  51.     @MSG    <CR,LF>
  52.     LD    A,(DRIVE)
  53.     CP    'A'
  54.     JR    C,DR$ERROR
  55.     CP    'O'+1
  56.     JR    C,DR$OK
  57. DR$ERROR:
  58.     @MSG    <'ERROR: Invalid Drive',CR,LF>
  59.     JP    MAIN$LOOP
  60. DR$OK:
  61. ;
  62. ;    GET DPB
  63. ;
  64.     LD    E,0FFH        ;RETURN ERROR MODE
  65.     @BDOS    B$SETER        ;SET BDOS ERROR MODE
  66. ;    
  67.     LD    HL,1        ;MAKE DRIVE VECTOR
  68.     LD    A,(DRIVE)
  69.     SUB    'A'
  70. SH$DVEC:            ;SHIFT REG(A) TIMES
  71.     DEC    A
  72.     JR    NZ,RST$DRV
  73.     ADD    HL,HL
  74.     JR    SH$DVEC
  75. RST$DRV:
  76.     EX    DE,HL
  77.     @BDOS    B$RSTDRV    ;RESET DRIVE
  78. ;
  79.     LD    A,(DRIVE)
  80.     SUB    'A'
  81.     LD    E,A    
  82.     @BDOS    B$SELDSK    ;SELECT DISK
  83.     INC    A
  84.     JP    NZ,SEL$SUC
  85.     LD    A,H
  86.     CP    4
  87.     JP    Z,DR$ERROR
  88.     JP    IO$ERROR
  89. SEL$SUC:
  90.     @BDOS    B$GETDPB    ;GET DPB ADDRESS OF SELECTED DRIVE
  91.     LD    (DPBADR),HL
  92.     LD    A,H
  93.     AND    L
  94.     CP    0FFH
  95.     JP    Z,IO$ERROR
  96. ;
  97. ;    CALC NUMBER OF PHISICAL SECTOR PER TRACK
  98. ;
  99.     LD    IX,(DPBADR)
  100.     LD    L,(IX+0)    ;SPT (128 SECTORS PER TRACK)
  101.     LD    H,(IX+1)
  102.     LD    A,(IX+15)    ;PSH (PHISICAL RECORD SHIFT FACTOR)
  103. PS$SHIFT:
  104.     AND    A
  105.     JR    Z,PS$S1
  106.     SRL    H        ;HALVE HL 
  107.     RR    L
  108.     JP    C,DPBERROR    ;ERROR IF REMAINDER IS NOT ZERO
  109.     DEC    A
  110.     JR    PS$SHIFT
  111. PS$S1:
  112.     LD    (PSPT),HL    ;STORE PHISICAL SECTOR PER TRACK
  113. ;
  114. ;    CALC NUMBER OF TRACKS 
  115. ;
  116.     LD    L,(IX+5)    ;DSM (NUMBER OF BLOCKS - 1)
  117.     LD    H,(IX+6)
  118.     INC    HL
  119.     LD    B,(IX+2)    ;BSH (BLOCK SHIFT FACTOR)
  120. TR$SHIFT:
  121.     ADD    HL,HL
  122.     JP    C,BIG$DISK
  123.     DJNZ    TR$SHIFT
  124.      LD    E,(IX+0)    ;SPT
  125.     LD    D,(IX+1)
  126.     LD    BC,1
  127. TR$DIV:
  128.     AND    A    ;CLEAR CARRY FLAG
  129.     SBC    HL,DE
  130.     JR    C,TR$D1
  131.     JR    Z,TR$D1
  132.     INC    BC
  133.     JR    TR$DIV
  134. TR$D1:
  135.     LD    (TRACKS),BC
  136. ;
  137.     @MSG    <'Do you want to scan reserved tracks ? (y/n) '>
  138.     CALL    YESNO
  139.     JR    Z,RSV$SCAN
  140.     LD    L,(IX+13)    ;OFF (NUMBER OF RESERVED TRACKS)
  141.     LD    H,(IX+14)
  142.     LD    (CURTRK),HL
  143.     JR    TR$E
  144. RSV$SCAN:
  145.     LD    HL,(TRACKS)
  146.     LD    E,(IX+13)    ;OFF
  147.     LD    D,(IX+14)
  148.     ADD    HL,DE
  149.     LD    (TRACKS),HL
  150.     LD    HL,0
  151.     LD    (CURTRK),HL
  152. TR$E:
  153.     @MSG    <'Do you need sector skewing ? (y/n) '>
  154.     CALL    YESNO
  155.     LD    A,0
  156.     JR    NZ,NO$SKEW
  157.     LD    A,0FFH
  158. NO$SKEW:
  159.     LD    (SKEWF),A
  160. ;
  161. ;    SCAN DISK
  162. ;
  163. @BIOS    MACRO    ?FUNC        ;;MACRO TO CALL BIOS
  164.     CALL    BIOSSUB
  165.     LD    A,?FUNC
  166.     LD    (FUNC),A
  167.     @BDOS    B$BIOS
  168.     ENDM
  169. ;
  170.     XOR    A
  171.     LD    (ERROR),A    ;CLEAR ERROR FLAG
  172. ;
  173.     LD    HL,(TRACKS)
  174.     LD    (TRKCNT),HL
  175. NEXT$TRK:
  176.     @MSG    <'Scanning Track - '>
  177.     LD    HL,(CURTRK)
  178.     CALL    DECPRI
  179.     @MSG    <'      ',CR>
  180. ;
  181.     LD    HL,1
  182.     LD    (CURSEC),HL
  183. NEXT$SEC:
  184.     LD    BC,(CURTRK)
  185.     @BIOS    10        ;SETTRK
  186.     LD    BC,(CURSEC)
  187.     @BIOS    11        ;SETSEC
  188.     LD    BC,SECBUF
  189.     @BIOS    12        ;SETDMA
  190.     @BIOS    13        ;READ
  191.     AND    A
  192.     CALL    NZ,BAD$SEC
  193. ;
  194.     LD    HL,(CURSEC)
  195.     INC    HL
  196.     LD    A,(SKEWF)
  197.     AND    A
  198.     JR    Z,NO$SK
  199.     INC    HL
  200.     LD    (CURSEC),HL
  201.     LD    DE,(PSPT)
  202.     SCF
  203.     SBC    HL,DE
  204.     JR    C,NEXT$SEC
  205.     BIT    0,L
  206.     JR    NZ,INC$TRK
  207.     LD    HL,2
  208.     LD    (CURSEC),HL
  209.     JR    NEXT$SEC
  210. NO$SK:
  211.     LD    (CURSEC),HL
  212.     LD    DE,(PSPT)
  213.     SCF
  214.     SBC    HL,DE
  215.     JR    C,NEXT$SEC
  216. INC$TRK:
  217.     LD    HL,(CURTRK)
  218.     INC    HL
  219.     LD    (CURTRK),HL
  220.     LD    HL,(TRKCNT)
  221.     DEC    HL
  222.     LD    (TRKCNT),HL
  223.     LD    A,H
  224.     OR    L
  225.     JP    NZ,NEXT$TRK
  226. ;
  227. ;    SCANNING COMPLETE
  228. ;
  229.     @MSG    <'Scanning Complete.    '>
  230.     LD    A,(ERROR)
  231.     AND    A
  232.     JR    Z,NO$BAD
  233.     LD    H,0
  234.     LD    L,A
  235.     CALL    DECPRI
  236.     JR    BSMSG
  237. NO$BAD:
  238.     @MSG    <'No'>
  239. BSMSG:
  240.     @MSG    <' Bad Sectors.       ',CR,LF>
  241.     JP    RESTART
  242. ;
  243. STOP:
  244.     @STOP
  245. ;
  246. ;    FATAL ERROR PROCESSING
  247. ;
  248. IO$ERROR:
  249.     @MSG    <'ERROR: Phisical Disk I/O',CR,LF>
  250.     JP    RESTART
  251. ;
  252. DPBERROR:
  253.     @MSG    <'ERROR: Invalid Disk Parameter Block',CR,LF>
  254.     JP    RESTART
  255. ;
  256. BIG$DISK:
  257.     @MSG    <'ERROR: This program cannot support such a big drive.',CR,LF>
  258.     JP    RESTART
  259. ;
  260. MED$CHG:
  261.     @MSG    <'ERROR: Media density has changed.',CR,LF>
  262.     JP    RESTART
  263. ;
  264. ;    SUBROUTINES
  265. ;
  266. YESNO:        ; FLAG Z: YES; NZ: NO
  267.     @BDOS    B$CIN
  268.     PUSH    AF
  269.     @MSG    <CR,LF>
  270.     POP    AF
  271.     CP    'Y'
  272.     RET    Z
  273.     CP    'y'
  274.     RET    
  275. ;
  276. BIOSSUB:    ; SET REGISTERS TO BIOSPB
  277.     LD    (AREG),A
  278.     LD    (BCREG),BC
  279.     LD    (DEREG),DE
  280.     LD    (HLREG),HL
  281.     LD    DE,BIOSPB
  282.     RET
  283. ;
  284. BAD$SEC:
  285.     POP    HL    ;RETURN ADDRESS
  286.     INC    A
  287.     JP    Z,MED$CHG
  288.     PUSH    HL    ;RE-PUSH
  289.     @MSG    <CR,'*** Bad Sector ***  Track - '>
  290.     LD    HL,(CURTRK)
  291.     CALL    DECPRI
  292.     @MSG    <'   Sector - '>
  293.     LD    HL,(CURSEC)
  294.     CALL    DECPRI
  295.     @MSG    <'            ',CR,LF>
  296. ;
  297.     LD    HL,ERROR
  298.     INC    (HL)
  299.     RET    NZ
  300.     DEC    (HL)
  301.     RET
  302. ;
  303. ;    DATA AREA
  304. ;
  305.     DSEG
  306. ;
  307. DRIVE:    DEFS    1    ;DRIVE SPEC. IN ASCII
  308. DPBADR: DEFS    2    ;DPB ADDRESS
  309. PSPT:    DEFS     2    ;NUMBER OF PHISICAL SECTORS PER TRACK
  310. TRACKS: DEFS    2    ;NUMBER OF TRACK 
  311. TRKCNT: DEFS    2    ;TRACK COUNTER
  312. CURTRK: DEFS    2    ;CURRENT TRACK
  313. CURSEC: DEFS    2    ;CURRENT SECTOR
  314. ERROR:    DEFS    1    ;ERROR COUNT
  315. SKEWF:    DEFS    1    ;NONZERO IF SKEWING
  316. ;
  317. BIOSPB:        ;BIOS PARAMETER BLOCK FOR DIRECT BIOS CALL
  318. FUNC:    DEFS    1
  319. AREG:    DEFS    1
  320. BCREG:    DEFS    2
  321. DEREG:    DEFS    2
  322. HLREG:    DEFS    2
  323. ;
  324.     DEFS    32    ;STACK ROOM
  325. STACK:
  326. ;
  327. SECBUF::        ;MUST BE LAST OF .COM FILE
  328. ;    DEFS    1024
  329. ;
  330.     END    SCAN
  331.