home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / cpm / basic / math.ark / TIME.BAS < prev    next >
Encoding:
BASIC Source File  |  1986-12-21  |  2.1 KB  |  71 lines
  1. 10 REM THIS IS PROGRAM "TIME" LOCAL SIDERIAL TIME IS CALCULATED
  2. 20 REM GIVEN THE DATE, HOUR, MINIT AND SECOND AND THE OBSERVER'S LONGITUDE
  3. 30 REM PROGRAM IS BY MIKE FINERTY MAKING USE OF PROGRAMS IN SKY AND TELESCOPE'S
  4. 40 REM COMPUTER SECTION.
  5. 50 DEFDBL A-Z
  6. 60 PRINT "PLEASE INPUT DATA: "
  7. 70 INPUT "LONGITUDE = ";L2
  8. 80 LPRINT "LONGITUDE = ";L2;" DEGREES"
  9. 90 L2 = L2/15
  10. 100 REM L2 IS NOW LONGITUDE IN DECIMAL HOURS
  11. 110 INPUT "YEAR =";Y
  12. 120 LPRINT "YEAR = ";Y
  13. 130 INPUT "MONTH = ";M
  14. 140 LPRINT "MONTH = ";M
  15. 150 INPUT "DAY = ";D2
  16. 160 LPRINT "DAY =";D2
  17. 170 REM THIS IS UNIVERSAL TIME
  18. 180 INPUT "HOURS =";A1
  19. 190 LPRINT "HOURS =";A1
  20. 200 INPUT "MINUTES =";A2
  21. 210 LPRINT "MINUTES =";A2
  22. 220 INPUT "SECONDS =";A3
  23. 230 LPRINT "SECONDS =";A3
  24. 240 F1 = (A3+60*A2+3600*A1)/86400!-.5
  25. 250 J = - INT(7*(INT((M+9)/12)+Y)/4)
  26. 260 S = SGN(M-9)
  27. 270 A4 = ABS(M-9)
  28. 280 J1 = INT(Y+S*INT(A4/7))
  29. 290 J1 = - INT((INT(J1/100)+1)*3/4)
  30. 300 J = J + INT(275*M/9)+D2+J1
  31. 310 J = J+1.72103E+06+367*Y
  32. 320 J = J - 2
  33. 330 PRINT "JULIAN DAY: ";J;" FRACTION OF A DAY:";F1
  34. 340 LPRINT "JULIAN DAY: ";J;" FRACTION OF A DAY:";F1
  35. 350 REM CALCULATE GREENWICH SIDERIAL TIME FIRST
  36. 360 D = J -2.45155E+06
  37. 370 D = D - 5
  38. 380 T = D/36525!
  39. 390 T1 = INT(T)
  40. 400 J0 = T1*36525!+2.45155E+06
  41. 410 J0 = J0 -5
  42. 420 T2 =(J - J0 +.5)/36525!
  43. 430 S0 = 24110.54841#+184.812866#*T1
  44. 440 S0 = S0 + 8640184.812860002#*T2
  45. 450 S0 = S0 + (.093104*T*T)
  46. 460 S0 = S0 -(.0000062*T*T*T)
  47. 470 S0 = S0/86400!
  48. 480 S1 = INT(S0)
  49. 490 S0 = S0 - S1
  50. 500 S0 = 24*(S0+(F1+.5)*1.002737909#)
  51. 510 IF S0<0 THEN S0 = S0+24
  52. 520 IF S0>24 THEN S0 = S0 - 24
  53. 530 LST = S0 - L2
  54. 540 LSTDEG = LST*15
  55. 550 IF LST < 0 THEN LST = LST + 24
  56. 560 PRINT "LOCAL SIDERIAL ANGLE (ARIES) IN DECIMAL DEGREES: ";LSTDEG
  57. 570 H = INT(LST)
  58. 580 M1 = 60 * (LST - H)
  59. 590 M = INT(M1)
  60. 600 S = 60 * (M1 - M)
  61. 610 PRINT "LOCAL SIDERIAL TIME:";H;"HRS";M;"MINS";S;"SECS"
  62. 620 LPRINT "LOCAL SIDERIAL TIME:";H;"HRS";M;"MINS";S;"SECS"
  63. 630 PRINT "DO YOU WANT A DIFFERENT TIME? Y/N?"
  64. 640 INPUT ANS$
  65. 650 IF ANS$ = "Y" THEN 100
  66. 660 END
  67. ;"HRS";M;"MINS";S;"SECS"
  68. 630 PRINT "DO YOU WANT A DIFFERENT TIME? Y/N?"
  69. 640 INPUT ANS$
  70. 650 IF ANS$ = "Y" THEN 100
  71.