home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / dos_ency / 14 / execsort.asm next >
Encoding:
Assembly Source File  |  1988-08-11  |  8.0 KB  |  193 lines
  1.         name    execsort
  2.         title   'EXECSORT --- demonstrate EXEC of filter'
  3.         .sall
  4. ;
  5. ; EXECSORT.ASM --- demonstration of use of EXEC to run the SORT
  6. ; filter as a child process, redirecting its input and output.
  7. ; This program requires the files SORT.EXE and MYFILE.DAT in
  8. ; the current drive and directory.
  9. ; 
  10. ; Ray Duncan, June 1987
  11. ;
  12.  
  13. stdin   equ     0                       ; standard input
  14. stdout  equ     1                       ; standard output
  15. stderr  equ     2                       ; standard error
  16.  
  17. stksize equ     128                     ; size of stack
  18.  
  19. cr      equ     0dh                     ; ASCII carriage return
  20. lf      equ     0ah                     ; ASCII linefeed
  21.  
  22. jerr    macro   target                  ;; Macro to test carry flag
  23.         local   notset                  ;; and jump if flag set.
  24.         jnc     notset                  ;; Uses JMP DISP16 to avoid
  25.         jmp     target                  ;; branch out of range errors
  26. notset:
  27.         endm
  28.  
  29.  
  30. DGROUP  group   _DATA,_STACK            ; 'automatic data group'
  31.  
  32.  
  33. _TEXT   segment byte public 'CODE'      ; executable code segment
  34.  
  35.         assume  cs:_TEXT,ds:DGROUP,ss:_STACK
  36.  
  37.  
  38. stk_seg dw      ?                       ; original SS contents
  39. stk_ptr dw      ?                       ; original SP contents 
  40.  
  41.  
  42. main    proc    far                     ; entry point from MS-DOS
  43.  
  44.         mov     ax,DGROUP               ; set DS = our data segment
  45.         mov     ds,ax
  46.  
  47.                                         ; now give back extra memory so
  48.                                         ; child SORT has somewhere to run...
  49.         mov     ax,es                   ; let AX = segment of PSP base
  50.         mov     bx,ss                   ; and BX = segment of stack base
  51.         sub     bx,ax                   ; reserve seg stack - seg psp 
  52.         add     bx,stksize/16           ; plus paragraphs of stack
  53.         mov     ah,4ah                  ; fxn 4AH = modify memory block
  54.         int     21h                     ; transfer to MS-DOS
  55.         jerr    main1                   ; jump if resize block failed
  56.  
  57.                                         ; prepare stdin and stdout
  58.                                         ; handles for child SORT process
  59.  
  60.         mov     bx,stdin                ; dup the handle for stdin
  61.         mov     ah,45h
  62.         int     21h                     ; transfer to MS-DOS
  63.         jerr    main1                   ; jump if dup failed
  64.         mov     oldin,ax                ; save dup'd handle     
  65.  
  66.         mov     dx,offset DGROUP:infile ; now open the input file
  67.         mov     ax,3d00h                ; mode = read-only
  68.         int     21h                     ; transfer to MS-DOS
  69.         jerr    main1                   ; jump if open failed
  70.  
  71.         mov     bx,ax                   ; force stdin handle to
  72.         mov     cx,stdin                ; track the input file handle
  73.         mov     ah,46h
  74.         int     21h                     ; transfer to MS-DOS
  75.         jerr    main1                   ; jump if force dup failed
  76.  
  77.         mov     bx,stdout               ; dup the handle for stdout
  78.         mov     ah,45h
  79.         int     21h                     ; transfer to MS-DOS
  80.         jerr    main1                   ; jump if dup failed
  81.         mov     oldout,ax               ; save dup'd handle
  82.  
  83.         mov     dx,offset dGROUP:outfile ; now create the output file
  84.         mov     cx,0                    ; normal attribute
  85.         mov     ah,3ch
  86.         int     21h                     ; transfer to MS-DOS 
  87.         jerr    main1                   ; jump if create failed
  88.  
  89.         mov     bx,ax                   ; force stdout handle to
  90.         mov     cx,stdout               ; track the output file handle
  91.         mov     ah,46h
  92.         int     21h                     ; transfer to MS-DOS
  93.         jerr    main1                   ; jump if force dup failed
  94.  
  95.                                         ; now EXEC the child SORT, 
  96.                                         ; which will inherit redirected
  97.                                         ; stdin and stdout handles
  98.  
  99.         push    ds                      ; save EXECSORT's data segment
  100.         mov     stk_seg,ss              ; save EXECSORT's stack pointer
  101.         mov     stk_ptr,sp
  102.  
  103.         mov     ax,ds                   ; set ES = DS
  104.         mov     es,ax
  105.         mov     dx,offset DGROUP:cname  ; DS:DX = child pathname
  106.         mov     bx,offset DGROUP:pars   ; EX:BX = parameter block
  107.         mov     ax,4b00h                ; function 4BH, subfunction 00H
  108.         int     21h                     ; transfer to MS-DOS
  109.  
  110.         cli                             ; (for bug in some early 8088s)
  111.         mov     ss,stk_seg              ; restore execsort's stack pointer
  112.         mov     sp,stk_ptr
  113.         sti                             ; (for bug in some early 8088s)
  114.         pop     ds                      ; restore DS = our data segment
  115.  
  116.         jerr    main1                   ; jump if EXEC failed
  117.  
  118.         mov     bx,oldin                ; restore original meaning of
  119.         mov     cx,stdin                ; standard input handle for
  120.         mov     ah,46h                  ; this process
  121.         int     21h
  122.         jerr    main1                   ; jump if force dup failed
  123.  
  124.         mov     bx,oldout               ; restore original meaning
  125.         mov     cx,stdout               ; of standard output handle
  126.         mov     ah,46h                  ; for this process
  127.         int     21h
  128.         jerr    main1                   ; jump if force dup failed
  129.  
  130.         mov     bx,oldin                ; close dup'd handle of 
  131.         mov     ah,3eh                  ; original stdin
  132.         int     21h                     ; transfer to MS-DOS
  133.         jerr    main1                   ; jump if close failed
  134.  
  135.         mov     bx,oldout               ; close dup'd handle of 
  136.         mov     ah,3eh                  ; original stdout
  137.         int     21h                     ; transfer to MS-DOS
  138.         jerr    main1                   ; jump if close failed
  139.  
  140.                                         ; display success message
  141.         mov     dx,offset DGROUP:msg1   ; address of message
  142.         mov     cx,msg1_len             ; message length
  143.         mov     bx,stdout               ; handle for standard output
  144.         mov     ah,40h                  ; fxn 40H = write file or device
  145.         int     21h                     ; transfer to MS-DOS
  146.         jerr    main1
  147.         
  148.         mov     ax,4c00h                ; no error, terminate program 
  149.         int     21h                     ; with return code = 0
  150.  
  151. main1:  mov     ax,4c01h                ; error, terminate program
  152.         int     21h                     ; with return code = 1 
  153.  
  154. main    endp                            ; end of main procedure
  155.  
  156. _TEXT   ends
  157.  
  158.  
  159. _DATA   segment para public 'DATA'      ; static & variable data segment
  160.  
  161. infile  db      'MYFILE.DAT',0          ; input file for SORT filter
  162. outfile db      'MYFILE.SRT',0          ; output file for SORT filter
  163.  
  164. oldin   dw      ?                       ; dup of old stdin handle
  165. oldout  dw      ?                       ; dup of old stdout handle      
  166.  
  167. cname   db      'SORT.EXE',0            ; pathname of child SORT process
  168.  
  169. pars    dw      0                       ; segment of environment block
  170.                                         ; (0 = inherit parent's)
  171.         dd      tail                    ; long address, command tail
  172.         dd      -1                      ; long address, default FCB #1
  173.                                         ; (-1 = none supplied)
  174.         dd      -1                      ; long address, default FCB #2
  175.                                         ; (-1 = none supplied)
  176.  
  177. tail    db      0,cr                    ; empty command tail for child
  178.  
  179. msg1    db      cr,lf,'SORT was executed as child.',cr,lf
  180. msg1_len equ    $-msg1 
  181.  
  182. _DATA   ends
  183.  
  184.  
  185. _STACK  segment para stack 'STACK'
  186.  
  187.         db      stksize dup (?)
  188.  
  189. _STACK  ends
  190.  
  191.  
  192.         end     main                    ; defines program entry point
  193.