home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol135 / dir-dump.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  6.8 KB  |  402 lines
  1. ;            DIR-DUMP.ASM Version 2.2
  2. ;
  3. ;                as of
  4. ;
  5. ;              September 23/11/1980
  6. ;
  7. ;
  8. ;    Mod for 64 char wide screen 23/11/82 W.Ellis
  9. ;
  10. ;   Changed are; Spacing between characters.
  11. ;           ; Headings have been abrevated
  12. ;           ; Proprietary bit check was removed
  13. ;
  14. ;           ; All this was to make it fit on one
  15. ;           ; 64 character line
  16. ;
  17. ;           ; Bit 7 gets turned off before the filename
  18. ;           ; gets printed
  19. ;
  20. ;    Name changed from FILE-XT2.ASM after this change
  21. ;
  22. ;
  23. ;==============================================================
  24. ;
  25. ;
  26. ;  Renamed from filename FILE-EXT.ASM, to indicate CP/M Version
  27. ;  2.X only compatibility (display format) only.
  28. ;
  29. ;  Added: User number  display, "proprietary software" display
  30. ;      and  removed "ILLCHK" for non-ASCII characters which 
  31. ;      then requested deletion of the questionable file.
  32. ;
  33. ;                   Kelly Smith
  34. ;
  35. ;
  36. ;  Originally  named  FILES.ASM,  and  from a  disassembly  by 
  37. ; "J.A.P"  of January 23,1980...FILE-XT2.ASM will display  the 
  38. ; selected disk's directory entries in the form:
  39. ; 
  40.  
  41. ;Us Filename.Typ RSH ExSfSiRc <-----------Group-------------->'
  42. ;============================================================='
  43. ;
  44. ; Where:
  45. ;
  46. ; "Us" is the User assignment for the file.
  47. ; "Filename" is the ASCII file name.
  48. ; "Typ" is the ASCII file type.
  49. ; "R" is the "read only" control bit
  50. ; "S" is the "system directory" control bit
  51. ; "R" is the "reserved" (MP/M Ver.1.0) control bit
  52. ; "Ex" is the "file extension" byte
  53. ; "Sf" is a CP/M "internal function" byte.
  54. ; "Si" is a CP/M "internal function" byte
  55. ; "Rc" is the "record count" byte.
  56. ; "Group" is the "allocation vector table" for the file.
  57. ; 
  58. ;  The "hack-job" I did on this one was less than  ideal,  but 
  59. ; none the less, it get's the job done...the display format is 
  60. ; now  alot  cleaner,  and  it    does'nt  "warm    boot"  as  the 
  61. ; FILES.ASM version did...
  62. ; 
  63. ;  The    program will display the disk directory of the    logged 
  64. ; on  disk,  including all the Hexadecimal information on  the 
  65. ; groups. 
  66. ; 
  67. ;  On  the  subject  of     "hack-job's"  of  software,  read  an 
  68. ; interesting  article    in  Psychology    Today  magazine,  "The 
  69. ; Hacker  Papers;  Computer  Addiction:     Reflection on    a  New 
  70. ; Obsession"...August 1980 issue, pages 62-69.
  71. ; 
  72. ;                Best regards,
  73. ; 
  74. ;                Kelly Smith, CP/M-NET (tm)
  75. ;                805-527-9321 (Modem, 300 Baud)
  76. ;                805-527-0518 (Verbal)
  77. ; 
  78.  
  79.     ORG    0100H
  80.  
  81. BDOS    EQU    05H
  82. TBUFF    EQU    80H
  83. ;
  84. CR    EQU    0DH    ;ASCII CARRIAGE RETURN
  85. LF    EQU    0AH    ;ASCII LINE FEED
  86. ;
  87. ;
  88. FILES:            ; 
  89.     LXI    H,0    ;
  90.     DAD    SP    ;
  91.     SHLD    OLDSTK    ;
  92.     LXI    SP,NEWSTK    ;
  93.     MVI    C,12    ;GET CP/M VERSION NUMBER
  94.     CALL    BDOS
  95.     CPI    20H    ;CP/M VERSION 2.0 OR BETTER?
  96.     JNC    BEGIN    ;IF VERSION O.K., PRESS ON
  97.     LXI    D,BADVER;OOPS...BAD VERSION FOR THIS FILE
  98.     CALL    PRINT
  99.     JMP    QUIT    ;QUIT
  100. ;
  101. ;
  102. ;    SYSTEM SUBROUTINES
  103. ;
  104. ;    PRINT STRING FROM D&E REGS.
  105. ;
  106. PRINT:    MVI    C,9
  107.     CALL    BDOS
  108.     RET
  109. ;
  110. ;    TYPE A CHAR FROM (A)
  111. ;
  112. TYPE:        ; 
  113.     PUSH    B
  114.     PUSH    D
  115.     PUSH    H
  116.     MVI    C,2
  117.     MOV    E,A
  118.     CALL    BDOS    ;
  119.     POP    H
  120.     POP    D
  121.     POP    B
  122.     RET
  123. ;
  124. ;    SEARCH FOR A FILE
  125. ;
  126. SEARCH:        ; 
  127.     PUSH    B
  128.     PUSH    D
  129.     PUSH    H
  130.     MVI    C,11H
  131.     LXI    D,AFN    ;
  132.     CALL    BDOS    ;
  133.     STA    RESULT    ;
  134.     POP    H
  135.     POP    D
  136.     POP    B
  137.     RET
  138. ;
  139. ;    AMBIGUOUS FILENAME.TYP
  140. ;
  141. AFN:        ; 
  142.     DB    '?????????????'
  143. RESULT:        ; 
  144.     DB    0    ;STORAGE FOR RESULT OF BDOS CALL
  145. ;
  146. ;    FIND NEXT OCCURRENCE OF FILE
  147. ;
  148. NEXTFILE:        ; 
  149.     PUSH    B
  150.     PUSH    D
  151.     PUSH    H
  152.     MVI    C,12H
  153.     LXI    D,AFN    ;
  154.     CALL    BDOS    ;
  155.     STA    RESULT    ;
  156.     POP    H
  157.     POP    D
  158.     POP    B
  159.     RET
  160. ;
  161. ;    GET INPUT FROM CONSOLE
  162. ;
  163. CONIN:        ; 
  164.     PUSH    B
  165.     PUSH    D
  166.     PUSH    H
  167.     MVI    C,1
  168.     CALL    BDOS    ;
  169.     POP    H
  170.     POP    D
  171.     POP    B
  172.     RET
  173. ;
  174. ;    CONVERT A BYTE IN (A) TO TWO PRINTED CHARACTERS
  175. ;
  176. HEXASC:        ; 
  177.     CPI    0AH
  178.     JC    HEXA2    ;
  179.     ADI    '7'    ;
  180.     CALL    TYPE    ;
  181.     RET
  182. HEXA2:        ; 
  183.     ADI    '0'    ;
  184.     CALL    TYPE    ;
  185.     RET
  186. HEXCON:        ; 
  187.     PUSH    PSW
  188.     RAR
  189.     RAR
  190.     RAR
  191.     RAR
  192.     ANI    0FH
  193.     CALL    HEXASC    ;
  194.     POP    PSW
  195.     ANI    0FH
  196.     CALL    HEXASC    ;
  197.     RET
  198. ;
  199. ;    NEWLINE
  200. ;
  201. CRLF:        ; 
  202.     MVI    A,CR
  203.     CALL    TYPE    ;
  204.     MVI    A,LF
  205.     CALL    TYPE    ;
  206.     RET
  207. ;
  208. ;    PRINT A SPACE
  209. ;
  210. SPACE:        ; 
  211.     MVI    A,' '    ;
  212.     CALL    TYPE    ;
  213.     RET
  214. ;
  215. ;    MAIN WORK LOOP
  216. ;
  217. ;    THIS ROUTINE FINDS THE POSITION OF THE FILE
  218. ;    INFORMATION IN THE DIRECTORY DMA, PRINTS THE
  219. ;    DATA IF IT IS A CURRENT FILE, AND PROMPTS THE
  220. ;    OPERATOR FOR INSTRUCTIONS IF THE FILENAME HAS
  221. ;    ILLEGAL (NON-ASCII) DATA IN IT.
  222. ;
  223. WORKLOOP:        ; 
  224.     LDA    RESULT    ;RESULT HOLDS POSITION OF-
  225.     MOV    B,A    ; -THE DIRECTORY ENTRY IN THE DIR. DMA
  226.     ANI    3
  227.     RAL
  228.     RAL
  229.     RAL
  230.     RAL
  231.     RAL
  232.     ANI    0E0H
  233.     MOV    E,A
  234.     MVI    D,0
  235.     LXI    H,TBUFF ;
  236.     DAD    D    ;HL NOW POINTS AT THE FILE INFO
  237.     MOV    A,M
  238.     CPI    0E5H    ;KILLED FILE?
  239.     RZ        ;YES
  240.     MOV    A,M
  241.     CALL    HEXCON    ;PRINT USER NUMBER
  242.     CALL    SPACE
  243.     PUSH    H
  244.     PUSH    H
  245.     INX    H    ;POINT TO FIRST CHARACTER IN FILE NAME
  246.  
  247.     MVI    B,8
  248. WORK02: MOV    A,M    ;PRINT FILE NAME
  249.     ANI    7FH    ;AND IT TO TURN OFF BIT 7
  250.     CALL    TYPE    ;
  251.     DCR    B
  252.     INX    H
  253.     JNZ    WORK02    ;
  254.     MVI    B,3
  255.     MVI    A,'.'
  256.     CALL    TYPE    ;PRINT NEXT THREE CHARACTERS AS ASCII
  257. WORK03: MOV    A,M
  258.     ANI    7FH    ;AND IT TO TURN OFF BIT 7
  259.     CALL    TYPE    ;
  260.     DCR    B
  261.     INX    H
  262.     JNZ    WORK03    ;
  263.     CALL    TYPE
  264.     CALL    SPACE
  265.     MVI    B,3
  266.     POP    H    ;NOW DISPLAY ATTRIBUTES
  267.     LXI    D,9
  268.     DAD    D
  269.  
  270. WORK03A:MOV    A,M
  271.     RLC        ;TEST $SYS AND $R/O, AND RESERVED
  272.     MVI    A,'1'
  273.     JC    WORK03B
  274.     MVI    A,'0'
  275. WORK03B:CALL    TYPE
  276.     DCR    B
  277.     INX    H
  278.     JNZ    WORK03A
  279.  
  280.     MVI    B,20
  281. WORK04: MOV    A,B
  282.     ANI    3
  283.     CZ    SPACE    ;
  284.     MOV    A,M
  285.     CALL    HEXCON    ;
  286.     INX    H
  287.     DCR    B
  288.     JNZ    WORK04    ;
  289.     CALL    CRLF    ;
  290.     POP    H
  291.     RET
  292. ;
  293. BADVER: DB    'Sorry, CP/M Version 2.X required$'
  294.  
  295. MSG:    DB    'Us Filename.Typ RSH ExSfSiRc'
  296.     DB    ' <--------------Group-------------->'
  297.     DB    CR,LF
  298.     DB    '============================'
  299.     DB    '===================================='
  300.     DB    CR,LF,LF,'$'
  301. ;
  302. ;
  303. ;
  304. ; ERROR MESSAGES
  305. ;
  306. ERROR1: LXI    D,ERMSG1;SAY NO GO, AND BAIL OUT
  307.     CALL    PRINT
  308.     JMP    QUIT
  309.  
  310. ;
  311. ERMSG1: DB    CR,LF,'Disk select should be " N:"$'
  312.  
  313. ;
  314. ERROR2: LXI    D,ERMSG2;SAY NO GO, AND BAIL OUT
  315.     CALL    PRINT
  316.     JMP    QUIT
  317.  
  318. ERMSG2: DB    CR,LF,'Bad delimeter, should be ":"$'
  319.  
  320. ;
  321. ERROR3: LXI    D,ERMSG3;SAY NO GO, AND BAIL OUT
  322.     CALL    PRINT
  323.     JMP    QUIT
  324.  
  325. ERMSG3: DB    CR,LF,'No drive specified$'
  326.  
  327. ;
  328. ERROR4: LXI    D,ERMSG4;SAY NO GO, AND BAIL OUT
  329.     CALL    PRINT
  330.     JMP    QUIT
  331.  
  332. ERMSG4: DB    CR,LF,'Only drives A to D allowed$'
  333.  
  334. ;
  335.  
  336. ;    PROGRAM BEGINS HERE
  337. ;
  338. BEGIN:
  339. ;
  340. ; CHECK FOR DRIVE SPECIFICATION
  341. ;
  342.     CALL    CRLF
  343.     LDA    TBUFF    ;GET LENGTH OF COMMAND PARAMETERS
  344.     CPI    2    ; IF <2, NO PARAMETERS
  345.     JC    MAIN01    ; MUST BE PRESENT LOGGED-IN DRIVE
  346.     JZ    ERROR1    ;EXACTLY 2, IS ERROR
  347.     LHLD    TBUFF+2 ;AT LEAST 3 THEN...
  348.     MOV    A,H    ;NEXT CHARACTER SHOULD BE ":"
  349.     CPI    ':'
  350.     JNZ    ERROR2    ;ONLY ALLOW DRIVE SET
  351.     MOV    A,L    ;NEXT CHARACTER SHOULD BE DRIVE
  352.     CPI    'A'    ;AT A MINIMUM, "A"
  353.     JC    ERROR3
  354.     CPI    'E'    ;AT A MAXIMUM "D"
  355.     JNC    ERROR4
  356.     ANI    7    ;STRIP BITS, FOR 0 TO 3
  357.     DCR    A    ;BACK OFF FOR 0 TO 3
  358.     MOV    E,A    ;MAKE DISK NUMBER
  359.     MVI    D,0
  360.     MVI    C,14    ;BDOS SELECT DISK FUNCTION
  361.     CALL    BDOS
  362.  
  363. MAIN01: LXI    D,MSG
  364.     CALL    PRINT
  365.     CALL    SEARCH    ;
  366. MAIN02:        ; 
  367.     LDA    RESULT    ;
  368.     CPI    0FFH
  369.     JZ    QUIT
  370.     CALL    WORKLOOP    ;
  371.     CALL    NEXTFILE    ;
  372.     JMP    MAIN02    ;
  373. ;MAIN04:        ; 
  374. ;    LHLD    DELPTR    ;
  375. ;    LXI    D,DELFIL
  376. ;    MOV    A,L
  377. ;    CMP    E
  378. ;    JNZ    MAIN06    ;
  379. ;    MOV    A,H
  380. ;    CMP    D
  381. ;    JZ    QUIT    ;
  382. ;MAIN06:        ; 
  383. ;    LXI    D,-10H
  384. ;    DAD    D
  385. ;    SHLD    DELPTR    ;
  386. ;    XCHG
  387. ;    CALL    DELETE    ;
  388. ;    JMP    MAIN04    ;
  389. QUIT:        ; 
  390.     LHLD    OLDSTK    ;
  391.     SPHL
  392.     RET        ;
  393. ;
  394. ;    SOME STORAGE LOCATIONS
  395. ;
  396. OLDSTK: DS    2    ;STORAGE FOR "OLD" STACK POINTER
  397.     DS    32
  398. NEWSTK    EQU    $    ;STORAGE FOR "NEW" STACK
  399. ;
  400. ;
  401.     END
  402.