home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / dos_ency / 15 / template.asm next >
Encoding:
Assembly Source File  |  1988-08-11  |  8.5 KB  |  330 lines
  1.         name    template
  2.         title   'TEMPLATE --- installable driver template'
  3.  
  4. ;
  5. ; TEMPLATE.ASM:  A program skeleton for an installable
  6. ;                device driver (MS-DOS 2.0 or later)
  7. ;
  8. ; The driver command-code routines are stubs only and have
  9. ; no effect but to return a nonerror "Done" status.
  10. ; 
  11. ; Ray Duncan, July 1987
  12. ;
  13.  
  14. _TEXT   segment byte public 'CODE'
  15.  
  16.         assume  cs:_TEXT,ds:_TEXT,es:NOTHING
  17.  
  18.         org     0
  19.  
  20. MaxCmd  equ     24              ; maximum allowed command code
  21.                                 ; 12 for MS-DOS 2.x
  22.                                 ; 16 for MS-DOS 3.0-3.1
  23.                                 ; 24 for MS-DOS 3.2-3.3
  24.  
  25. cr      equ     0dh             ; ASCII carriage return
  26. lf      equ     0ah             ; ASCII linefeed
  27. eom     equ     '$'             ; end-of-message signal
  28.  
  29.  
  30. Header:                         ; device driver header
  31.         dd      -1              ; link to next device driver
  32.         dw      c840h           ; device attribute word
  33.         dw      Strat           ; "Strategy" routine entry point
  34.         dw      Intr            ; "Interrupt" routine entry point
  35.         db      'TEMPLATE'      ; logical device name
  36.  
  37.  
  38. RHPtr   dd      ?               ; pointer to request header, passed
  39.                                 ; by MS-DOS kernel to Strategy routine
  40.  
  41.  
  42. Dispatch:                       ; Interrupt routine command code
  43.                                 ; dispatch table
  44.         dw      Init            ; 0  = initialize driver
  45.         dw      MediaChk        ; 1  = media check on block device
  46.         dw      BuildBPB        ; 2  = build BIOS parameter block
  47.         dw      IoctlRd         ; 3  = I/O control read
  48.         dw      Read            ; 4  = read (input) from device
  49.         dw      NdRead          ; 5  = nondestructive read
  50.         dw      InpStat         ; 6  = return current input status
  51.         dw      InpFlush        ; 7  = flush device input buffers
  52.         dw      Write           ; 8  = write (output) to device
  53.         dw      WriteVfy        ; 9  = write with verify
  54.         dw      OutStat         ; 10 = return current output status
  55.         dw      OutFlush        ; 11 = flush output buffers
  56.         dw      IoctlWt         ; 12 = I/O control write
  57.         dw      DevOpen         ; 13 = device open       (MS-DOS 3.0+)
  58.         dw      DevClose        ; 14 = device close      (MS-DOS 3.0+)
  59.         dw      RemMedia        ; 15 = removable media   (MS-DOS 3.0+)
  60.         dw      OutBusy         ; 16 = output until busy (MS-DOS 3.0+)
  61.         dw      Error           ; 17 = not used
  62.         dw      Error           ; 18 = not used
  63.         dw      GenIOCTL        ; 19 = generic IOCTL     (MS-DOS 3.2+)
  64.         dw      Error           ; 20 = not used
  65.         dw      Error           ; 21 = not used
  66.         dw      Error           ; 22 = not used
  67.         dw      GetLogDev       ; 23 = get logical device (MS-DOS 3.2+)
  68.         dw      SetLogDev       ; 24 = set logical device (MS-DOS 3.2+)
  69.  
  70.  
  71. Strat   proc    far             ; device driver Strategy routine,
  72.                                 ; called by MS-DOS kernel with
  73.                                 ; ES:BX = address of request header
  74.  
  75.                                 ; save pointer to request header
  76.         mov     word ptr cs:[RHPtr],bx
  77.         mov     word ptr cs:[RHPtr+2],es
  78.  
  79.         ret                     ; back to MS-DOS kernel
  80.  
  81. Strat   endp
  82.  
  83.  
  84. Intr    proc    far             ; device driver Interrupt routine,
  85.                                 ; called by MS-DOS kernel immediately
  86.                                 ; after call to Strategy routine
  87.  
  88.         push    ax              ; save general registers
  89.         push    bx
  90.         push    cx
  91.         push    dx
  92.         push    ds
  93.         push    es
  94.         push    di
  95.         push    si
  96.         push    bp
  97.  
  98.         push    cs              ; make local data addressable
  99.         pop     ds              ; by setting DS = CS
  100.  
  101.         les     di,[RHPtr]      ; let ES:DI = request header
  102.  
  103.                                 ; get BX = command code
  104.         mov     bl,es:[di+2]
  105.         xor     bh,bh
  106.         cmp     bx,MaxCmd       ; make sure it's valid
  107.         jle     Intr1           ; jump, function code is ok
  108.         call    Error           ; set error bit, "Unknown Command" code
  109.         jmp     Intr2
  110.  
  111. Intr1:  shl     bx,1            ; form index to dispatch table
  112.                                 ; and branch to command-code routine
  113.         call    word ptr [bx+Dispatch]
  114.  
  115.         les     di,[RHPtr]      ; ES:DI = address of request header
  116.  
  117. Intr2:  or      ax,0100h        ; merge Done bit into status and
  118.         mov     es:[di+3],ax    ; store status into request header
  119.  
  120.         pop     bp              ; restore general registers
  121.         pop     si
  122.         pop     di
  123.         pop     es
  124.         pop     ds
  125.         pop     dx
  126.         pop     cx
  127.         pop     bx
  128.         pop     ax
  129.         ret                     ; return to MS-DOS kernel
  130.  
  131.  
  132. ; Command-code routines are called by the Interrupt routine
  133. ; via the dispatch table with ES:DI pointing to the request
  134. ; header. Each routine should return AX = 00H if function was
  135. ; completed successfully or AX = 8000H + error code if
  136. ; function failed.
  137.  
  138.  
  139. MediaChk proc   near            ; function 1 = Media Check
  140.  
  141.         xor     ax,ax
  142.         ret
  143.  
  144. MediaChk endp
  145.  
  146.  
  147. BuildBPB proc   near            ; function 2 = Build BPB
  148.  
  149.         xor     ax,ax
  150.         ret
  151.  
  152. BuildBPB endp
  153.  
  154.  
  155. IoctlRd proc    near            ; function 3 = I/O Control Read
  156.  
  157.         xor     ax,ax
  158.         ret
  159.  
  160. IoctlRd endp
  161.  
  162.  
  163. Read    proc    near            ; function 4 = Read (Input)
  164.  
  165.         xor     ax,ax
  166.         ret
  167.  
  168. Read    endp
  169.  
  170.  
  171. NdRead  proc    near            ; function 5 = Nondestructive Read
  172.  
  173.         xor     ax,ax
  174.         ret
  175.  
  176. NdRead  endp
  177.  
  178.  
  179. InpStat proc    near            ; function 6 = Input Status
  180.  
  181.         xor     ax,ax
  182.         ret
  183.  
  184. InpStat endp
  185.  
  186.  
  187. InpFlush proc   near            ; function 7 = Flush Input Buffers
  188.  
  189.         xor     ax,ax
  190.         ret
  191.  
  192. InpFlush endp
  193.  
  194.  
  195. Write   proc    near            ; function 8 = Write (Output)
  196.  
  197.         xor     ax,ax
  198.         ret
  199.  
  200. Write   endp
  201.  
  202.  
  203. WriteVfy proc   near            ; function 9 = Write with Verify
  204.  
  205.         xor     ax,ax
  206.         ret
  207.  
  208. WriteVfy endp
  209.  
  210.  
  211. OutStat proc    near            ; function 10 = Output Status
  212.  
  213.         xor     ax,ax
  214.         ret
  215.  
  216. OutStat endp
  217.  
  218.  
  219. OutFlush proc   near            ; function 11 = Flush Output Buffers
  220.  
  221.         xor     ax,ax
  222.         ret
  223.  
  224. OutFlush endp
  225.  
  226.  
  227. IoctlWt proc    near            ; function 12 = I/O Control Write
  228.  
  229.         xor     ax,ax
  230.         ret
  231.  
  232. IoctlWt endp
  233.  
  234.  
  235. DevOpen proc    near            ; function 13 = Device Open
  236.  
  237.         xor     ax,ax
  238.         ret
  239.  
  240. DevOpen endp
  241.  
  242.  
  243. DevClose proc   near            ; function 14 = Device Close
  244.  
  245.         xor     ax,ax
  246.         ret
  247.  
  248. DevClose endp
  249.  
  250.  
  251. RemMedia proc   near            ; function 15 = Removable Media
  252.  
  253.         xor     ax,ax
  254.         ret
  255.  
  256. RemMedia endp
  257.  
  258.  
  259. OutBusy proc    near            ; function 16 = Output Until Busy
  260.  
  261.         xor     ax,ax
  262.         ret
  263.  
  264. OutBusy endp
  265.  
  266.  
  267. GenIOCTL proc   near            ; function 19 = Generic IOCTL
  268.  
  269.         xor     ax,ax
  270.         ret
  271.  
  272. GenIOCTL endp
  273.  
  274.  
  275. GetLogDev proc  near            ; function 23 = Get Logical Device
  276.  
  277.         xor     ax,ax
  278.         ret
  279.  
  280. GetLogDev endp
  281.  
  282.  
  283. SetLogDev proc  near            ; function 24 = Set Logical Device
  284.  
  285.         xor     ax,ax
  286.         ret
  287.  
  288. SetLogDev endp
  289.  
  290.  
  291. Error   proc    near            ; bad command code in request header
  292.  
  293.         mov     ax,8003h        ; error bit + "Unknown Command" code
  294.         ret
  295.  
  296. Error   endp
  297.  
  298.  
  299. Init    proc    near            ; function 0 = initialize driver
  300.  
  301.         push    es              ; save address of request header
  302.         push    di
  303.  
  304.         mov     ah,9            ; display driver sign-on message
  305.         mov     dx,offset Ident
  306.         int     21h
  307.  
  308.         pop     di              ; restore request header address
  309.         pop     es
  310.  
  311.                                 ; set address of free memory 
  312.                                 ; above driver (break address)
  313.         mov     word ptr es:[di+14],offset Init
  314.         mov     word ptr es:[di+16],cs
  315.  
  316.         xor     ax,ax           ; return status
  317.         ret
  318.  
  319. Init    endp
  320.  
  321. Ident   db      cr,lf,lf
  322.         db      'TEMPLATE Example Device Driver'
  323.         db      cr,lf,eom
  324.  
  325. Intr    endp
  326.  
  327. _TEXT   ends
  328.  
  329.         end
  330.