home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / dskutl / archive.aqm / ARCHIVE.ASM
Encoding:
Assembly Source File  |  1985-02-10  |  26.6 KB  |  878 lines
  1. ;               ARCHIVE - File Archive/Backup Utility
  2. ;               Version 1.0, 6-June-82 by Kelly Smith
  3. ; 
  4. ; 
  5. ;      ARCHIVE  is  a  user oriented disk maintenance  utility  for 
  6. ; archival  storage and file backup.   User facilities include  the 
  7. ; ability to selectively 'tag' files for archival (or non-archival) 
  8. ; attributes,  display  file  archive attributes,  or  backup  non-
  9. ; archive files to a selected disk.  Wild-card filenames (using '*' 
  10. ; and/or  '?')  may be used freely,  to select some or  all  (i.e., 
  11. ; '*.*') files for archiving.
  12. ; 
  13. ; 
  14. ;                      - Theory of Operation -
  15. ; 
  16. ;      Digital  Research's  MP/M-II and CP/M-86  Operating  Systems 
  17. ; utilize a file attribute for archival backup of any file addition 
  18. ; or update to the disk directory.   This attribute is 'reset' when 
  19. ; an  application  program is required to write a file to  a  disk.  
  20. ; The  actual 'mechanism' for this archive function is realized  by 
  21. ; controlling  the  most significant bit of the third character  of 
  22. ; the FCB (File Control Block) directory entry (i.e.,  position 11, 
  23. ; identified  as byte position T3,  with the Archive attribute  bit 
  24. ; (bit  7  of byte T3) identified as T3').   It is  then  a  simple 
  25. ; matter to identify a file as archived (e.g.,  backed-up) when T3' 
  26. ; is a 'one',  and non-archived (e.g.,  needs to be backed-up) when 
  27. ; T3'  is  a  'zero'.   The 'not-so-simple' part,  is  the  utility 
  28. ; required   to  keep  track  of  the  archive  attributes   on   a 
  29. ; disk...thats where ARCHIVE comes in, and works with CP/M-80 (with 
  30. ; the help of a little 'patch'),  as well as with MP/M-II and CP/M-
  31. ; 86 (when translated for 8086 CPU operation).    
  32. ; 
  33. ; 
  34. ;                       - Examples of Usage -
  35. ; 
  36. ;      At  the CP/M user command prompt,  (usually 'A>'),  the user 
  37. ; has the option for four single letter ARCHIVE command directives, 
  38. ; as follows:
  39. ; 
  40. ;                S - Set file archive attribute.
  41. ; 
  42. ;                R - Reset file archive attribute.
  43. ; 
  44. ;                D - Display file arcive attribute.
  45. ; 
  46. ;                B - Backup non-archived files.
  47. ; 
  48. ;      ARCHIVE  is  invoked by the user at the CP/M  command  level 
  49. ; therefore, as follows,
  50. ; 
  51. ;                    A>ARCHIVE FN.FT OPTION<cr>
  52. ; 
  53. ; ...where,  'FN.FT' is an amibiguous or un-ambiguous filename  and 
  54. ; filetype,  followed  by one of the single character options,  and 
  55. ; then a keyboard RETURN entry.  An actual example then might be:
  56. ; 
  57. ;                       A>archive b:*.* b<cr>
  58. ; 
  59. ; ...then,  we  are executing ARCHIVE from the 'A' disk drive,  for 
  60. ; all  filenames and filetypes on disk 'B' whose archive  attribute 
  61. ; has   been  'reset',   to  be  'backed-up'  to  some   (as   yet) 
  62. ; indeterminate destination disk.
  63. ; 
  64. ;      Options  'S',  'R' and 'D' (Set,  Reset,  and Display)  when 
  65. ; invoked,  will  cause each file found in the directory 'match' to 
  66. ; be  displayed by 'multiple extension'...that is,  each  directory 
  67. ; entry will be displayed,  with its 'extent' number,  followed  by 
  68. ; the archive attribute action/status as 'S' or 'R' (Set or Reset).
  69. ; 
  70. ;      Option  'B'  (Backup)  will  request the  user  to  enter  a 
  71. ; destination disk letter (A to P), then proceed to scan the source 
  72. ; disk  directory for 'reset' archive file  entries.   Any  'reset' 
  73. ; entries  will  then be 'set' (indicating that the file  has  been 
  74. ; archived)  and then these files will be copied to the destination 
  75. ; disk  (Note  however,  that  these  files  will  not  retain  any 
  76. ; previously  set  attributes of 'Read Only' or 'System'  had  they 
  77. ; been  set...all  files  copied to the destination  disk  will  be 
  78. ; 'tagged'  as archived only).   If a disk becomes full,  the  user 
  79. ; will  be requested to remove the disk from the destination  drive 
  80. ; and  insert another for completion of the  backup  process.   Any 
  81. ; file  that has not been completely copied to the destination disk 
  82. ; at the time that disk is detected as 'full', will be deleted from 
  83. ; that disk,  and the file copy will resume intact on the next disk 
  84. ; installed in the destination drive.
  85. ; 
  86. ;      Users of MP/M-II can use ARCHIVE immediately, with no system 
  87. ; modification  required  because it "knows" about file  archiving.  
  88. ; However,  for  CP/M-80 users,  they must patch there system  BDOS 
  89. ; (Basic Disk Operating System) to "teach" CP/M-80 file  archiving.  
  90. ; The following code must be edited and assembled,  then loaded (as 
  91. ; a  '.HEX'  file)  with DDT (Dynamic Debugging  Tool)  using  your 
  92. ; normal  system  installation  procedure for  merging  your  'Boot 
  93. ; Loader'  and  BIOS (Basic Input/Output System) into  your  system 
  94. ; "image"  for eventual SYSGEN'ing (this code assumes the  standard 
  95. ; SYSGEN position of address 980H for the start of the CCP (Console 
  96. ; Command   Processor,   with   a  CP/M-80  system  'size'  of   56 
  97. ; Kilobytes...change the value at label MSIZE to suit your needs).
  98. ; 
  99. ; 
  100. ;                           *+*+*+*+*+*+*
  101. ;                           *+         +*
  102. ;                           *+ WARNING +*
  103. ;                           *+         +*
  104. ;                           *+*+*+*+*+*+*
  105. ; 
  106. ;      You  must incorporate this 'archive patch' in an  unmodified 
  107. ; CP/M-80   (version   2.2)   BDOS   O-N-L-Y...any   other    prior 
  108. ; modifications  will (no doubt) be overlayed by this one,  causing 
  109. ; unpredictable results...'nuf said.
  110. ;                                              - KS -
  111. ;
  112. ;
  113. ;
  114. ; msize        equ    56        ; size of this CP/M 2.2 system
  115. ; ;
  116. ; bdos$loc    equ    (msize-20)*1024+3c00h    ; base address of BDOS
  117. ; wrsec        equ    bdos$loc+03b8h    ; address of write sector routine
  118. ; pntdir    equ    bdos$loc+055eh    ; address of directory pointer routine
  119. ; reset$archive    equ    bdos$loc+0df0h    ; address of reset archive bit patch
  120. ; ;
  121. ; ccp$base    equ    0980h        ; sysgen ccp base position
  122. ; bdos$entry    equ    ccp$base+0806h    ; sysgen bdos entry position
  123. ; wrt$dir    equ    bdos$entry+05c8h; 'wrsec' call location, in DIR write routine
  124. ; scratch    equ    bdos$entry+0deah; scratch RAM inside bdos for patch
  125. ; 
  126. ;     org    wrt$dir            ; patch 'call wrsec'
  127. ; ;
  128. ;     call    reset$archive        ; call patch in scratch RAM
  129. ; ;
  130. ;     org    scratch            ; patch area for 'archive bit reset'
  131. ; ;
  132. ;     call    pntdir            ; point to directory entry in buffer
  133. ;     lxi    d,11            ; make offset to 't3' in FCB
  134. ;     dad    d
  135. ;     mov    a,m            ; get 't3' character from FCB
  136. ;     ani    07fh            ; kill archive bit position
  137. ;     mov    m,a            ; return reset archive bit to FCB
  138. ;     call    wrsec            ; write directory sector
  139. ;     ret                ; return to 'wrt$dir' routine
  140. ; ;
  141. ; ;
  142. ; ;
  143. ;     end
  144. ;
  145. ;
  146. ;
  147. ; *+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*
  148. ; *+                                                                     +*
  149. ; *+  ARCHIVE.ASM Utility Version 1.0,  as of 6-June-82, by Kelly Smith  +*
  150. ; *+                                                                     +*
  151. ; *+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*+*
  152. ;
  153. ;
  154. ; 
  155. true    equ    -1        ; define true
  156. false    equ    not true    ; define false
  157. ;
  158. mpm    equ    not true    ; conditional assembly for MP/M
  159. ;
  160. bdos    equ    5        ; CP/M entry point
  161. exit    equ    0        ; CP/M exit point
  162. dfcb    equ    5ch        ; CP/M default fcb
  163. fcbext    equ    dfcb+12        ; fcb extent byte
  164. fcbrno    equ    dfcb+32        ; fcb record number byte
  165. dbuff    equ    80h        ; default disk buffer
  166. ; 
  167. coninp    equ    1        ; console character input function
  168. pchar    equ    2        ; print character function
  169. dircon    equ    6        ; direct console i/o function
  170. pmessg    equ    9        ; print message function
  171. constat    equ    11        ; console status function
  172. version    equ    12        ; return version number function
  173. rsetdsk    equ    13        ; reset disk system function
  174. seldsk    equ    14        ; select drive function
  175. open    equ    15        ; open file function
  176. close    equ    16        ; close file function
  177. srchfst    equ    17        ; search for first file match function
  178. srchnxt    equ    18        ; search for next file match function
  179. delete    equ    19        ; delete file function
  180. read    equ    20        ; read record function
  181. write    equ    21        ; write record function
  182. make    equ    22        ; make file function
  183. currdsk    equ    25        ; return current logged disk function
  184. stdma    equ    26        ; set dma address function
  185. attrib    equ    30        ; set file attributes function
  186. ; 
  187. tab    equ    09h        ; tab character
  188. lf    equ    0ah        ; line feed character
  189. cr    equ    0dh        ; carriage return character
  190. ; 
  191.  
  192.     org    100h
  193.  
  194. ;
  195. ; jump over authorship notice
  196. ;
  197.     jmp    over
  198. ;
  199.     db    cr,lf,'ARCHIVE Ver.1.0, 6-Jun-82:  Kelly Smith'
  200.     db    cr,lf,'3055 Waco Avenue, Simi Valley, CA 93063'
  201.     db    cr,lf,'Z'-40h    ; force end-of-file for display
  202. ;
  203. ; make a new stack pointer at CP/M serial number
  204. ;
  205. over:    lhld    bdos+1        ; set up a stack
  206.     sphl            ; at top of tpa
  207. ;
  208. ; get curent logged disk, and save it
  209. ;
  210.     mvi    c,currdsk    ; return curent disk
  211.     call    bdos
  212.     sta    logdsk        ; save as logged disk
  213. ;
  214. ; reset disk system in case someone swapped in new disk on the system
  215. ;
  216.     mvi    c,rsetdsk    ; reset disk system function
  217.     call    bdos
  218. ;
  219. ; now return to original login disk
  220. ;
  221.     lda    logdsk        ; get logged in disk number
  222.     mov    e,a        ; do disk select
  223.     mvi    c,seldsk
  224.     call    bdos    
  225. ;
  226. ; announcing, the new and improved ARCHIVE...it beats as it sweeps, as it cleans
  227. ; 
  228.     lxi    d,signon    ; point to signon message
  229.     mvi    c,pmessg    ; print string fuction
  230.     call    bdos        ; print it
  231. ;
  232. ; check for proper environment, we only live for CP/M 2.2
  233. ;
  234.     mvi    c,version    ; check version number, must be 2.2
  235.     call    bdos
  236.     cpi    022h        ; version number correct?
  237.     lxi    d,bad$ver$num    ; set-up bad version message, in case its not
  238.     jnz    arcexit        ; bail-out now, if wrong version number
  239. ;
  240.     if    not mpm        ; CP/M-80 does not know about archiving...
  241.     lhld    bdos+1        ; see if archiving installed in CP/M
  242.     lxi    d,05c9h        ; add offset to archive patch address
  243.     dad    d
  244.     shld    arch$addr    ; save address for later
  245.     mov    a,m        ; get low byte content
  246.     cpi    0b8h        ; is this address for write sector routine?
  247.     jnz    patch$bdos    ; if not, patch it back into bdos
  248.     lxi    d,noarch    ; tell user that archive is not installed
  249.     jmp    arcexit        ; exit via CP/M warm boot
  250. ;
  251. patch$bdos:
  252. ;
  253.     lhld    bdos+1        ; patch write sector address back to bdos
  254.     lxi    d,03b2h        ; add offset address of 'wrsec'
  255.     dad    d
  256.     xchg            ; address patch info to [DE]
  257.     lhld    arch$addr    ; get address to patch in [HL]
  258.     mov    m,e        ; low byte address patched first
  259.     inx    h        ; bump pointer
  260.     mov    m,d        ; high byte address patched second
  261.     endif            ; endif MP/M
  262. ;
  263. ; check if filename specified, abort if not
  264. ;
  265.     lda    dfcb+1        ; this will be a space, if no filename
  266.     cpi    ' '
  267.     jnz    gotname        ; if not space, probably filename
  268.     lxi    d,no$file$nam    ; inform user of error of their way...
  269.     mvi    c,pmessg
  270.     call    bdos
  271.     lxi    d,opts        ; tell'em about backup options also
  272.     jmp    arcexit        ; bail-out now, no filename
  273. ;
  274. ; got a name, now check to see which (if any) disk specified
  275. ; 
  276. gotname:lda    dfcb        ; check for specific drive
  277.     dcr    a
  278.     mov    e,a        ; set up for select disk call
  279.     mvi    c,seldsk
  280.     inr    a        ; if no specified drive, skip call
  281.     sta    src$dsk$num    ; save drive specifier for later check
  282.     cnz    bdos
  283.     xra    a        ; now zap out drive specifier
  284.     sta    dfcb
  285.     mvi    a,'?'        ; force extent number wild
  286.     sta    dfcb+12
  287.     lda    dfcb+17        ; get "B", "S", "R" or "D" option
  288.     sta    option
  289.     cpi    'B'        ; backup operation?
  290.     jz    okopt
  291.     cpi    'S'        ; set archive operation?
  292.     jz    okopt
  293.     cpi    'R'        ; reset archive operation?
  294.     jz    okopt
  295.     cpi    'D'        ; just display?
  296.     jz    okopt
  297. ; 
  298. badopt:    lxi    d,ilgopt    ; let'em know it was an illegal option
  299. arcexit:mvi    c,pmessg    ; bitch, bitch, bitch... 
  300.     call    bdos
  301.     jmp    exit
  302. ; 
  303. ; findout now, if operation is for backup or general lobotomy
  304. ;
  305. okopt:    lda    option        ; get option specifier
  306.     cpi    'B'
  307.     jnz    arc$s$r        ; if not backup, must be set/reset archive
  308. dest:    lxi    d,req$dest    ; request destination disk for backup files
  309.     mvi    c,pmessg
  310.     call    bdos
  311.     mvi    c,coninp    ; get console input character
  312.     call    bdos
  313.     ani    05fh        ; force upper case
  314.     sbi    'A'        ; force binary digit
  315.     cpi    16        ; disk >P?
  316.     jnc    dest        ; must satisfy ourselves with 16 disks maximum
  317.     lxi    h,logdsk    ; is this jerk backing up to the same disk?
  318.     ani    0fh        ; strip high nibble for match to logged disk
  319.     cmp    m
  320.     push    psw        ; save flags
  321.     inr    a        ; save re-adjusted disk number
  322.     sta    dest$dsk$num
  323.     pop    psw        ; get flags
  324.     jz    dsksame        ; if same, tell'em so now
  325.     inx    h        ; bump pointer to destination disk
  326.     mov    a,m        ; get disk number
  327.     inx    h        ; bump pointer to source disk number
  328.     cmp    m        ; any chance he specified destination as source
  329.     jnz    backup        ; if not, we can (finally) proceed with backup
  330. dsksame:lxi    d,same$dsk    ; sob...(read this anyway you want)
  331.     mvi    c,pmessg
  332.     call    bdos
  333.     jmp    dest        ; computers never lose their patience...
  334. ;
  335. ; ready for directory write operations now...do archive set/reset
  336. ;
  337. arc$s$r:call    crlf        ; tidy up display
  338.     xra    a        ; zero out file count
  339.     sta    filcnt
  340.     lxi    d,dfcb        ; find the first file and get its block map
  341.     mvi    c,srchfst
  342.     call    bdos
  343.     inr    a        ; search successful?
  344.     jnz    gotfile        ; yes, go process rest
  345.     lxi    d,no$file$fnd    ; oops, no file found
  346.     jmp    arcexit        ; exit via CP/M warm boot
  347. ; 
  348. gotfile:dcr    a        ; compensate for 'inr' above
  349.     rrc            ; file offset to bits 5 and 6
  350.     rrc
  351.     rrc
  352.     ani    60h
  353.     lxi    h,dbuff        ; point to base of buffer
  354.     mov    c,a
  355.     mvi    b,0
  356.     dad    b        ; index by file offset
  357.     push    h        ; save directory entry, for the moment
  358.     lxi    b,filetable    ; point to base of file table
  359.     call    filepoint    ; get table pointer to [HL]
  360.     xchg            ; [DE] now points to place in table
  361.     lda    filcnt        ; keep track of number of files in table
  362.     inr    a
  363.     sta    filcnt        ; bump file count
  364.     pop    h        ; [HL] points to directory entry
  365.     mvi    b,32
  366.     call    blkmov        ; copy entry into table
  367. getnext:mvi    c,srchnxt    ; search for another entry
  368.     lxi    d,dfcb
  369.     call    bdos
  370.     inr    a        ; returns 0ffh at end of search
  371.     jnz    gotfile        ; got another one, go save it
  372. ; 
  373. ;  end of directory encountered, now process them
  374. ; 
  375. tagfile:call    abort        ; check for user abort of process
  376.     lxi    b,filetable-32    ; allow for file count one greater than desired
  377.     call    filepoint
  378.     push    h
  379.     lxi    d,dfcb        ; copy next name to default fcb
  380.     mvi    b,32
  381.     call    blkmov        ; someday I will grow up to be a Z80...
  382.     xra    a
  383.     sta    dfcb        ; clear drive number
  384.     lxi    d,-20        ; point back to extent field
  385.     dad    d
  386.     mvi    m,'$'        ; tag end of print here
  387.     pop    d        ; get back pointer to start of entry
  388.     inx    d        ; bump forward to name
  389.     mvi    c,pmessg
  390.     call    bdos        ; say what we're working on
  391.     mvi    e,' '        ; make space between filename.typ and extent
  392.     mvi    c,pchar
  393.     call    bdos
  394.     lda    dfcb+12        ; get extent number
  395.     push    psw        ; save it
  396.     adi    '0'        ; convert to ascii
  397.     mov    e,a
  398.     mvi    c,pchar        ; display extent number
  399.     pop    psw
  400.     call    bdos
  401.     lda    option        ; get B, S, R, or D
  402.     cpi    'D'        ; display only?
  403.     jz    nextfile
  404.     rrc            ; bit 7 = 0 for B, R, and D, 1 for S
  405.     ani    80h
  406.     mov    b,a        ; save mask
  407.     lxi    d,dfcb+11    ; point to t3
  408.     ldax    d        ; get it
  409.     ani    7fh        ; strip t3'
  410.     ora    b        ; set bit if option was S
  411.     stax    d        ; put it back
  412.     lxi    d,dfcb        ; point to start of fcb
  413.     xra    a        ; zap out drive field
  414.     stax    d
  415.     mvi    c,attrib    ; do set attributes function
  416.     call    bdos
  417. ; 
  418. nextfile:
  419. ; 
  420.     lda    dfcb+11        ; get t3
  421.     rlc            ; isolate t3'
  422.     ani    1
  423.     adi    'R'        ; make an R or S
  424.     sta    donmsg+1
  425.     lxi    d,donmsg
  426.     mvi    c,pmessg    ; print completion message for this file
  427.     call    bdos
  428.     call    crlf        ; tidy up display
  429.     lxi    h,filcnt    ; point to file counter
  430.     dcr    m        ; count it down
  431.     jz    exit        ; exit if done
  432.     jmp    tagfile        ; tag next file
  433. ;
  434. ; backup routine - does multiple file search and copy
  435. ;
  436. backup:    call    crlf        ; tidy up display
  437. noback:    call    abort        ; check for user abort of process
  438.     call    mfname        ; set-up multi-file search (seek and ye shall find?)
  439.     jnc    movname        ; file found, if no carry
  440.     lda    mfflg1        ; check if anything ever found...
  441.     ora    a
  442.     lxi    d,bakup$done    ; set-up backup done message
  443.     jnz    nofile        ; if not...indicate, no file found
  444.     lda    got$arc        ; check archive found flag
  445.     ora    a
  446.     jnz    arcexit        ; if not zero, must have found one (or more)
  447.     lxi    d,narcs        ; indicate no archive files found
  448.     jmp    arcexit
  449. nofile:    lxi    d,no$file$fnd    ; oops, no file found
  450.     jmp    arcexit        ; exit with perturbed message
  451. movname:lxi    h,dfcb+11    ; point to t3 in filetype
  452.     mov    a,m        ; get t3 byte
  453.     rlc            ; archive bit set?
  454.     jc    noback        ; if so, no backup required
  455.     rrc            ; adjust back to normal
  456.     sta    got$arc        ; set archive file found flag with non-zero
  457.     ori    080h        ; set 'archived' status back
  458.     mov    m,a        ; put it back
  459.     push    h        ; save pointer
  460.     lxi    d,dfcb        ; point to start of fcb
  461.     mvi    c,attrib    ; do set attributes function
  462.     call    bdos
  463.     pop    h        ; restore pointer
  464.     dcx    h        ; point to t2 in filetype
  465.     mov    a,m        ; get t2 byte
  466.     ani    07fh        ; strip-off t2'
  467.     mov    m,a        ; put it back
  468.     dcx    h        ; point to t1 in filetype
  469.     mov    a,m        ; get t1 byte
  470.     ani    07fh        ; strip-off t1'
  471.     mov    m,a        ; put it back
  472.     lxi    h,dfcb+1    ; point to filename for move and display
  473.     lxi    d,fname        ; display destination for filename
  474.     mvi    b,8        ; set-up to move 8 characters in filename
  475.     call    blkmov        ; too bad that 8080 is defacto standard
  476.     lxi    h,dfcb+9    ; point to filetype for move and display
  477.     lxi    d,fname+9    ; display destination for filetype
  478.     mvi    b,3        ; set-up to move 3 characters in filetype
  479.     call    blkmov        ; LDIR is so nifty...
  480. dspname:lxi    d,fname        ; display filename and filetype
  481.     mvi    c,pmessg
  482.     call    bdos
  483. ; 
  484. ; save first fcb for use later as destination file name
  485. ; 
  486.     mvi    b,11           ; number of characters to move
  487.     lxi    h,dfcb+1    ; from default fcb
  488.     lxi    d,destfcb+1     ; to destfcb
  489.     call    blkmov        ; round'em up and head'em out
  490. ; 
  491. ; open the source file
  492. ; 
  493.     lda    logdsk        ; select disk, in case of disk full status
  494.     mov    e,a
  495.     mvi    c,seldsk    ; select disk function
  496.     call    bdos    
  497.     lxi    d,dfcb        ; point to source fcb
  498.     mvi    c,open        ; attempt open
  499.     call    bdos
  500.     cpi    0ffh        ; file not found?
  501.     jnz    openok
  502.     lxi    d,src$open$err    ; oops, source file open error
  503.     jmp    arcexit        ; exit via CP/M warm boot
  504. ; 
  505. ; open the destination file
  506. ; 
  507. openok:    lxi    d,destfcb    ; point to destination fcb
  508.     lda    dest$dsk$num    ; get destination disk number
  509.     stax    d        ; set-up destination disk fcb disk number
  510.     mvi    c,delete    ; erase any old file
  511.     call    bdos
  512.     lxi    d,destfcb
  513.     mvi    c,make        ; make the new one
  514.     call    bdos
  515.     cpi    0ffh        ; succesfully created?
  516.     jz    full        ; oops, disk full...time for a new one
  517. ; 
  518. ; read source file to buffer, write to destination as copy
  519. ;
  520. copy:    lxi    h,(table$end-filetable)/128    ; save buffer size
  521.     shld    bufmax
  522.     xra    a        ; clear eof flag
  523.     sta    eof$flg
  524. copy1:    call    abort        ; check for user abort on ctrl-c
  525.     lxi    h,0        ; set current buffer counter to zero
  526.     shld    bufcnt
  527.     lxi    h,filetable    ; set buffer start pointer to begin
  528.     shld    bufpnt
  529. ; 
  530. ; file source reading loop to read all of buffer full or stop on eof
  531. ; 
  532. copy2:    lhld    bufpnt        ; set dma address to buffer pointer
  533.     xchg
  534.     mvi    c,stdma
  535.     call    bdos
  536.     lxi    d,dfcb        ; point at default fcb for reading
  537.     mvi    c,read        ; function set for record read
  538.     call    bdos
  539.     ora    a        ; check if read was o.k., or eof
  540.     jnz    copy3        ; end of file so set eof flag
  541.     lhld    bufpnt        ; set buffer pointer up one sector
  542.     lxi    d,128
  543.     dad    d
  544.     shld    bufpnt
  545.     lhld    bufcnt        ; increase buffer sector count
  546.     inx    h
  547.     shld    bufcnt
  548.     xchg            ; check to see if memory is full
  549.     lhld    bufmax        ; maximum sector count
  550.     call    cdehl        ; compare
  551.     jnz    copy2        ; if not full go get next sector
  552.     jmp    copy4        ; go handle write operation
  553. ; 
  554. ; here if read operation indicates that the file is at its end on read
  555. ; 
  556. copy3:    mvi    a,0ffh        ; set eof flag
  557.     sta    eof$flg
  558. ; 
  559. ; write output file processing loop to send memory buffer to destination disk file
  560. ; 
  561. copy4:    lxi    h,filetable    ; set buffer pointer to start
  562.     shld    bufpnt
  563. copy5:    call    abort        ; check for user abort on ctrl-c
  564.     lhld    bufcnt        ; see if buffer is empty yet
  565.     mov    a,h
  566.     ora    l
  567.     jz    copy6        ; buffer empty so check eof flag
  568.     dcx    h        ; dec buffer sector count for each write
  569.     shld    bufcnt
  570.     lhld    bufpnt        ; set up dma address
  571.     push    h        ; save for size bump
  572.     xchg
  573.     mvi    c,stdma
  574.     call    bdos
  575.     pop    h
  576.     lxi    d,128        ; increase address for sector size
  577.     dad    d
  578.     shld    bufpnt
  579.     lxi    d,destfcb    ; point to output file fcb
  580.     mvi    c,write        ; write record function code
  581.     call    bdos        ; go write
  582.     ora    a           ; check if any error
  583.     jz    copy5        ; o.k., so do next record
  584.     jmp    full        ; oops...disk full, time for a new one
  585. ;
  586. copy6:    lda    eof$flg        ; buffer all written so go check eof
  587.     ora    a
  588.     jz    copy1        ; go to read next buffer full
  589.     lxi    d,destfcb    ; point at fcb for file close
  590.     mvi    c,close        ; close file function code
  591.     call    bdos
  592.     cpi    0ffh        ; check if close error
  593.     jnz    backup        ; if not, backup more files
  594.     lxi    d,src$close$err    ; oops, close error on destination disk
  595.     jmp    arcexit        ; exit with error message
  596. ;
  597. ; subroutine to compare [DE] to [HL], [Z] set if equal
  598. ;
  599. cdehl:    mov    a,d        ; high bytes equal?
  600.     cmp    h
  601.     rnz
  602.     mov    a,e        ; yes, how'bout low bytes?
  603.     cmp    l
  604.     ret            ; set zero, if equal
  605. ;
  606. ; subroutine to allow disk change, to continue backup process
  607. ;
  608. full:    lxi    d,destfcb    ; delete partial file on destination disk
  609.     mvi    c,delete
  610.     call    bdos
  611.     lxi    d,dsk$full    ; indicate that disk (or dir) is full
  612.     mvi    c,pmessg
  613.     call    bdos
  614.     lda    dest$dsk$num    ; get destination disk number
  615.     adi    040h        ; ASCII'ize it
  616.     mov    e,a        ; display it
  617.     mvi    c,pchar
  618.     call    bdos
  619.     lxi    d,now$full    ; display remaining portion of full message
  620.     mvi    c,pmessg
  621.     call    bdos
  622. req$cnt:lxi    d,enter$ret    ; tell'em to remove/insert disk, hit return
  623.     mvi    c,pmessg
  624.     call    bdos
  625.     mvi    c,coninp    ; wait for user response
  626.     call    bdos
  627.     cpi    cr        ; carriage return?
  628.     jnz    req$cnt        ; if not, leave reminder on what to do
  629.     call    crlf        ; tidy up screen
  630.     mvi    c,rsetdsk    ; reset disk system for newcomer
  631.     call    bdos
  632.     call    rset$fcb    ; reset fcb for retry of previous file
  633.     jmp    dspname        ; continue on new disk, with last file
  634. ;
  635. ; Multi-file  access  subroutine.   Allows processing  of  multiple 
  636. ; files (i.e.  *.*) from disk.  This routine builds the proper name 
  637. ; in the fcb each time it is called.  Carry is set if no more names
  638. ; can be found. 
  639. ;
  640. mfname:    mvi    c,stdma        ; set dma address
  641.     lxi    d,dbuff
  642.     call    bdos
  643.     xra     a        ; clear fcb extension and  record number
  644.     sta    fcbext
  645.     sta    fcbrno
  646.     lda    mfflg1        ; get multi-file flag
  647.     ora    a
  648.     jz    mfile1        ; if zero, not 1st time flag
  649.     lxi    h,dfcb        ; save filename as requested name
  650.     lxi    d,mfreq
  651.     mvi    b,12
  652.     call    blkmov
  653.     lda    dfcb
  654.     sta    mfcur        ; save disk in current fcb
  655.     lxi    h,mfreq        ; set-up for filename search
  656.     lxi    d,dfcb
  657.     mvi    b,12
  658.     call    blkmov
  659.     mvi    c,srchfst    ; do search first
  660.     lxi    d,dfcb
  661.     call    bdos
  662.     jmp    mfile2        ; check if file found
  663. ;
  664. mfile1:    lxi    h,mfcur        ; do search first on current filename
  665.     lxi    d,dfcb
  666.     mvi    b,12
  667.     call    blkmov
  668.     mvi    c,srchfst
  669.     lxi    d,dfcb
  670.     call    bdos
  671.     lxi    h,mfreq        ; do search next on requested filename
  672.     lxi    d,dfcb
  673.     mvi    b,12
  674.     call    blkmov
  675.     mvi    c,srchnxt
  676.     lxi    d,dfcb
  677.     call    bdos
  678. mfile2:    inr    a        ; return carry set, if file not found
  679.     stc
  680.     rz
  681. ;
  682. ; move name found to current filename
  683. ;
  684.     dcr    a        ; adjust location found
  685.     ani    3
  686.     add    a
  687.     add    a
  688.     add    a
  689.     add    a
  690.     add    a
  691.     adi    81h
  692.     mov    l,a        ; make filename pointer
  693.     mvi    h,0
  694.     push    h        ; save filename pointer
  695.     lxi    d,mfcur+1
  696.     mvi    b,11
  697.     call    blkmov        ; move filename to current filename
  698. ;
  699. ; move filename found to fcb
  700. ;
  701.     pop    h        ; get filename pointer
  702.     lxi    d,dfcb+1
  703.     mvi    b,11
  704.     call    blkmov        ; move filename to fcb
  705. ;
  706. ; setup fcb for subsequent file write operation
  707. ;
  708. rset$fcb:
  709. ;
  710.     lxi    d,dfcb        ; point to source fcb
  711.     lda    src$dsk$num    ; force disk number, in case not logged disk
  712.     stax    d
  713.     xra    a        ; clean-up for new file backup
  714.     sta    fcbext
  715.     sta    fcbrno
  716.     sta    destfcb
  717.     sta    destfcb+12
  718.     sta    destfcb+32
  719.     sta    mfflg1        ; turn off 1st time flag
  720.     ret
  721. ;
  722. ; 
  723. ; 
  724. ;  subroutine to do block moves
  725. ;
  726. blkmov:    mov    a,m        ; copy byte from [HL] to [DE]
  727.     stax    d
  728.     inx    h        ; bump pointers
  729.     inx    d
  730.     dcr    b        ; loop for count in [B]
  731.     jnz    blkmov
  732.     ret
  733. ; 
  734. ;  subroutine to index [BC] by file counter
  735. ;
  736. filepoint:
  737. ;
  738.     lhld    filcnt        ; get file counter
  739.     mvi    h,0        ; force hi ord to 0
  740.     dad    h        ; multiply by 32
  741.     dad    h
  742.     dad    h
  743.     dad    h
  744.     dad    h
  745.     dad    b        ; use as index to file table
  746.     ret
  747. ;
  748. ; subroutine to check for user abort (any key pressed)
  749. ;
  750. abort:    push    h        ; save all registers
  751.     push    d
  752.     push    b
  753.     push    psw
  754.     mvi    c,dircon    ; check direct console i/o (status)
  755.     mvi    e,0ffh        ; input only
  756.     call    bdos
  757.     ora    a        ; set flags
  758.     jz    abortx        ; return, if zero result
  759.     cpi    'C'-40h        ; control-c for abort?
  760.     jnz    abortx        ; just return, if not
  761.     lxi    d,abort$process    ; indicate we are aborting process
  762.     mvi    c,pmessg
  763.     call    bdos
  764.     jmp    exit        ; exit via CP/M warm boot
  765. abortx:    pop    psw        ; restore all registers
  766.     pop    b
  767.     pop    d
  768.     pop    h
  769.     ret
  770. ;
  771. ; subroutine to do carriage return/line feed
  772. ;
  773. crlf:    lxi    d,crlf$msg
  774.     mvi    c,pmessg
  775.     call    bdos
  776.     ret
  777. ; 
  778. ; 
  779. ; 
  780. signon:        db    cr,lf,'ARCHIVE (CTRL-C to Abort) - Ver.1.0'
  781.         db    cr,lf,cr,lf,'$'
  782. ; 
  783. ilgopt:        db    'Invalid or Unspecified Option - Must Be Specified As:'
  784.         db    cr,lf,cr,lf
  785. opts:        db    tab,'B - Backup File Archive or,'
  786.         db    cr,lf
  787.         db    tab,'S - Set File Archive or,'
  788.         db    cr,lf
  789.         db    tab,'R - Reset File Archive or,'
  790.         db    cr,lf
  791.         db    tab,'D - Display File Archive'
  792.         db    cr,lf,'$'
  793. ; 
  794. no$file$fnd:    db    cr,lf,'File Not Found, Aborting$'
  795. ; 
  796. donmsg:        db    '  ','$'
  797. ; 
  798. crlf$msg:    db    cr,lf,'$'
  799. ; 
  800. bad$ver$num:    db    'Must be CP/M Version 2.2 to Archive, Aborting$'
  801. ;
  802.     if    not mpm        ; archive must be 'installed' in CP/M-80
  803. noarch:        db    'Archiving Not Installed, Aborting$'
  804.     endif            ; endif MP/M    
  805. ;
  806. req$dest:    db    'Destination Disk for BACKUP Files (A to P)? $'
  807. ;
  808. same$dsk:    db    cr,lf,'Can''t BACKUP to Source Disk You TWIT!',cr,lf,'$'
  809. ;
  810. abort$process:    db    cr,lf,'User Abort of ARCHIVE Process$'
  811. ;
  812. narcs:        db    cr,lf,'No ARCHIVE Files Found to BACKUP$' 
  813. ;
  814. no$file$nam:    db    'No Filename or Option Specified - '
  815.         db    'ARCHIVE must be invoked as:'
  816.         db    cr,lf,cr,lf
  817.         db    tab,'ARCHIVE FN.FT OPTION<cr>'
  818.         db    cr,lf,cr,lf
  819.         db    'Where;',tab,'FN.FT is Filename and Filetype '
  820.         db    '(? and * allowed)'
  821.         db    cr,lf,cr,lf
  822.         db    'And;',tab,'OPTION is specified as:'
  823.         db    cr,lf,cr,lf,'$'
  824. ; 
  825. src$open$err:    db    cr,lf,'Oops, Can''t Open File on Source Disk$'
  826. ; 
  827. dsk$full:    db    cr,lf,'Destination BACKUP Disk $'
  828. ;
  829. now$full:    db    ': is now FULL - Remove, insert NEW Disk$'
  830. ;
  831. enter$ret:    db    cr,lf,'Enter RETURN when ready to continue BACKUP process: $'
  832. ; 
  833. src$read$err:    db    cr,lf,'Oops, Read Error on Source Disk$'
  834. ; 
  835. src$close$err:    db    cr,lf,'Oops, Bad Close on Destination Disk$'
  836. ;
  837. bakup$done:    db    cr,lf,'BACKUP Complete',cr,lf,'$'
  838. ;
  839. fname:        db    '            $'    ; 11 spaces for filename.typ
  840. ;
  841. got$arc:    db    0    ; archive file found flag (1 = found)
  842. ;
  843. mfflg1:        db    1    ; 1st time flag for multi-file access
  844. ;
  845. mfreq:        ds    12    ; multi-file requested filename
  846. ;
  847. mfcur:        ds    12    ; multi-file current filename
  848. ;
  849. arch$addr:    ds    2    ; archive patch address
  850. ;
  851. logdsk:        ds    1    ; current logged-in disk number
  852. ; 
  853. dest$dsk$num:    ds    1    ; destination disk number
  854. ;
  855. src$dsk$num:    ds    1    ; source disk number
  856. ;
  857. filcnt:        ds    1    ; count of files in filetable
  858. ;
  859. option:        ds    1    ; storage for B, S, R or D option letter
  860. ;
  861. destfcb:    ds    33    ; destination disk file control block
  862. ;
  863. bufmax:        ds    2    ; buffer maximum size
  864. ;
  865. bufcnt:        ds    2    ; buffer sector count
  866. ;
  867. bufpnt:        ds    2    ; buffer pointer
  868. ;
  869. eof$flg:    ds    1    ; end-of-file flag
  870. ;
  871. filetable    equ    $        ; file table/buffer starts here
  872.         ds    4*4096        ; 16k buffer
  873. table$end    equ    $        ; file table/buffer ends here
  874. ; 
  875. ;
  876. ;
  877.     end
  878.