home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpmug / cpmug021.ark / KING.ASC < prev    next >
Encoding:
Text File  |  1984-04-29  |  7.1 KB  |  235 lines
  1. 10 OUT 2,26
  2. 30 N5=8:N4=8
  3. 100 INPUT "WHAT IS YOUR NAME";A$
  4. 105 B$=""
  5. 110 IF LEFT$(A$,4)="KING" THEN 370
  6. 120 IF LEFT$(A$,4)="QUEE" THEN 370
  7. 130 PRINT"ARE YOU KING OR QUEEN ";A$
  8. 140 INPUT B$
  9. 370 PRINT"GREETINGS ";B$;" ";A$
  10. 380 PRINT"YOUR GOAL: TO COMPLETE YOUR ";N4;" YEAR TERM."
  11. 390 PRINT"GOOD LUCK"
  12. 400 M=INT(70000+(RND(1)*1000)-(RND(2)*1000))
  13. 410 P=INT(500 +(RND(3)*10)-(RND(4)*10))
  14. 420 L=2000
  15. 430 W=0:X2=0:E0=0:X1=0:E1=0:S9=0:S0=0:M5=0:S1=0
  16. 440 D1=INT(P/3)
  17. 450 L1=INT((RND(0)*5)+10)
  18. 460 L0=INT(RND(0)*10+95)
  19. 470 GOSUB 2220
  20. 471 PRINT B$;" ";A$;" ";
  21. 472 PRINT"THIS IS THE START OF YEAR ";(N4-N5)+1;"OF YOUR "; N4;"YEAR REIGN."
  22. 480 PRINT"YOU HAVE ";M;" RALLODS, ";
  23. 490 PRINTP;" COUNTRYMEN,";
  24. 500 IF W=0 THEN 520
  25. 510 PRINTW;" FOREIGN WORKERS,";
  26. 520 PRINT" AND";L;" SQ. MILES OF LAND."
  27. 530 PRINT"THIS YEAR INDUSTRY WILL BUY LAND FOR";L0;" RALLODS/SQ. MILE"
  28. 540 PRINT"LAND CURRENTLY COSTS";L1;" RALLODS/SQ. MILE TO PLANT"
  29. 550 IF S1=0 THEN 570
  30. 560 PRINT"POLLUTION LEVEL IS ";S1;" UNITS."
  31. 570 GOSUB 2220
  32. 580 INPUT"HOW MANY SQ. MILES TO SELL TO INDUSTRY ";L2
  33. 600 IF L2<0 THEN 580
  34. 610 IF L2<(L-1000) THEN 680
  35. 620 PRINT"  THINK AGAIN. YOU'VE ONLY";L-1000;" SQ. MILES OF FARM LAND"
  36. 630 IF X<>1 THEN 580
  37. 640 PRINT"(FOREIGN INDUSTRY NOT INTERESTED IN FOREST LAND BECAUSE"
  38. 650 PRINT"OF GREATER DEVELOPMENT COST)"
  39. 660 X1=1
  40. 670 GOTO 580
  41. 680 M=INT(M+L2*L0)
  42. 690 L=INT(L-L2)
  43. 700 X9=INT(44*(2000-L))
  44. 710 M2=0
  45. 720 M3=0
  46. 730 M4=0
  47. 740 INPUT"HOW MANY RALLODS TO DISTRIBUTE TO YOUR COUNTRYMEN ";M1
  48. 770 IF M1<0 THEN 740
  49. 780 IF M1<=M THEN 810
  50. 790 GOSUB 2250
  51. 800 GOTO 740
  52. 810 M=INT(M-M1)
  53. 820 IF M=0 THEN 1170
  54. 830 INPUT"HOW MANY SQ. MILES TO PLANT ";L3
  55. 850 IF L3<0 THEN 830
  56. 860 IF L3<=P*2 THEN 890
  57. 870 PRINT"EACH COUNTRYMAN CAN ONLY PLANT 2 SQ. MILES":GOTO 950
  58. 890 IF L3<=L-1000 THEN 920
  59. 900 PRINT"ONLY GOT";L-1000;" SQ. MILES OF FARM LAND."
  60. 910 GOTO 950
  61. 920 M4=INT(L3*L1)
  62. 930 IF M4<=M THEN 990
  63. 940 GOSUB 2250
  64. 950 PRINT"YOU CAN AFFORD";INT(M/L1);
  65. 960 PRINT" AND HAVE LABOR FOR";P*2;
  66. 970 PRINT" AND HAVE";L-1000;" SQ. MILES":GOTO 830
  67. 990 M=INT(M-M4)
  68. 1000 IF M=0 THEN 1170
  69. 1010 INPUT"HOW MUCH TO SPEND FOR EDUCATION ";M2
  70. 1030 IF M2<0 THEN 1010
  71. 1040 IF M2<M THEN 1070
  72. 1050 GOSUB 2250
  73. 1060 GOTO 1010
  74. 1070 M=INT(M-M2)
  75. 1080 IF M=0 THEN 1170
  76. 1090 IF L=2000 THEN 1170
  77. 1100 INPUT"HOW MUCH TO SPEND TO COMBAT POLLUTION ";M3
  78. 1120 IF M3<0 THEN 1100
  79. 1130 IF M3<=M THEN 1160
  80. 1140 GOSUB 2250
  81. 1150 GOTO 1100
  82. 1160 M=INT(M-M3)
  83. 1170 GOSUB 2220
  84. 1180 D0=0
  85. 1190 E2=M2/P
  86. 1200 D2=INT(P-M1/100)
  87. 1210 IF D2<=0 THEN 1240
  88. 1220 D0=D2
  89. 1230 PRINT D2;" COUNTRYMEN DIED OF STARVATION."
  90. 1240 D3=INT((S1/100000)*(.1+.4*RND(1))*P)
  91. 1250 IF D3<=0 THEN 1280
  92. 1260 PRINT D3;" COUNTRYMEN DIED OF EXCESS POLLUTION."
  93. 1270 D0=D0+D3
  94. 1280 IF D0<=0THEN 1400
  95. 1290 F=D0*9
  96. 1300 PRINT"YOU WERE FORCE TO SPEND";F;" RALLODS FOR FUNERAL EXPENSES"
  97. 1310 M=INT(M-F)
  98. 1320 IF M<=0 THEN 1400
  99. 1330 PRINT"INSUFFICIENT RESOURCES FORCED SALE OF LAND."
  100. 1340 T0=-INT((M-L0+1)/L0)
  101. 1350 L=L-T0
  102. 1360 IF L>=1000 THEN 1390
  103. 1370 PRINT"NOT ENOUGH LAND TO SELL"
  104. 1380 GOTO 2270
  105. 1390 M=M+T0*L0
  106. 1400 IF D0>200 THEN 2300
  107. 1410 P=P-D0
  108. 1420 D1=D1-D0
  109. 1430 IF D1<0 THEN 2410
  110. 1440 IF D2<=2 THEN 1460
  111. 1450 IF M>500 THEN 2520
  112. 1460 IF L2=0 THEN 1520
  113. 1470 T0=INT(L2+L2*RND(2)*2)
  114. 1480 IF W=0 THEN 1500
  115. 1490 T0=INT(T0+.1*W)
  116. 1500 PRINT T0;" WORKERS CAME TO THE ISLAND AND"
  117. 1510 W=W+T0
  118. 1520 T0=INT(((500-P)/10-D3/3-D2/5)*.75*(1+RND(1)))
  119. 1530 PRINT ABS(T0);" COUNTRYMEN ";
  120. 1540 IF T0<0THEN 1570
  121. 1550 PRINT"CAME TO";
  122. 1560 GOTO 1580
  123. 1570 PRINT"LEFT";
  124. 1580 PRINT" THE ISLAND."
  125. 1590 P=P+T0
  126. 1600 IF P<W THEN 2480
  127. 1610 T0=0
  128. 1620 IF L=2000 THEN 1680
  129. 1630 T0=INT((S1/100000)*L3)
  130. 1640 IF T0<=L3 THEN 1660
  131. 1650 T0=L3
  132. 1660 IF T0=0 THEN 1680
  133. 1670 PRINT"OF";L3;" SQ. MILES PLANTED, ";
  134. 1680 PRINT"YOU HARVESTED";L3-T0;" SQ. MILES OF CROPS."
  135. 1690 IF T0=0 THEN 1760
  136. 1700 IF X2>=2 THEN 1760
  137. 1710 PRINT"  (DUE TO ";
  138. 1720 IF X2=0 THEN 1740
  139. 1730 PRINT"INCREASED ";
  140. 1740 PRINT"POLLUTION LEVEL)"
  141. 1750 X2=X2+1
  142. 1760 T1=INT((39+RND(1)*20)*(1+.25*(E0+E1)/20))
  143. 1770 PRINT"  MAKING";INT(T1*(L3-T0));" RALLODS."
  144. 1780 M=M+INT(T1*(L3-T0))
  145. 1790 E0=E1
  146. 1800 IF E2<=10 THEN 1820
  147. 1810 E2=10
  148. 1820 E1=E2
  149. 1830 T0=2000-L
  150. 1840 IF T0<2 THEN 2100
  151. 1850 IF T0<=26 THEN 1870
  152. 1860 T0=26
  153. 1870 T0=INT(T0*500*(.52+.5*RND(6)))
  154. 1880 T1=S1/100000
  155. 1890 IF T1<=1 THEN 1910
  156. 1900 T1=1
  157. 1910 T1=T1*T0
  158. 1920 PRINT"YOU MADE";INT(T0-T1);" RALLODS FROM TOURIST TRADE"
  159. 1930 M=M+INT(T0-T1)
  160. 1940 IF INT(T0-T1)<=M5 THEN 2080
  161. 1950 IF S1<=S9 THEN 2080
  162. 1960 PRINT"  DECREASE BECAUSE ";
  163. 1970 T2=RND(1)*10
  164. 1980 ON (T2/2)+1 GOTO 1990,2010,2030,2050,2070,2070
  165. 1990 PRINT"FISH POPULATIN HAS DWINDLED DUE TO WATER POLLUTION"
  166. 2000 GOTO 2080
  167. 2010 PRINT"AIR POLLUTION IS KILLING GAME BIRD POPULATION"
  168. 2020 GOTO 2080
  169. 2030 PRINT"MINERAL BATHS ARE BEING RUINED BY WATER POLLUTION"
  170. 2040 GOTO 2080
  171. 2050 PRINT"UNPLEASANT SMOG IS DISCOURIGING SUN BATHERS"
  172. 2060 GOTO 2080
  173. 2070 PRINT"HOTEL ARE LOOKING SHABBY DUE TO SMOG GRIT"
  174. 2080 M5=INT(T0-T1)
  175. 2090 S9=S1
  176. 2100 S2=(2000-L)^2-M3/.44
  177. 2110 PRINT"YOU RECEIVED";X9;" RALLODS FROM TAXES ON INDUSTRY"
  178. 2120 IF S2>=0 THEN 2170
  179. 2130 S1=INT(S1+S2/2)
  180. 2140 IF S1>=S0 THEN 2160
  181. 2150 S1=S0
  182. 2160 GOTO 2190
  183. 2170 S1=INT(S1+S2)
  184. 2180 S0=INT(S0+S2/10)
  185. 2190 N5=N5-1
  186. 2200 IF N5>0 THEN 450
  187. 2210 GOTO 2570
  188. 2220 PRINT:PRINT:RETURN
  189. 2250 PRINT"ONLY GOT";M;" RALLODS LEFT!":RETURN
  190. 2270 PRINT"YOU HAVE BEEN THROWN OUT OF OFFICE AND YOU ARE NOW"
  191. 2280 PRINT"RESIDING IN PRISON."
  192. 2290 GOTO 2615
  193. 2300 PRINTD0;" COUNTRYMEN DIED IN ONE YEAR!!!!!"
  194. 2310 PRINT"DUE TO THIS EXTREME MISMANAGEMENT YOU HAVE NOT ONLY"
  195. 2320 PRINT"BEEN IMPEACHED AND THROWN OUT OF OFFICE BUT YOU"
  196. 2330 T0=INT(RND(1)*2.01)+1
  197. 2340 ON T0 GOTO 2350,2370,2390
  198. 2350 PRINT"ALSO HAD YOUR LEFT EYE GOUGED OUT."
  199. 2360 GOTO 2615
  200. 2370 PRINT"HAVE ALSO GAINED A VERY BAD REPUTATION."
  201. 2380 GOTO 2615
  202. 2390 PRINT"HAVE ALSO BEEN DECLARED NATIONAL FINK."
  203. 2400 GOTO 2615
  204. 2410 PRINT"OVER ONE THIRD OF THE POPULATION HAS DIED SINCE YOU"
  205. 2420 PRINT"WERE ELECTED TO OFFICE.  THE PEOPLE (REMAINING)"
  206. 2430 PRINT"HATE YOUR GUTS."
  207. 2440 GOTO 2450
  208. 2450 IF RND(2)<.25 THEN 2270
  209. 2460 PRINT"YOU HAVE BEEN ASSASINATED, AND YOUR BODY THROWN IN" 
  210. 2465 PRINT" THE BREA DUMP.  " 
  211. 2470 GOTO 2615
  212. 2480 PRINT"THE NUMBER OF FOREIGN WORKERS HAS EXCEEDED THE NUMBER"
  213. 2490 PRINT"OF COUNTRYMEN. AS A MAJORITY THEY HAVE REVOLTED AND"
  214. 2500 PRINT"TAKEN OVER THE COUNTRY."
  215. 2510 GOTO 2450
  216. 2520 PRINT"MONEY WAS LEFT OVER IN THE TREASURY WHICH YOU DID NOT"
  217. 2530 PRINT"SPEND.  AS A RESULT SOME OF YOUR COUNTRYMEN DIED OF "
  218. 2540 PRINT"STARVATION.  THE PUBLIC IS ENRAGED AND YOU HAVE BEEN"
  219. 2550 PRINT"FORCED TO EITHER RESIGN OR COMMIT SUICIDE."
  220. 2560 GOTO 2615
  221. 2570 PRINT
  222. 2580 PRINT"CONGRATULATIONS ";B$;" ";A$
  223. 2585 PRINT
  224. 2590 PRINT"YOU HAVE SUCCESSFULLY COMPLETED YOUR";N4;" YEAR TERM"
  225. 2600 PRINT"OF OFFICE.  YOU HAVE DONE SUCH A GOOD JOB THAT YOU MIGHT"
  226. 2610 PRINT"WANT TO RUN FOR ELECTION AGAIN THIS TIME."
  227. 2615 PRINT:PRINT:PRINT"WOULD YOU LIKE TO TRY AGAIN ";B$;" ";A$;"?"
  228. 2620 INPUT"TYPE YES OR NO.";Q$
  229. 2625 N5=N4
  230. 2630 IF LEFT$(Q$,1)="Y" THEN 440
  231. 2640 IF LEFT$(Q$,1)="N" THEN 3000
  232. 2660 GOTO 2620
  233. 3000 PRINT:PRINT B$;" ";A$;" IS A CHICKEN!!!!!!"
  234. 3010 END
  235.