home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpmug / cpmug033.ark / RJCASP.BAS < prev    next >
Encoding:
BASIC Source File  |  1984-04-29  |  2.2 KB  |  75 lines
  1. 10  REM   THIS IS THE PROGRAM 'RJCASP.BAS' A SAR RESOURCE ALLOCATION PROGRAM
  2. 20  REM   WRITTEN BY MJ BOB MATTSON USAF, DIR OF SAR, CIVIL AIR PATROL
  3. 30  REM
  4. 35  DIM D(50),C1$(50),C2(50),C5$(50),P1(50),P2(50)
  5. 40  LET P4=99
  6. 45  PRINT "ENTER PRIMARY CELL NAME,COMMA,SECONDARY CELL NAME,COMMA,AND THEN"
  7. 50  PRINT"PROBABILITY OF TARGET IN THE CELL USING THE RANGE 0-";P4
  8. 55  PRINT "FOR THE LAST ENTRY USE 'END,0,0'"
  9. 60  INPUT C3$,C6$,P3
  10. 70  FOR I=1 TO N
  11. 80  IF C3$="END" THEN 180
  12. 90  IF C3$<>C1$(I) THEN 120
  13. 100 LET P1(I)=P1(I)+P3
  14. 110 GOTO 60
  15. 120 NEXT I
  16. 130 LET N=N+1
  17. 140 LET C1$(N)=C3$
  18. 145 LET C5$(N)=C6$
  19. 150 LET P1(N)=P3
  20. 160 LET D(N)=N
  21. 170 GOTO 60
  22. 180 LET P4=0
  23. 190 FOR I=1 TO N
  24. 195 LET P4=P4+P1(I)
  25. 200 NEXT I
  26. 210 FOR I=1 TO N
  27. 220 LET P1(I)=P1(I)/P4
  28. 230 NEXT I
  29. 240 PRINT "ENTER CELL NAME,COMMA,AND POD FOR CELL (1-99)"
  30. 250 PRINT "FOR THE LAST ENTRY, ENTER 'END,0'"
  31. 260 INPUT C3$, Q1
  32. 270 FOR I=1 TO N
  33. 280 IF C3$=C1$(I) THEN 300
  34. 290 NEXT I
  35. 300 LET C2(I)=C2(I)-LOG(1-Q1/100)
  36. 310 IF C3$<>"END" THEN 260
  37. 320 LET C4=0
  38. 330 FOR I=1 TO N
  39. 340 LET C4=C4+P1(I)*EXP(-1*C2(I))
  40. 350 NEXT I
  41. 360 FOR I=1 TO N
  42. 370 LET P2(I)=P1(I)*EXP(-1*C2(I))/C4
  43. 380 NEXT I
  44. 390 FOR J=1 TO N-1
  45. 400 FOR I=J+1 TO N
  46. 410 IF P2(D(J))>P2(D(I)) THEN 450
  47. 420 LET T=D(J)
  48. 430 LET D(J)=D(I)
  49. 440 LET D(I)=T
  50. 450 NEXT I
  51. 460 NEXT J
  52. 470 PRINT "ENTER NUMBER OF CELLS YOU WISH TO SEE";
  53. 480 INPUT J
  54. 490 PRINT "CELL","CELL","INIT PROB", "CUMULATIVE","CURRENT PROB"
  55. 500 PRINT "NUMBER", "NAME","TGT IN CELL","POD","TARGET IN CELL"
  56. 510 FOR I=1 TO J
  57. 520 PRINT C5$(D(I)),C1$(D(I)),INT(100*P1(D(I))+.5);"%",
  58. 530 PRINT INT(100*(1-EXP(-1*C2(D(I))))+.5);"%",INT(100*P2(D(I))+.5);"%"
  59. 540 NEXT I
  60. 550 PRINT "SEARCH EFFECTIVENESS PROBABILITY =";INT(1000*(1-C4)+.5)/10;"%"
  61. 560 PRINT "DO YOU HAVE ANY NEW SEARCH POD'S TO REPORT? Y/N??";
  62. 570 INPUT K$
  63. 580 IF LEFT$(K$,1)="Y" THEN 240
  64. 590 PRINT "DO YOU HAVE ANY NEW AREAS OR REVISED POT'S TO REPORT? Y/N??";
  65. 600 INPUT K$
  66. 610 IF LEFT$(K$,1)<>"Y" THEN 660
  67. 620 FOR I=1 TO N
  68. 630 LET P1(I)=P4*P1(I)
  69. 640 NEXT I
  70. 650 GOTO 45
  71. 660 END
  72. 670 LTCOL MATTSON MAY BE CONTACTED BY WRITTING TO
  73. 671            NATIONAL HEADQUARTERS-CIVIL AIR PATROL
  74. 672            MAXWELL AIR FORCE BASE,ALABAMA 36112, U.S.A.
  75.