home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol119 / lm16.asm < prev    next >
Encoding:
Assembly Source File  |  1984-04-29  |  30.6 KB  |  1,629 lines
  1. ;        LMODEM.ASM  by S. Kluger, N5NX
  2. ;
  3. ;    Developed from XMODEM56.ASM by Keith Petersen, W8SDZ
  4. ;    The basic idea on how to access the LBR file was taken from
  5. ;    LRUN.ASM by G. Novosielski, but no code was copied therefrom.
  6. ;    Error checking is not done as extensively as in LRUN.
  7. ;    Note that this is an EXPERIMENTAL version and could most
  8. ;    definitely be improved by a more experienced programmer.
  9. ;    (This doesn't mean I'm incompetent. I made it work, didn't I???)
  10. ;
  11. ;-----------------------------------------------------------------
  12. ; Modifications/updates: (in reverse order to minimize reading time)
  13. ; 1.6  12/26/82 Finally fixed send bug. Changed end-of-member detect
  14. ;        routine and placement of RCNT. (SFK)
  15. ; 1.5  12/25/82 Fixed bug which kept LMODEM from sending files larger
  16. ;        than 255 sectors (bug made file size modulo 255) (SFK)
  17. ; 1.4  12/22/82 Incorporated directory check to make sure LBR directory
  18. ;        is not corrupt. Changed program to accept either a file name
  19. ;        defaulting to .LBR or any full file name, in case the library
  20. ;        file has a different type. (SFK)
  21. ; 1.3  12/03/82 Added EQU to version no.,and changed sign-on message.
  22. ;        (Tim Hancock  Walled Lake, Mich)
  23. ; 1.2  11/29/82 Fixed RECU and DEFDRV labels (for LOGCAL only) (SFK)
  24. ; 1.1  11/27/82 Fixed bug where sometimes the end-of-member would not
  25. ;               be detected; LMODEM kept going until EOF on the LBR (SFK)
  26. ; 1.0  11/27/82 Original distribution version
  27. ;
  28. ;
  29. ;        REMOTE LBR - CP/M FILE TRANSFER PROGRAM
  30. ;
  31. ; Based on MODEM.ASM V2.0, by Ward Christensen.  This program is in-
  32. ; tended for use on remote CP/M systems where it is important that the
  33. ; initialization of the modem not be changed, such as when using the
  34. ; BYE program.  The baud rate and number of bits remains the same as
  35. ; whatever was set previously.  There is no disconnect, terminal or echo
  36. ; option.
  37. ;
  38. ;       NOTE:  REQUIRES SEQIO22.LIB if "LOGCAL" is set TRUE
  39. ;
  40. ;*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *
  41. ;
  42. ;
  43. ;    NOTE:  If you add improvements or otherwise update
  44. ;          this program, please modem a copy of the
  45. ;          new file to "El Paso RCPM" in El Paso, TX
  46. ;          (915)-598-1668.
  47. ;
  48. ;
  49. ;*   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *   *
  50. ;
  51. ;
  52. FALSE    EQU    0
  53. TRUE    EQU    NOT FALSE
  54. ;
  55. ;
  56. ;-----------------------------------------------------------------------
  57. ;
  58. ;        --- Conditional Assembly Options ---
  59. ;
  60. ;-----------------------------------------------------------------------
  61. ;
  62. ;
  63. VERSION    EQU    1
  64. MODLEV    EQU    6
  65. ;
  66. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  67. ALTCPM    EQU    FALSE    ;TRUE, IS TRS-80 OR H8 W/O 0-ORG
  68. ;
  69. DCH    EQU    FALSE    ;TRUE, IS D.C. HAYES
  70. PMMI    EQU    TRUE    ;TRUE, IS PMMI
  71. H8    EQU    FALSE    ;TRUE, IS H8/H89 W/INS8250 MODEM CHIP
  72. EXTMOD    EQU    FALSE    ;TRUE, IS NONE OF THE ABOVE!
  73. ;
  74. FASTCLK EQU    TRUE    ;PUT TRUE HERE FOR 4 MHZ CLOCK
  75. ;
  76. FRNTPNL    EQU    FALSE    ;TO DISPLAY STATUS ON FRONT PANEL
  77. PANEL    EQU    0FFH    ;DEFAULT ADDRESS OF FRONT PANEL
  78. ;
  79. ;
  80. ;    FILE TRANSFER LOGGING OPTIONS
  81. ;
  82. LOGCAL    EQU    false    ;IF USING LOGGING OF LMODEM TRANSFERS
  83. LASTUSR    EQU    14    ;USER AREA OF 'LASTCALR' FILE(IF 'LOGCAL' ONLY)
  84. RECU    EQU    0    ;user area for .LOG file
  85. DEFDRV    EQU    'A'    ;LOG file drive
  86. ;
  87. LSPEED    EQU    true    ;TRUE IF USING BYE WITH SPEED SELECTION
  88. MSPEED    EQU    3DH    ;LOCATION OF BAUD RATE FACTOR  (SET BY BYE)
  89. CONOUT    EQU    0000H    ;ADDRESS OF BIOS 'C' REGISTER OUTPUT.  THIS WILL
  90. ;            ;BE THE 5TH ENTRY IN THE CP/M JUMP TABLE.  ENTER
  91. ;            ;YOUR OWN BIOS ADDRESS HERE IF YOU WISH TO HAVE
  92. ;            ;THE RECORD COUNT ON YOUR LOCAL CRT CONSOLE.
  93. ;
  94. ;-----------------------------------------------------------------------
  95. ;
  96. ;         --- Modem Port Equates ---
  97. ;
  98. ;-----------------------------------------------------------------------
  99. ;
  100.     IF    PMMI
  101. MODCTLP    EQU    0E0H        ;PMMI VALUES (BASE PORT ADDRESS)
  102. MODSNDB    EQU    1        ;BIT TO TEST FOR SEND
  103. MODSNDR    EQU    1        ;VALUE WHEN READY
  104. MODRCVB    EQU    2        ;BIT TO TEST FOR RECEIVE
  105. MODRCVR    EQU    2        ;VALUE WHEN READY
  106. MODDCDB    EQU    4        ;CARRIER DETECT BIT
  107. MODDCDA    EQU    0        ;VALUE WHEN ACTIVE
  108. MODPARE    EQU    08H        ;VALUE FOR PARITY ERROR
  109. MODOVRE    EQU    10H        ;VALUE FOR OVERRUN ERROR
  110. MODFRME    EQU    20H        ;VALUE FOR FRAMING ERROR
  111. MODDATP    EQU    MODCTLP+1    ;DATA PORT, RECEIVE
  112. MODDATO    EQU    MODCTLP+1    ;DATA PORT, SEND
  113. BAUDRP    EQU    MODCTLP+2    ;BAUD RATE OUTPUT/MODEM STATUS
  114. MODCTL2    EQU    MODCTLP+3    ;SECOND CTL PORT
  115.     ENDIF
  116. ;
  117.     IF    H8
  118. MODCTLP    EQU    0E5H    ;H8/H89 VALUES (LSR-LINE STATUS REG.)
  119. MODSNDB    EQU    20H    ;TEST FOR SEND (LSR-THRE)
  120. MODSNDR    EQU    20H    ;VALUE WHEN READY
  121. MODRCVB    EQU    01H    ;TEST FOR RECIEVE (LSR-DR)
  122. MODRCVR    EQU    01H    ;VALUE WHEN READY
  123. MODDCDB    EQU    80H    ;CARRIER DETECT BIT (MSR-CTS)
  124. MODDCDA    EQU    80H    ;VALUE WHEN ACTIVE
  125. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR (LSR-PE)
  126. MODOVRE    EQU    02H    ;VALUE FOR OVERRUN ERROR (LSR-OR)
  127. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROE (LSR-FE)
  128. MODDATP    EQU    0E0H    ;DATA PORT, RECIEVE
  129. MODDATO    EQU    0E0H    ;DATA PORT, SEND
  130. BAUDRP    EQU    0E6H    ;BAUD RATE PORT (DALB IN LCR MUST=1)
  131. MODCTL2    EQU    0E6H    ;MODEM STATUS REGISTER (MSR)
  132. MODCTL1    EQU    0E3H    ;LINE CONTROL REGISTER (LCR)
  133.     ENDIF
  134. ;
  135.     IF    DCH
  136. MODCTLP    EQU    92H    ;D. C. HAYES VALUES
  137. MODSNDB    EQU    2    ;BIT TO TEST FOR SEND
  138. MODSNDR    EQU    2    ;VALUE WHEN READY
  139. MODRCVB    EQU    1    ;BIT TO TEST FOR RECEIVE
  140. MODRCVR    EQU    1    ;VALUE WHEN READY
  141. MODDCDB    EQU    40H    ;CARRIER DETECT BIT
  142. MODDCDA    EQU    40H    ;VALUE WHEN ACTIVE
  143. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR
  144. MODOVRE    EQU    10H    ;VALUE FOR OVERRUN ERROR
  145. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROR
  146. MODDATP    EQU    90H    ;DATA PORT IN PORT
  147. MODDATO    EQU    90H    ;DATA OUT PORT
  148. MODCTL2    EQU    91H    ;SECOND CTL PORT
  149.     ENDIF
  150. ;
  151. ; If you are using an external modem (not S-100 plug-in) change these
  152. ; equates for your modem port requirements
  153. ;
  154.     IF    EXTMOD
  155. MODCTLP    EQU    0C3H    ;PUT YOUR MODEM STATUS PORT HERE
  156. MODSNDB    EQU    10H    ;YOUR BIT TO TEST FOR SEND
  157. MODSNDR    EQU    10H    ;YOUR VALUE WHEN READY
  158. MODRCVB    EQU    01H    ;YOUR BIT TO TEST FOR RECEIVE
  159. MODRCVR    EQU    01H    ;YOUR VALUE WHEN READY
  160. MODDCDB    EQU    02H    ;CARRIER DETECT BIT
  161. MODDCDA    EQU    02H    ;VALUE WHEN ACTIVE
  162. MODDATP    EQU    0C0H    ;YOUR MODEM DATA IN PORT
  163. MODDATO    EQU    0C2H    ;YOUR MODEM DATA OUT PORT
  164. MODCTL2    EQU    0C1H    ;SECOND CONTROL/STATUS PORT.
  165.     ENDIF        ;END OF EXTERNAL MODEM EQUATES
  166. ;
  167. ;
  168. ;-----------------------------------------------------------------------
  169. ;
  170. ;            --- End of Options ---
  171. ;
  172. ;-----------------------------------------------------------------------
  173. ;
  174. ;
  175. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS (10 STANDARD)
  176. ;
  177. ;
  178. ; Define ASCII characters used
  179. ;
  180. SOH    EQU    1    ;START OF HEADER
  181. EOT    EQU    4    ;END OF TRANSMISSION
  182. ACK    EQU    6    ;ACKNOWLEDGE
  183. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  184. CRC    EQU    'C'    ;CRC REQUEST CHARACTER
  185. CAN    EQU    18H    ;CONTROL-X FOR CANCEL
  186. LF    EQU    10    ;LINEFEED
  187. CR    EQU    13    ;CARRIAGE RETURN
  188. ; 
  189.     IF    STDCPM
  190. BASE    EQU    0    ;CP/M BASE ADDRESS
  191.     ENDIF
  192. ;
  193.     IF    ALTCPM
  194. BASE    EQU    4200H    ;ALTERNATE CP/M BASE ADDRESS
  195.     ENDIF
  196. ;
  197.     ORG    BASE+100H
  198. ;
  199. ;
  200.     JMP    BEGIN
  201.  
  202. SPEED    DB    1    ;SPEED FOR FILE TIME TRANSFER WITHOUT AUTO-SET
  203. ;            ;0=110, 1=300, 2=450, 3=600, 4=710, 5=1200
  204. ;
  205. ; INIT PRIVATE STACK
  206. ;
  207.  
  208. BEGIN:
  209.     LXI    H,0        ;HL=0
  210.     DAD    SP        ;HL=STACK FROM CP/M
  211.     SHLD    STACK        ;   SAVE IT
  212.     LXI    SP,STACK     ;SP=MY STACK
  213.     CALL    ILPRT    ;PRINT:
  214.     DB    CR,LF
  215.     DB    'LMODEM V'
  216.     DB    VERSION+'0'    ;VERSION #
  217.     DB    '.',MODLEV+'0'    ;MODIFICATION LEVEL
  218.     DB    '[CRC capable]',CR,LF,0
  219.     MVI    A,'S'
  220.     PUSH    PSW        ;SAVE OPTION
  221. ;
  222. ;
  223. ; MOVE THE FILENAME FROM FCB2 TO MEMFCB
  224. ;
  225.     CALL    MOVEFCB
  226. ;
  227. ;
  228. ; GOBBLE UP GARBAGE CHARACTERS FROM THE LINE PRIOR TO RECEIVER OR SEND
  229. ;
  230.     IN    MODDATP
  231.     IN    MODDATP
  232. ;
  233.     POP    PSW        ;GET OPTION
  234.     IF    LOGCAL
  235.     PUSH    PSW        ;BUT SAVE IT
  236.     ENDIF
  237. ;
  238.     STA    OPTSAV        ;SAVE OPTION IN CASE WE LOSE CARRIER
  239.     JMP    SENDFIL
  240. ;
  241.     IF    LOGCAL
  242. ;
  243.     MACLIB SEQIO22
  244. ;
  245. BSIZE    EQU    80H
  246. FILERR    SET    EXIT
  247. BUFFERS    SET    DBUF
  248. ;
  249. ;
  250. ; THE FOLLOWING ALLOCATIONS ARE USED BY THE 'FILE' MACROS
  251. ;
  252. DEFAULT$USER:
  253.     DB    LASTUSR
  254. CUR$USER:
  255.     DB    0FFH
  256. DEFAULT$DISK:
  257.     DB    DEFDRV-'A'
  258. CUR$DISK:
  259.     DB    0FFH
  260. PGSIZE:
  261.     DW    0
  262. LOGCALL:
  263.     FILE    INFILE,CALLER,,LASTCALR,,BSIZE,,PUBLIC,TRUE
  264. ;
  265.     MVI    A,RECU
  266.     STA    DEFAULT$USER
  267. ;
  268.     FILE    APPEND,LOG,,LOG,SYS,BSIZE,,PUBLIC,TRUE
  269. ;
  270.     POP    PSW        ;GET OPTION
  271.     PUT    LOG        ;PUT IT OUT TO LOG
  272.     LDA    MSPEED        ;GET SPEED FACTOR
  273.     ADI    30H
  274.     PUT    LOG        ;PUT OUT A SINGLE LETTER CODE
  275.     LDA    PGSIZE        ;NOW THE PRGM SIZE IN MINS TRANSFER TIME
  276.     CALL    PNDEC
  277.     MVI    A,' '        ;BLANK
  278.     PUT    LOG
  279. ;
  280. ;
  281. ; LOG THE DRIVE AND USER AREA AS A PROMPT
  282. ;
  283.     LDA    FCB
  284.     ORA    A
  285.     JNZ    WDRV
  286.     MVI    C,25
  287.     CALL    @BDOS
  288.     INR    A
  289. WDRV:
  290.     ADI    'A'-1
  291.     PUT    LOG
  292.     MVI    C,32        ;NOW THE USER AREA (AS DECIMAL NUMBER)
  293.     MVI    E,0FFH
  294.     CALL    @BDOS
  295.     CALL    PNDEC
  296.     MVI    A,'>'        ;MAKE IT LOOK LIKE A PROMPT
  297.     PUT    LOG
  298.     LXI    H,FCB+1        ;NOW THE NAME OF THE FILE
  299.     MVI    B,11
  300.     CALL    PUTSTR
  301.     MVI    A,' '        ;BLANK
  302.     PUT    LOG
  303. CLOOP:
  304.     GET    CALLER        ;AND THE CALLER
  305.     CPI    EOF
  306.     JZ    QUIT
  307.     PUT    LOG
  308.     JMP    CLOOP
  309. ;.....
  310. ;
  311. ;
  312. PNDEC:
  313.     CPI    10        ;TWO COLUMN DECIMAL FORMAT ROUTINE
  314.     JC    ONE        ;ONE OR TWO DIGITS TO AREA #?
  315.     JMP    TWO
  316. ;...
  317. ;
  318. ;
  319. ONE:
  320.     PUSH    PSW
  321.     MVI    A,'0'
  322.     PUT    LOG
  323.     POP    PSW
  324. TWO:
  325.     MVI    H,0
  326.     MOV    L,A
  327.     CALL    DECOT
  328.     RET
  329. ;.....
  330. ;
  331. ;
  332. DECOT:
  333.     PUSH    B
  334.     PUSH    D
  335.     PUSH    H
  336.     LXI    B,-10
  337.     LXI    D,-1
  338. ;
  339. DECOT2:    DAD    B
  340.     INX    D
  341.     JC    DECOT2
  342.     LXI    B,10
  343.     DAD    B
  344.     XCHG
  345.     MOV    A,H
  346.     ORA    L
  347.     CNZ    DECOT
  348.     MOV    A,E
  349.     ADI    '0'
  350.     PUT    LOG
  351.     POP    H
  352.     POP    D
  353.     POP    B
  354.     RET
  355. ;.....
  356. ;
  357. ;
  358. PUTSTR:
  359.     MOV    A,M
  360.     PUSH    H
  361.     PUSH    B
  362.     PUT    LOG
  363.     POP    B
  364.     POP    H
  365.     INX    H
  366.     DCR    B
  367.     JNZ    PUTSTR
  368.     RET
  369. ;.....
  370. ;
  371. ;
  372. QUIT:    FINIS    LOG
  373.     JMP    EXIT
  374. ;.....
  375. ;
  376.     ENDIF            ;LOGCAL
  377. ;
  378. ;
  379. ;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  380. ;
  381. ;        SENDFIL: SENDS A MEMBER OF A LBR FILE
  382. ;
  383. ;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  384. ;
  385. ; The LBR member specified in the LMODEM command is transferred over the
  386. ; phone to another computer running MODEM with the "R" (receive) option.
  387. ; The data is sent one record at a time with headers and checksums, and
  388. ; re transmission on errors.  
  389. ;
  390. SENDFIL:
  391.     CALL    TRAP        ;CHECK FOR NO NAME OR AMBIG. NAME
  392.     CALL    OPENFIL     ;OPEN THE FILE
  393.     MVI    E,80        ;WAIT 80 SEC FOR INITIAL NAK
  394.     CALL    WAITNAK
  395. ;
  396. SENDLP:
  397.     CALL    RDSECT        ;READ A SECTOR    
  398.     JC    SENDEOF        ;SEND 'EOF' IF DONE
  399.     CALL    INCRSNO     ;BUMP SECTOR #
  400.     XRA    A        ;ZERO ERROR COUNT
  401.     STA    ERRCT
  402. ;
  403. SENDRPT:
  404.     CALL    SENDHDR     ;SEND A HEADER
  405.     CALL    SENDSEC     ;SEND DATA SECTOR
  406.     LDA    CRCFLG        ;GET CRC FLAG
  407.     ORA    A        ;CRC IN EFFECT?
  408.     CZ    SENDCRC        ;YES, SEND CRC
  409.     CNZ    SENDCKS     ;NO, SEND CKSUM
  410.     CALL    GETACK        ;GET THE ACK
  411.     JC    SENDRPT     ;REPEAT IF NO ACK
  412.     lhld    rcnt
  413.     mov    a,h
  414.     ora    l
  415.     jz    sendeof
  416.     dcx    h
  417.     shld    rcnt
  418.     JMP    SENDLP        ;LOOP UNTIL EOF
  419. ;.....
  420. ;
  421. ;
  422. ; FILE SENT, SEND EOT's
  423. ;
  424. SENDEOF:
  425.     MVI    A,EOT        ;SEND AN 'EOT'
  426.     CALL    SEND
  427.     CALL    GETACK        ;GET THE ACK
  428.     JC    SENDEOF     ;LOOP IF NO ACK
  429.     JMP    EXITLG        ;ALL DONE
  430. ;.....
  431. ;
  432. ;
  433. ;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  434. ;
  435. ;            SUBROUTINES
  436. ;
  437. ;* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
  438. ;
  439. ;
  440. ; ---> TRAP:  Check for no file name or ambiguous name
  441. ;
  442. TRAP    LXI    H,FCB+1     ;POINT TO FILE NAME
  443.     MOV    A,M        ;GET FIRST CHAR OF FILE NAME
  444.     CPI    ' '        ;ANY THERE?
  445.     JNZ    ATRAP        ;YES, CHECK FOR AMBIGOUS FILE NAME
  446.     CALL    ERXIT        ;PRINT MSG, EXIT
  447.     DB    CR,LF,'++No File Name Specified++',CR,LF
  448.     DB    'SYNTAX:',CR,LF
  449.     DB    'LMODEM <library> <member>',CR,LF
  450.     DB    'Where <library> is the file name for a '
  451.     DB    '.LBR file, i.e. "TEST.LBR" or "TEST"',CR,LF
  452.     DB    'and <member> is the FULL file name for a '
  453.     DB    'member of that LBR file.',CR,LF
  454.     DB    '(Find <member> with LDIR <library>).',CR,LF,'$'
  455. ;
  456. ATRAP:
  457.     MVI    B,11        ;11 CHARS TO CHECK
  458. TRLOOP:
  459.     MOV    A,M        ;GET CHAR FROM FCB
  460.     CPI    '?'        ;AMBIGUOUS?
  461.     JZ    TRERR        ;YES, EXIT WITH ERROR MSG
  462.     INX    H        ;POINT TO NEXT CHAR
  463.     DCR    B        ;ONE LESS TO GO
  464.     JNZ    TRLOOP        ;NOT DONE, CHECK SOME MORE
  465. ;
  466. ; Now see if he specified a LBR file.
  467. ; If not and if the type is empty, make it LBR.
  468. ;
  469.     LXI    H,FCB+9
  470.     MOV    A,M
  471.     CPI    ' '
  472.     JZ    NOXT        ;no extension in file name, make one.
  473.     RET            ;NO AMBIGUOUS NAME, RETURN
  474. ;
  475. ; NOXT: The file he specified didn't have an extension. Make it LBR.
  476. ;
  477. NOXT:    LXI    D,LBRTYP
  478.     MVI    B,3
  479. NXLP:    LDAX    D
  480.     MOV    M,A
  481.     INX    D
  482.     INX    H
  483.     DCR    B
  484.     JNZ    NXLP
  485.     RET
  486. ;
  487. LBRTYP:    DB    'LBR'
  488. ;
  489. TRERR:
  490.     CALL    ERXIT        ;PRINT MSG, EXIT
  491.     DB    CR,LF,'++Wild Card Options not allowed++',CR,LF,'$'
  492. ;
  493. ;
  494. ; ---> SENDHDR:  Send the sector header
  495. ;
  496. ; SEND: (SOH) (block #) (complemented block #)
  497. ;
  498. SENDHDR:
  499.     MVI    A,SOH        ;SEND
  500.     CALL    SEND        ;   SOH,
  501.     LDA    SECTNO        ;THEN SEND
  502.     CALL    SEND        ;   SECTOR #
  503.     LDA    SECTNO        ;THEN SECTOR #
  504.     CMA            ;   COMPLEMENTED
  505.     JMP    SEND        ;   SECTOR #
  506. ;.....
  507. ;
  508. ;
  509. ; ---> SENDSEC:  Send the data sector
  510. ;
  511. SENDSEC:
  512.     MVI    C,0        ;INIT CKSUM
  513.     CALL    CLRCRC        ;CLEAR THE CRC COUNTER
  514.     LXI    H,BASE+80H    ;POINT TO BUFFER
  515. SENDC:
  516.     MOV    A,M        ;GET A CHAR
  517.     CALL    SEND        ;SEND IT
  518.     INR    L        ;POINT TO NEXT CHAR
  519.     JNZ    SENDC        ;LOOP IF <100H
  520.     RET            ;FROM SENDSEC
  521. ;.....
  522. ;
  523. ;
  524. ; ---> SENDCKS:  Send the checksum
  525. ;
  526. SENDCKS:
  527.     MOV    A,C        ;SEND THE
  528.     JMP    SEND        ;   CHECKSUM
  529. ;.....
  530. ;
  531. ;
  532. ; ---> SENDCRC:  Send the two Cyclic Redundancy Check characters.  Call
  533. ;         FINCRC to calculate the CRC which will be in 'DE' upon
  534. ;         return.
  535. ;
  536. SENDCRC:
  537.     CALL    FINCRC        ;CALC THE CRC FOR THIS SECTOR
  538.     MOV    A,D        ;PUT FIRST CRC BYTE IN ACCUM
  539.     CALL    SEND        ;SEND IT
  540.     MOV    A,E        ;PUT SECOND CRC BYTE IN ACCUM
  541.     CALL    SEND        ;SEND IT
  542.     XRA    A        ;SET ZERO RETURN CODE
  543.     RET
  544. ;.....
  545. ;
  546. ;
  547. ; ---> GETACK:  Get the ACK on the sector
  548. ;
  549. ; Returns with carry clear if ACK received.  If an ACK is not received,
  550. ; the error count is incremented, and if less than "ERRLIM", carry is
  551. ; set and control returns.  If the error count is at "ERRLIM", the pro-
  552. ; gram aborts.
  553. ;
  554. GETACK:
  555.     MVI    B,10        ;WAIT 10 SECONDS MAX
  556.     CALL    RECVDG        ;RECV W/GARBAGE COLLECT
  557.     JC    GETATOT     ;TIMED OUT
  558.     CPI    ACK        ;OK? (CARRY OFF IF =)
  559.     RZ            ;YES, RET FROM GETACK
  560. ;
  561. ;
  562. ; Timeout or error on ACK - bump error count
  563. ;
  564. ACKERR:
  565.     LDA    ERRCT        ;GET COUNT
  566.     INR    A        ;BUMP IT
  567.     STA    ERRCT        ;SAVE BACK
  568.     CPI    ERRLIM        ;AT LIMIT?
  569.     RC            ;NOT AT LIMIT
  570.     CALL    ERXIT
  571.     DB    CR,LF,'++Can''t send sector - Aborting++',CR,LF,'$'
  572. ;
  573. ; 
  574. ; Timeout getting ACK
  575. ;
  576. GETATOT:
  577.     JMP    ACKERR    ;NO MSG
  578. ABORT:
  579.     LXI    SP,STACK
  580. ABORTL:
  581.     MVI    B,1        ;1 SECOND WITHOUT CHARACTERS
  582.     CALL    RECV
  583.     JNC    ABORTL        ;LOOP UNTIL SENDER DONE
  584.     MVI    A,CAN        ;CTL- X
  585.     CALL    SEND        ;STOP SENDING END
  586. ABORTW:
  587.     MVI    B,1        ;1 SECOND WITHOUT CHRACTERS
  588.     CALL    RECV
  589.     JNC    ABORTW        ;LOOP UNTIL SENDER DONE
  590.     MVI    A,' '        ;GET A SPACE...
  591.     CALL    SEND        ;TO CLEAR OUT CONTROL X
  592.     CALL    ERXIT        ;EXIT WITH ABORT MSG
  593.     DB    CR,LF,'++LMODEM Program Cancelled++',CR,LF,'$'
  594. ;
  595. ;
  596. ; ---> INCRSNO:  Increment sector #
  597. ;
  598. INCRSNO:
  599.     PUSH    H        ;INCREMENT RECORD NUMBER
  600.     LHLD    SECTNO
  601.     INX    H
  602.     SHLD    SECTNO
  603.     LXI    H,CONOUT    ;CHECK FOR OPTIONAL COUNT TO CONSOLE
  604.     MOV    A,H
  605.     ORA    L        ;IF 0, THEN NOPE, SO
  606.     POP    H
  607.     RZ            ;RETURN
  608. ;...
  609. ;
  610. ;
  611. DSPLY:
  612.     MVI    A,1
  613.     STA    CONONL        ;SET LOCAL ONLY
  614.     CALL    ILPRT
  615.     DB    CR,'Record #',0
  616.     LHLD    SECTNO
  617.     CALL    DECOUT
  618.     CALL    ILPRT
  619.     DB    '  (',0
  620.     CALL    DHXOUT
  621.     CALL    ILPRT
  622.     DB    'H)',0
  623.     ORA    A
  624.     STA    CONONL        ;RESET LOCAL ONLY
  625.     RET
  626. ;.....
  627. ;
  628. ; ---> OPENFIL:  Opens the file to be sent
  629. ;
  630. OPENFIL:
  631.     XRA    A        ;SET EXT & REC # TO 0 FOR PROPER OPEN
  632.     STA    FCBEXT
  633.     STA    FCBSNO
  634.     LXI    D,FCB        ;POINT TO FILE
  635.     MVI    C,OPEN        ;GET FUNCTION
  636.     CALL    BDOS        ;OPEN IT
  637.     INR    A        ;OPEN OK?
  638.     JNZ    OPENOK        ;   YES
  639.     CALL    ERXIT        ;   NO, ABORT
  640.     DB    CR,LF,'++Unable to open the file++',CR,LF,'$'
  641. ;
  642. ;
  643. ; Check for distribution-protected file
  644. ;
  645. OPENOK:
  646.     LDA    FCB+1        ;FIRST CHAR OF FILE NAME
  647.     ANI    80H        ;CHECK BIT 7
  648.     JNZ    OPENOT        ;IF ON, FILE CAN'T BE SENT
  649.     LDA    FCB+2        ;ALSO CHECK "F2" FOR TAB
  650.     ANI    80H        ;IS IS SET?
  651.     JZ    OPENOK2        ;IF NOT, OK TO SEND FILE
  652. OPENOT:
  653.     CALL    ERXIT    ;EXIT W/MESSAGE
  654.     DB    CR,LF,'++File is Not for Distribution, Sorry++'
  655.     DB    CR,LF,'$'
  656. OPENOK2:
  657.     LXI    D,80H
  658.     MVI    C,STDMA
  659.     CALL    BDOS
  660.     MVI    C,READ
  661.     LXI    D,FCB
  662.     CALL    BDOS
  663.     LHLD    8EH
  664.     SHLD    DIRSZ
  665.     LXI    D,MEMFCB
  666.     LDAX    D
  667.     CPI    ' '
  668.     JNZ    MOK
  669.     CALL    ERXIT
  670.     DB    '++No member name specified!++',CR,LF,'$'
  671. ;
  672. MOK:    LXI    H,80H
  673.     MOV    A,M
  674.     ORA    A
  675.     JZ    CKDIR        ;check directory present?
  676. BADLBR:    CALL    ERXIT
  677.     DB    '++The file specified is not recognized '
  678.     DB    'as LBR file!++',CR,LF,'$'
  679. ;
  680. ; CKDIR - check to see if there indeed is a LBR file
  681. ;      directory and barf if not!
  682. ;
  683. CKDIR:    MVI    B,11        ;len of file name
  684.     MVI    A,' '        ;space
  685.     INX    H
  686. CKDLP:    CMP    M
  687.     JNZ    BADLBR
  688.     DCR    B
  689.     INX    H
  690.     JNZ    CKDLP
  691. ;
  692. ; The first entry in the LBR directory is indeed blank.
  693. ; Now see if the directory size is >0
  694. ;
  695.     MOV    D,M
  696.     INX    H
  697.     MOV    A,M
  698.     ORA    D
  699.     JNZ    BADLBR
  700.     INX    H
  701.     MOV    A,M
  702.     INX    H
  703.     ORA    M
  704.     JZ    BADLBR
  705.     LXI    H,80H
  706. ;
  707. ; The next routine checks the LBR directory for the
  708. ; specified member name 1 sector at a time.
  709. ;
  710. CMLP:    MOV    A,M
  711.     ORA    A
  712.     MVI    B,11
  713.     INX    H
  714.     JNZ    NOMTCH
  715. CKLP:    LDAX    D
  716.     CMP    M
  717.     JNZ    NOMTCH
  718.     INX    H
  719.     INX    D
  720.     DCR    B
  721.     JNZ    CKLP
  722.     MOV    E,M
  723.     INX    H
  724.     MOV    D,M
  725.     XCHG
  726.     SHLD    INDEX
  727.     XCHG
  728.     INX    H
  729.     MOV    E,M
  730.     INX    H
  731.     MOV    D,M
  732.     XCHG
  733.     DCX    H
  734.     SHLD    RCNT
  735.     LHLD    INDEX
  736.     DAD    H
  737.     MOV    A,H
  738.     STA    FCBEXT
  739.     MOV    A,L
  740.     RRC
  741.     STA    FCBSNO
  742.     LXI    D,FCB
  743.     MVI    C,OPEN
  744.     CALL    BDOS
  745.     CPI    0FFH
  746.     JZ    WHAT
  747.     JMP    OPENOK3
  748. ;
  749. WHAT:    CALL    ERXIT
  750.     DB    '++Impossible error - notify SYSOP++',CR,LF,'$'
  751. ;
  752. NOMTCH:    INX    H
  753.     DCR    B
  754.     JNZ    NOMTCH
  755.     LXI    B,20
  756.     DAD    B
  757.     LXI    D,MEMFCB
  758.     MOV    A,H
  759.     ORA    A
  760.     JZ    CMLP
  761.     LHLD    DIRSZ
  762.     MOV    A,H
  763.     ORA    L
  764.     JZ    NFOUND
  765.     DCX    H
  766.     SHLD    DIRSZ
  767.     MVI    C,READ
  768.     LXI    D,FCB
  769.     CALL    BDOS
  770.     LXI    H,80H
  771.     LXI    D,MEMFCB
  772.     JMP    CMLP
  773. ;
  774. NFOUND:    CALL    ERXIT
  775.     DB    '++Member file not in library++',CR,LF
  776.     DB    'Run LDIR on the file and try again.',CR,LF,'$'
  777. ;
  778. OPENOK3:
  779.     CALL    ILPRT    ;PRINT:
  780.     DB    'File Open:  ',0
  781.     LHLD    RCNT        ;GET RECORD COUNT
  782.     INX    H
  783.     CALL    DECOUT        ;PRINT DECIMAL NUMBER OF RECORDS
  784.     CALL    ILPRT
  785.     DB    ' (',0
  786.     CALL    DHXOUT        ;NOW PRINT SIZE IN HEX
  787.     CALL    ILPRT
  788.     DB    ' Hex) Records',CR,LF
  789.     DB    'Send Time:  ',0
  790.  
  791.     IF    LSPEED
  792.     LDA    MSPEED        ;GET THE SPEED INDICATOR
  793.     ENDIF
  794. ;
  795.     IF    NOT LSPEED
  796.     LDA    SPEED        ;DEFAULT TO PRESET SPEED AT 0103H
  797.     ENDIF
  798. ;    
  799.     LXI    D,0
  800.     MOV    E,A        ;SET UP FOR TABLE ACCESS
  801.     LXI    H,BTABLE    ;POINT TO BAUD FACTOR TABLE
  802.     DAD    D        ;INDEX TO PROPER FACTOR
  803.     MOV    A,M        ;FACTOR IN 'A'
  804. ;    
  805.     LHLD    RCNT        ;GET NUMBER OF RECORDS
  806.     INX    H
  807.     CALL    DIVHLA        ;DIVIDE HL BY VALUE IN A (RECORDS/MIN)    
  808.     PUSH    H
  809. ;
  810.     IF    LOGCAL
  811.     SHLD    PGSIZE
  812.     ENDIF
  813. ;
  814.     MVI    H,0
  815.     CALL    DECOUT        ;PRINT DECIMAL NUMBER OF MINUTES
  816.     CALL    ILPRT
  817.     DB    ' mins, ',0
  818.     LXI    H,SECTBL    ;POINT TO DIVISORS FOR SECONDS CALC.
  819.     LXI    D,0
  820. ;
  821.     IF    LSPEED
  822.     LDA    MSPEED        ;GET INDEX FOR BAUD RATE
  823.     ENDIF
  824. ;
  825.     IF    NOT LSPEED
  826.     LDA    SPEED
  827.     ENDIF
  828. ;
  829.     MOV    E,A
  830.     DAD    D        ;INDEX INTO TABLE
  831.     MOV    A,M        ;GET MULTIPLIER
  832.     POP    H        ;GET REMAINDER
  833.     CALL    MULHA        ;MULTIPLY 'H' BY 'A'
  834.     CALL    SHFTHL
  835.     CALL    SHFTHL
  836.     CALL    SHFTHL
  837.     CALL    SHFTHL    
  838. ;
  839.     MVI    H,0
  840.     CALL    DECOUT
  841. ;
  842.     IF    LSPEED
  843.     LDA    MSPEED        ;GET BAUD RATE CODE
  844.     ENDIF
  845. ;
  846.     IF    NOT LSPEED
  847.     LDA    SPEED        ;DEFAULT TO PRESET SPEED AT 0103H
  848.     ENDIF
  849. ;
  850.     CPI    0        ;110 BAUD?
  851.     JNZ    MS300        ;NO-CHECK 300
  852. MS110:
  853.     CALL    ILPRT
  854.     DB    ' secs at 110 Baud',CR,LF,0
  855.     JMP    MSCTLX
  856. ;...
  857. ;
  858. ;
  859. MS300:
  860.     CPI    1        ;300 BAUD?
  861.     JNZ    MS450        ;NO-CHECK 450
  862.     CALL    ILPRT
  863.     DB    ' secs at 300 Baud',CR,LF,0
  864.     JMP    MSCTLX
  865. ;...
  866. ;
  867. ;
  868. MS450
  869.     CPI    2        ;450 BAUD?
  870.     JNZ    MS600        ;NO-CHECK 600
  871.     CALL    ILPRT
  872.     DB    ' secs at 450 Baud',CR,LF,0
  873.     JMP    MSCTLX
  874. ;.....
  875. ;
  876. ;
  877. MS600:
  878.     CPI    3        ;600 BAUD?
  879.     JNZ    MS710        ;NO-CHECK 710
  880.     CALL    ILPRT
  881.     DB    ' secs at 600 Baud',CR,LF,0
  882.     JMP    MSCTLX
  883. ;...
  884. ;
  885. ;
  886. MS710:
  887.     CPI    4        ;710 BAUD?
  888.     JNZ    MS1200        ;NO-MUST BE 1200
  889.     CALL    ILPRT
  890.     DB    ' secs at 710 Baud',CR,LF,0
  891.     JMP    MSCTLX
  892. ;...
  893. ;
  894. ;
  895. MS1200:
  896.     CALL    ILPRT        ;MUST BE 1200 - NO OTHERS SUPPORTED
  897.     DB    ' secs at 1200 Baud',CR,LF,0
  898. ;...
  899. ;
  900. ;
  901. MSCTLX    CALL    ILPRT
  902.     DB    'Use CTL-X to Cancel',CR,LF,0
  903.     RET
  904. ;...
  905. ;
  906. ;
  907. BTABLE:    DB    5,13,19,25,29,49,0
  908. SECTBL:    DB    192,74,51,38,33,20,0
  909. ;...
  910. ;
  911. ;
  912. ; ---> DIVHL-A:  Divides 'HL' by value in 'A',
  913. ;     UPON EXIT: L=QUOTIENT,H=REMAINDER
  914. ;
  915. DIVHLA:
  916.     PUSH    B
  917.     MVI    B,8        ;SHIFT FACTOR TO 'B'
  918.     MOV    C,A        ;DIVISOR TO 'C'
  919. DIV2:
  920.     XRA    A        ;CLEAR CARRY FLAG AND ACCUMULATOR
  921.     DAD    H
  922.     MOV    A,H
  923.     SUB    C
  924.     JM    DIV3        ;DONT BORROW ON NEG RESULTS
  925.     MOV    H,A
  926.     MOV    A,L
  927.     ORI    1        ;BORROW 1
  928.     MOV    L,A
  929. DIV3:
  930.     DCR    B
  931.     JNZ    DIV2
  932.     POP    B
  933.     RET
  934. ;...
  935. ;
  936. ;
  937. ; ---> MULHA:  Multiply the value in 'H' by the value in 'A'
  938. ;     Return with answer in 'HL'.
  939. ;
  940. MULHA:
  941.     MOV    B,A        ;PUT LOOP COUNT IN 'B'
  942.     MVI    D,0
  943.     MOV    E,H
  944.     MOV    L,H
  945.     MVI    H,0
  946. MULLP:
  947.     DCR    B
  948.     RZ
  949.     DAD    D
  950.     JMP    MULLP
  951.     RET
  952. ;
  953. ;
  954. ; Shift the 'HL' pair one bit to the right
  955. ;
  956. SHFTHL:
  957.     MOV    A,L
  958.     RAR
  959.     MOV    L,A
  960.     ORA    A        ;CLEAR THE CARRY BIT
  961.     MOV    A,H
  962.     RAR
  963.     MOV    H,A
  964.     RNC
  965.     MVI    A,80h
  966.     ORA    L
  967.     MOV    L,A
  968.     RET
  969. ;.....
  970. ;
  971. ; ---> DECOUT:  Decimal output routine
  972. ;
  973. DECOUT:
  974.     PUSH    B
  975.     PUSH    D
  976.     PUSH    H
  977.     LXI    B,-10
  978.     LXI    D,-1
  979. DECOU2:
  980.     DAD    B
  981.     INX    D
  982.     JC    DECOU2
  983.     LXI    B,10
  984.     DAD    B
  985.     XCHG
  986.     MOV    A,H
  987.     ORA    L
  988.     CNZ    DECOUT
  989.     MOV    A,E
  990.     ADI    '0'
  991.     CALL    CTYPE
  992.     POP    H
  993.     POP    D
  994.     POP    B
  995.     RET
  996. ;.....
  997. ;
  998. ;
  999. ; ---> DHXOUT: Double precision hex output routine.
  1000. ;     Call with hex value in 'HL'.
  1001. ;
  1002. DHXOUT:
  1003.     PUSH    H        ;SAVE H,L
  1004.     PUSH    PSW        ;SAVE A
  1005.     MOV    A,H        ;GET MS BYTE
  1006.     CALL    HEXO        ;OUTPUT HIGH ORDER BYTE
  1007.     MOV    A,L        ;GET LS BYTE
  1008.     CALL    HEXO        ;OUTPUT LOW ORDER BYTE
  1009.     POP    PSW        ;RESTORE A
  1010.     POP    H        ;RESTORE H,L
  1011.     RET            ;RETURN TO CALLER
  1012. ;
  1013. ;
  1014. ; ---> RDSECT:  Reads a sector
  1015. ;
  1016. ; For speed, this routine buffers up 16 sectors at a time.
  1017. ;
  1018. RDSECT:    LDA    SECNBF        ;GET # SECT IN BUFF
  1019.     DCR    A        ;DECREMENT
  1020.     STA    SECNBF        ;   IT
  1021.     JM    RDBLOCK     ;EXHAUSTED?  NEED MORE
  1022.     LHLD    SECPTR        ;GET POINTER
  1023.     LXI    D,BASE+80H    ;TO DATA
  1024.     CALL    MOVE128     ;MOVE TO BUFFER
  1025.     SHLD    SECPTR        ;SAVE BUFFER POINTER
  1026.     RET            ;FROM "READSEC"
  1027. ;.....
  1028. ;
  1029. ;
  1030. ; Buffer is empty - read in another block of 16
  1031. ;
  1032. RDBLOCK:
  1033.     LDA    EOFLG        ;GET 'EOF' FLAG
  1034.     CPI    1        ;IS IT SET?
  1035.     STC            ;TO SHOW 'EOF'
  1036.     RZ            ;GOT 'EOF'
  1037.     MVI    C,0        ;SECTORS IN BLOCK
  1038.     LXI    D,DBUF        ;TO DISK BUFFER
  1039. ;
  1040. RDSECLP:
  1041.     PUSH    B
  1042.     PUSH    D
  1043.     MVI    C,STDMA     ;SET DMA ADDRESS
  1044.     CALL    BDOS
  1045.     LXI    D,FCB
  1046.     MVI    C,READ
  1047.     CALL    BDOS
  1048.     POP    D
  1049.     POP    B
  1050.     ORA    A        ;READ OK?
  1051.     JZ    RDSECOK     ;YES
  1052.     DCR    A        ;'EOF'?
  1053.     JZ    REOF        ;GOT 'EOF'
  1054. ;
  1055. ;
  1056. ; Read error
  1057. ;
  1058.     CALL    ERXIT
  1059.     DB    CR,LF,'++File Read Error++',CR,LF,'$'
  1060. ;
  1061. RDSECOK:
  1062.     INR    C
  1063.     LXI    H,80H        ;ADD LENGTH OF ONE SECTOR
  1064.     DAD    D        ;   TO NEXT BUFF
  1065.     XCHG            ;BUFF TO DE
  1066.     MOV    A,C        ;GET COUNT
  1067.     CPI    16        ;DONE?
  1068.     JZ    RDBFULL     ;   YES, BUFF IS FULL
  1069.     JMP    RDSECLP     ;READ MORE
  1070. ;...
  1071. ;
  1072. ;
  1073. REOF:
  1074.     MVI    A,1
  1075.     STA    EOFLG        ;SET EOF FLAG
  1076.     MOV    A,C
  1077. ;
  1078. ;
  1079. ; Buffer is full, or got EOF
  1080. ;
  1081. RDBFULL:
  1082.     STA    SECNBF        ;STORE SECTOR COUNT
  1083.     LXI    H,DBUF        ;INIT BUFFER POINTEAR
  1084.     SHLD    SECPTR
  1085.     LXI    D,BASE+80H    ;RESET DMA ADDRESS 
  1086.     MVI    C,STDMA
  1087.     CALL    BDOS
  1088.     JMP    RDSECT        ;PASS SECT TO CALLER
  1089. ;
  1090. ;---->    RECV:  Receive a character
  1091. ;
  1092. ; Timeout time is in B, in seconds.  Entry via "RECVDG" deletes garbage
  1093. ; characters on the line.  For example, having just sent a sector, 
  1094. ; calling RECVDG will delete any line-noise-induced characters "long"
  1095. ; before the ACK/NAK would be received.
  1096. ;
  1097. RECVDG:
  1098.     IN    MODDATP     ;GET A CHAR
  1099.     IN    MODDATP     ;   TOTALLY PURGE UART
  1100. RECV:
  1101.     PUSH    D        ;SAVE
  1102. ;
  1103.     IF    FASTCLK     ;4MHZ?
  1104.     MOV    A,B        ;GET TIME REQUEST
  1105.     ADD    A        ;DOUBLE IT
  1106.     MOV    B,A        ;NEW TIME IN B
  1107.     ENDIF
  1108. MSEC:
  1109.     LXI    D,50000     ;1 SECOND DCR COUNT
  1110. ;
  1111.     IF    NOT DCH
  1112. MWTI:
  1113.     IN    MODCTLP     ;CHECK STATUS
  1114.     ENDIF
  1115. ;
  1116.     IF    DCH
  1117. MWTI:
  1118.     IN    MODCTL2     ;CHECK STATUS
  1119.     ENDIF
  1120. ;
  1121.     IF    PMMI AND FRNTPNL
  1122.     OUT    PANEL        ;DISPLAY STATUS ON PANEL LIGHTS
  1123.     ENDIF
  1124. ;
  1125.     ANI    MODRCVB     ;ISOLATE BIT
  1126.     CPI    MODRCVR     ;READY?
  1127.     JZ    MCHAR        ;GOT CHAR
  1128.     DCR    E        ;COUNT
  1129.     JNZ    MWTI        ;   DOWN
  1130.     DCR    D        ;   FOR
  1131.     JNZ    MWTI        ;   TIMEOUT
  1132.     DCR    B        ;MORE SECONDS?
  1133.     JNZ    MSEC        ;YES, WAIT
  1134. ;
  1135. ;
  1136. ; Test for the presence of carrier - if none, go to CARCK and continue
  1137. ; testing for 15 seconds. If carrier returns, continue. If is doesn't
  1138. ; return, exit.
  1139. ;
  1140.     IF    EXTMOD OR H8 OR DCH
  1141.     IN    MODCTL2        ;READ MODEM STATUS
  1142.     ENDIF
  1143. ;
  1144.     IF    PMMI
  1145.     IN    BAUDRP        ;READ MODEM STATUS
  1146.     ENDIF
  1147. ;
  1148.     IF    PMMI AND FRNTPNL
  1149.     OUT    PANEL        ;DISPLAY STATUS ON PANEL LIGHTS
  1150.     ENDIF
  1151. ;
  1152.     ANI    MODDCDB        ;CARRIER DETECT MASK
  1153.     CPI    MODDCDA        ;IS IT STILL ON?
  1154.     CNZ    CARCK        ;IF NOT, TEST FOR 15 SECONDS
  1155. ;
  1156. ; Modem timed out receiving - but carrier still on.
  1157. ;
  1158.     POP    D        ;RESTORE D,E
  1159.     STC            ;CARRY SHOWS TIMEOUT
  1160.     RET
  1161. ;.....
  1162. ;
  1163. ;
  1164. ; Got character from modem.  Check to see if there was a framing error,
  1165. ; overrun, or parity error.
  1166. ;
  1167. MCHAR:
  1168.     IF    PMMI OR H8
  1169.     IN    MODCTLP        ;GET MODEM STATUS
  1170.     ENDIF
  1171. ;
  1172.     IF    DCH
  1173.     IN    MODCTL2        ;GET MODEM STATUS
  1174.     ENDIF
  1175. ;
  1176.     IF    PMMI OR H8 OR DCH
  1177.     MOV    D,A        ;SAVE STATUS
  1178.     ANI    MODFRME        ;FRAMING ERROR?
  1179.     CPI    MODFRME
  1180.     JNZ    MCHAR2        ;NO, CHECK FOR OVERRUN
  1181.     LDA    ERRCDE        ;GET RECV ERR CODE
  1182.     ORI    MODFRME        ;TURN ON RECV ERR CODE
  1183.     STA    ERRCDE        ;PUT IT BACK
  1184. MCHAR2:
  1185.     MOV    A,D        ;RESTORE MODEM STATUS
  1186.     ANI    MODOVRE        ;OVERRUN?
  1187.     CPI    MODOVRE
  1188.     JNZ    MCHAR3        ;NO, CHECK FOR PARITY ERROR
  1189.     LDA    ERRCDE
  1190.     ORI    MODOVRE        ;TURN ON RECV ERR CODE
  1191.     STA    ERRCDE
  1192. MCHAR3:
  1193.     MOV    A,D        ;RESTORE MODEM STATUS
  1194.     ANI    MODPARE        ;PARITY ERROR?
  1195.     CPI    MODPARE
  1196.     JNZ    MCHAR4        ;NO, GET DATA CHAR
  1197.     LDA    ERRCDE
  1198.     ORI    MODPARE
  1199.     STA    ERRCDE
  1200. MCHAR4:
  1201.     ENDIF            ;PMMI OR H8 OR DCH
  1202. ;
  1203. ;
  1204. ; Get data char
  1205. ;
  1206.     IN    MODDATP     ;READ THE CHAR
  1207.     POP    D        ;RESTORE 'DE'
  1208. ;
  1209. ;
  1210. ; Calculate checksum and CRC
  1211. ;
  1212.     PUSH    PSW        ;SAVE THE CHAR
  1213.     CALL    UPDCRC        ;CALC CRC
  1214.     ADD    C        ;ADD TO CHECKSUM
  1215.     MOV    C,A        ;SAVE CHECKSUM
  1216.     POP    PSW        ;RESTORE CHAR
  1217.     ORA    A        ;CARRY OFF: NO ERROR
  1218.     RET            ;FROM "RECV"
  1219. ;.....
  1220. ;
  1221. ;
  1222. ; CARCK - common 15 second carrier test for RECV and SEND.  If carrier
  1223. ; returns within 15 seconds, normal program execution continues.  Else,
  1224. ; it will abort to CP/M via EXIT.
  1225. ;
  1226. CARCK:
  1227.     MVI    E,150        ;VALUE FOR 15 SECOND DELAY
  1228. CARCK1:
  1229.     CALL    DELAY        ;KILL .1 SECONDS
  1230. ;
  1231.     IF    EXTMOD OR H8 OR DCH
  1232.     IN    MODCTL2        ;READ MODEM STATUS
  1233.     ENDIF
  1234. ;
  1235.     IF    PMMI
  1236.     IN    BAUDRP        ;READ MODEM STATUS
  1237.     ENDIF
  1238. ;
  1239.     IF    PMMI AND FRNTPNL
  1240.     OUT    PANEL        ;DISPLAY STATUS
  1241.     ENDIF
  1242. ;
  1243.     ANI    MODDCDB        ;CARRIER DETECT MASK
  1244.     CPI    MODDCDA        ;IS IT STILL ON?
  1245.     RZ            ;RETURN IF CARRIER ON
  1246.     DCR    E        ;HAS 15 SECONDS EXPIRED?
  1247.     JNZ    CARCK1        ;IF NOT, CONTINUE TESTING
  1248.     JMP    EXIT        ;ELSE, ABORT TO CP/M.
  1249. ;
  1250. ;
  1251. ; DELAY - 100 millisecond delay.
  1252. ;
  1253. DELAY:
  1254.     PUSH    B        ;SAVE B,C
  1255. ;
  1256.     IF    FASTCLK        ;IF 4MHZ CLOCK
  1257.     LXI    B,16667        ;VALUE FOR 100MS DELAY
  1258.     ENDIF
  1259. ;
  1260.     IF    NOT FASTCLK
  1261.     LXI    B,8334        ;VALUE FOR 100MS DELAY
  1262.     ENDIF
  1263. DELAY2:
  1264.     DCX    B        ;UPDATE COUNT
  1265.     MOV    A,B        ;GET MS BYTE
  1266.     ORA    C        ;COUNT = ZERO?
  1267.     JNZ    DELAY2        ;IF NOT, CONTINUE
  1268.     POP    B        ;RESTORE B,C
  1269.     RET            ;RETURN TO CARCK1.
  1270. ;.....
  1271. ;
  1272. ;
  1273. ; ---> SEND:  Send a character to the modem
  1274. ;
  1275. SEND:
  1276.     PUSH    PSW        ;SAVE THE CHARACTER
  1277.     CALL    UPDCRC        ;CALC THE CRC
  1278.     ADD    C        ;CALC CKSUM
  1279.     MOV    C,A        ;SAVE CKSUM
  1280. ;
  1281.     IF    NOT DCH
  1282. SENDW:
  1283.     IN    MODCTLP     ;GET STATUS
  1284.     ENDIF
  1285. ;
  1286.     IF    DCH
  1287. SENDW:
  1288.     IN    MODCTL2     ;GET STATUS
  1289.     ENDIF
  1290. ;
  1291.     IF    PMMI AND FRNTPNL
  1292.     OUT    PANEL        ;DISPLAY STATUS
  1293.     ENDIF
  1294. ;
  1295.     ANI    MODSNDB     ;ISOLATE READY BIT
  1296.     CPI    MODSNDR     ;READY?
  1297.     JZ    SENDR        ;   YES, GO SEND
  1298. ;
  1299. ;
  1300. ; Xmit status not ready, so test for carrier before looping - if lost,
  1301. ; go to CARCK and give it up to 15 seconds to return.  If it doesn't,
  1302. ; return abort via EXIT.
  1303. ;
  1304.     PUSH    D        ;SAVE 'DE'
  1305. ;
  1306.     IF    EXTMOD OR H8 OR DCH
  1307.     IN    MODCTL2        ;READ MODEM STATUS
  1308.     ENDIF
  1309. ;
  1310.     IF    PMMI
  1311.     IN    BAUDRP        ;READ MODEM STATUS
  1312.     ENDIF
  1313. ;
  1314.     IF    PMMI AND FRNTPNL
  1315.     OUT    PANEL        ;DISPLAY STATUS
  1316.     ENDIF
  1317. ;
  1318.     ANI    MODDCDB        ;CARRIER DETECT MASK
  1319.     CPI    MODDCDA        ;IS IT STILL ON?
  1320.     CNZ    CARCK        ;IF NOT, CONTINUE TESTING IT
  1321.     POP    D        ;RESTORE D,E
  1322.     JMP    SENDW        ;ELSE, WAIT FOR XMIT READY.
  1323. ;.....
  1324. ;
  1325. ;
  1326. ; Xmit status ready, carrier still on - send the data.
  1327. ;
  1328. SENDR:
  1329.     POP    PSW        ;GET CHAR
  1330.     OUT    MODDATP     ;OUTPUT IT
  1331.     RET            ;FROM "SEND"
  1332. ;
  1333. ; ---> WAITNAK:  Waits for initial NAK
  1334. ;
  1335. ; To ensure no data is sent until the receiving program is ready, this
  1336. ; routine waits for the first timeout-NAK or the letter 'C' for CRC
  1337. ; from the receiver.  If CRC is in effect, then Cyclic Redundancy Checks
  1338. ; are used instead of checksums.  'E' contains the number of seconds to
  1339. ; wait.
  1340. ;
  1341. ; If the first character received is a CAN (CTL-X) then the send will be
  1342. ; aborted as though it had timed out.
  1343. ;
  1344. WAITNAK:
  1345.     MVI    B,1        ;TIMEOUT DELAY
  1346.     CALL    RECV        ;DID WE GET
  1347.     CPI    NAK        ;   A NAK?
  1348.     RZ            ;YES, SEND BLOCK
  1349.     CPI    CRC        ;CRC INDICATED?
  1350.     JZ    WAITCRC        ;YES, GO PUT CRC IN EFFECT
  1351.     CPI    CAN        ;WAS IT A CANCEL (CTL-X)?
  1352.     JZ    ABORT        ;YES, ABORT
  1353.     DCR    E        ;80 TRIES?
  1354.     JZ    ABORT        ;YES, ABORT
  1355.     JMP    WAITNAK     ;NO, LOOP
  1356. ;.....
  1357. ;
  1358. ;
  1359. ; ---> WAITCRC:  Turn on CRC Flag
  1360. ;
  1361. WAITCRC:
  1362.     XRA    A        ;ZERO ACCUM
  1363.     STA    CRCFLG        ;TURN ON CRC OPT
  1364.     RET
  1365. ;.....
  1366. ;
  1367. ;
  1368. ; ---> MOVEFCB:  Moves FCB(2) to MEMFCB
  1369. ;
  1370. ; Saves the member file name into MEMFCB
  1371. ;
  1372. MOVEFCB:
  1373.     LXI    H,FCB+16    ;FROM
  1374.     LXI    D,MEMFCB-1    ;TO
  1375.     MVI    B,16        ;LEN
  1376.     CALL    MOVE        ;DO THE MOVE
  1377.     XRA    A        ;GET 0
  1378.     STA    FCBSNO        ;ZERO SECTOR #
  1379.     STA    FCBEXT        ;   AND EXTENT
  1380.     RET
  1381. ;.....
  1382. ;
  1383. ;
  1384. CTYPE:
  1385.     PUSH    B        ;SAVE ALL REGISTERS
  1386.     PUSH    D
  1387.     PUSH    H
  1388.     PUSH    PSW        ;SAVE THE CHARACTER TEMPORARILY
  1389.     LDA    CONONL        ;LOCAL ONLY?
  1390.     ORA    A
  1391.     JNZ    CLTYP        ;YES, TO TO BIOS OUT
  1392.     POP    PSW        ;ELSE GET THE CHARACTER BACK
  1393.     MOV    E,A        ;CHARACTER TO 'E'
  1394.     MVI    C,WRCON     ;WRITE TO CONSOLE
  1395.     CALL    BDOS        ;PRINT THE CHARACTER
  1396.     POP    H        ;RESTORE
  1397.     POP    D        ;   ALL
  1398.     POP    B        ;   REGS
  1399.     RET            ;FROM "CTYPE"
  1400. ;...
  1401. ;
  1402. ;
  1403. CLTYP:
  1404.     POP    PSW        ;GET THE CHARACTER BACK
  1405.     MOV    C,A        ;BIOS NEEDS IT IN 'C'
  1406.     CALL    CONOUT        ;DO BIOS CALL
  1407.     POP    H        ;ALL THIS
  1408.     POP    D        ;   IS FROM
  1409.     POP    B        ;   CTYPE ROUTINE
  1410.     RET
  1411. ;.....
  1412. ;
  1413. ;
  1414. HEXO:
  1415.     PUSH    PSW        ;SAVE FOR RIGHT DIGIT
  1416.     RAR            ;RIGHT
  1417.     RAR            ;   JUSTIFY
  1418.     RAR            ;   LEFT
  1419.     RAR            ;   DIGIT
  1420.     CALL    NIBBL        ;PRINT LEFT DIGIT
  1421.     POP    PSW        ;RESTORE RIGHT
  1422. NIBBL:
  1423.     ANI    0FH        ;ISOLATE DIGIT
  1424.     CPI    10        ;IS IT <10?
  1425.     JC    ISNUM        ;YES, NOT ALPHA
  1426.     ADI    7        ;ADD ALPHA BIAS
  1427. ISNUM:
  1428.     ADI    '0'        ;MAKE PRINTABLE
  1429.     JMP    CTYPE        ;   THEN TYPE IT
  1430. ;.....
  1431. ;
  1432. ;
  1433. ; ---> ILPRT:  Inline print of message
  1434. ;
  1435. ; The call to ILPRT is followed by a message, binary 0 for its end.
  1436. ;
  1437. ILPRT:
  1438.     XTHL            ;SAVE HL, GET HL=MSG
  1439. ;
  1440. ILPLP:
  1441.     MOV    A,M        ;GET CHAR
  1442.     ORA    A        ;END OF MSG?
  1443.     JZ    ILPRET        ;   YES, RETURN
  1444.     CALL    CTYPE        ;TYPE THE MSG
  1445.     INX    H        ;TO NEXT CHAR
  1446.     JMP    ILPLP        ;LOOP
  1447. ;...
  1448. ;
  1449. ILPRET:
  1450.     XTHL            ;RESTORE HL
  1451.     RET            ;PAST MSG
  1452. ;.....
  1453. ;
  1454. ;
  1455. EXITLG:                ; SPECIAL LOG CALLER EXIT
  1456.     IF    LOGCAL
  1457.     JMP    LOGCALL
  1458.     ENDIF
  1459. ;
  1460.     JMP    EXIT
  1461. ;.....
  1462. ;
  1463. ;
  1464. ; ---> ERXIT:  Exit printing message following call
  1465. ;
  1466. ERXIT:
  1467.     POP    D        ;GET MESSAGE
  1468.     MVI    C,PRINT     ;GET BDOS FNC
  1469.     CALL    BDOS        ;PRINT MESSAGE
  1470. EXIT:
  1471.     LHLD    STACK        ;GET ORIGINAL STACK
  1472.     SPHL            ;RESTORE IT
  1473. ;
  1474.     RET            ;--EXIT-- TO CP/M
  1475. ;
  1476. ;
  1477. ; Move 128 characters from 'HL' to 'DE' length in 'B'
  1478. ;
  1479. MOVE128:
  1480.     MVI    B,128        ;SET MOVE COUNT
  1481. MOVE:
  1482.     MOV    A,M        ;GET A CHAR
  1483.     STAX    D        ;STORE IT
  1484.     INX    H        ;TO NEXT "FROM"
  1485.     INX    D        ;TO NEXT "TO"
  1486.     DCR    B        ;MORE?
  1487.     JNZ    MOVE        ;   YES, LOOP
  1488.     RET            ;   NO, RETURN
  1489. ;.....
  1490. ;
  1491. ;
  1492. ;***********************************************************************
  1493. ;
  1494. ; CRCSUBS (Cyclic Redundancy Code Subroutines) version 1.20
  1495. ; 8080 Mnemonics
  1496. ;
  1497. ; These subroutines will compute and check a true 16-bit Cyclic Redun-
  1498. ; dancy Code for a message of arbitrary length.
  1499. ;
  1500. ; (Theory and appliction are discussed extensively in the LMODEMxx.HIS
  1501. ; file.  See that for additional information.)
  1502. ;
  1503. ;***********************************************************************
  1504. ;
  1505. ;
  1506. ; ENTRY    CLRCRC,UPDCRC,FINCRC,CHKCRC
  1507. ;
  1508. CLRCRC:
  1509.     PUSH    H        ;RESET CRC ACCUMULATOR FOR A NEW MSG.
  1510.     LXI    H,0
  1511.     SHLD    CRCVAL
  1512.     POP    H
  1513.     RET
  1514. ;
  1515. UPDCRC:
  1516.     PUSH    PSW        ;UPDATE CRC ACCUMULATOR WITH BYTE IN 'A'
  1517.     PUSH    B
  1518.     PUSH    H
  1519.     MVI    B,8
  1520.     MOV    C,A
  1521.     LHLD    CRCVAL
  1522. UPDLOOP:
  1523.     MOV    A,C
  1524.     RLC
  1525.     MOV    C,A
  1526.     MOV    A,L
  1527.     RAL
  1528.     MOV    L,A
  1529.     MOV    A,H
  1530.     RAL
  1531.     MOV    H,A
  1532.     JNC    SKIPIT
  1533. ;
  1534.     MOV    A,H        ;The generator is X^16 + X^12 + X^5 + 1
  1535.     XRI    10H        ;as recommended by CCITT.  An alternate
  1536.     MOV    H,A        ;generator which is often used in
  1537.     MOV    A,L        ;synchronous transmission protocols is
  1538.     XRI    21H        ;X^16 + X^15 + X^2 + 1. This may be used
  1539.     MOV    L,A        ;by substituting XOR 80H for XOR 10H and
  1540. SKIPIT:
  1541.     DCR    B        ;XOR 05H for XOR 21H in the adj. code.
  1542.     JNZ    UPDLOOP
  1543.     SHLD    CRCVAL
  1544.     POP    H
  1545.     POP    B
  1546.     POP    PSW
  1547.     RET
  1548. ;
  1549. FINCRC:
  1550.     PUSH    PSW        ;FINISH CRC CALC FOR OUTBOUND MSG.
  1551.     XRA    A
  1552.     CALL    UPDCRC
  1553.     CALL    UPDCRC
  1554.     PUSH    H
  1555.     LHLD    CRCVAL
  1556.     MOV    D,H
  1557.     MOV    E,L
  1558.     POP    H
  1559.     POP    PSW
  1560.     RET
  1561. ;.....
  1562. ;
  1563. CRCVAL:    DW    0
  1564. ;
  1565. ;
  1566. ;
  1567. ; Temporary storage area
  1568. ;
  1569.     DB    0
  1570. MEMFCB:    DS    16
  1571. ;
  1572. DIRSZ:    DW    0
  1573. MAXEXT:    DB    0        ;HIGHEST EXT. # SEEN IN FILE SIZE CALC.
  1574. SECTNO:    DW    0        ;CURRENT SECTOR NUMBER 
  1575. ERRCT:    DB    0        ;ERROR COUNT
  1576. OPTSAV:    DB    0        ;SAVE OPTION HERE FOR CARRIER LOSS
  1577. CONONL:    DB    0        ;CTYPE CONSOLE-ONLY FLAG        
  1578. INDEX:    DW    0
  1579. ;
  1580.     IF    PMMI OR H8 OR DCH
  1581. ERRCDE:    DB    0        ;RECEIVE ERROR CODE
  1582.     ENDIF
  1583. ;
  1584. CRCFLG:    DB    'C'        ;SET TO NULL IF CRC USED
  1585. RCNT:    DW    0        ;RECORD COUNT
  1586. ;
  1587. ;
  1588. ; Following 3 used by disk buffering routines
  1589. ;
  1590. EOFLG:    DB    0        ;'EOF' FLAG (1=TRUE)
  1591. SECPTR:    DW    DBUF
  1592. SECNBF:    DB    0        ;# OF SECTORS IN BUFFER
  1593.     DS    60        ;STACK AREA
  1594. ;
  1595. STACK:    DS    2        ;STACK POINTER
  1596. ;
  1597. ;
  1598. ; 16 sector disk buffer
  1599. ;
  1600. DBUF:    DS    0        ;16 SECTOR DISK BUFFER
  1601. ;
  1602. ; BDOS equates
  1603. ;
  1604. RDCON    EQU    1
  1605. WRCON    EQU    2
  1606. PRINT    EQU    9
  1607. CONST    EQU    11        ;CONSOLE STAT
  1608. SELDRV    EQU    14        ;SELECT DRIVE
  1609. OPEN    EQU    15        ;0FFH = NOT FOUND
  1610. CLOSE    EQU    16        ;    "       "
  1611. SRCHF    EQU    17        ;    "       "
  1612. SRCHN    EQU    18        ;    "       "
  1613. ERASEF    EQU    19        ;NO RET CODE
  1614. READ    EQU    20        ;0=OK, 1=EOF
  1615. WRITE    EQU    21        ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  1616. MAKE    EQU    22        ;0FFH=BAD
  1617. REN    EQU    23        ;0FFH=BAD
  1618. CURDRV    EQU    25        ;GET CURRENT DRIVE
  1619. STDMA    EQU    26        ;SET DMA
  1620. USER    EQU    32        ;SET USER AREA TO RECEIVE FILE
  1621. BDOS    EQU    BASE+5
  1622. FCB    EQU    BASE+5CH    ;SYSTEM FCB
  1623. FCBEXT    EQU    FCB+12        ;FILE EXTENT
  1624. FCBSNO    EQU    FCB+32        ;SECTOR #
  1625. ;.....
  1626. ;
  1627. ;
  1628.     END
  1629.