home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch19 / asmhelp.asm next >
Encoding:
Assembly Source File  |  1988-12-12  |  8.6 KB  |  277 lines
  1.     title    ASMHELP -- Sample MASM DLL
  2.         page    55,132
  3.     .286
  4.  
  5. ; 
  6. ; ASMHELP.ASM
  7. ;
  8. ; Source code for the MASM dynlink library ASMHELP.DLL.
  9. ;
  10. ; Assemble with:  C> masm asmhelp.asm;
  11. ; Link with:  C> link asmhelp,asmhelp.dll,,os2,asmhelp
  12. ;
  13. ; Exports two routines for use by MASM programs:
  14. ;
  15. ; ARGC  Returns count of command line arguments.
  16. ;       Treats blanks and tabs as whitespace.
  17. ;
  18. ;       Calling sequence:
  19. ;
  20. ;       push    seg argcnt      ; receives argument count
  21. ;       push    offset argcnt
  22. ;       call    ARGC
  23. ;
  24. ; ARGV  Returns address and length of specified
  25. ;       command line argument.  If called for 
  26. ;       argument 0, returns address and length
  27. ;    of fully qualified pathname of program.
  28. ;
  29. ;       Calling sequence:
  30. ;
  31. ;       push    argno           ; argument number
  32. ;       push    seg argptr      ; receives argument address
  33. ;       push    offset argptr
  34. ;       push    seg arglen      ; receives argument length
  35. ;       push    offset arglen
  36. ;       call    ARGV
  37. ;
  38. ; Copyright (C) 1988 Ray Duncan
  39. ;
  40.  
  41. tab     equ     09h             ; ASCII tab
  42. blank   equ     20h             ; ASCII space character
  43.  
  44.         extrn   DosGetEnv:far
  45.  
  46. DGROUP  group   _DATA
  47.  
  48.  
  49. _DATA   segment word public 'DATA'
  50.  
  51. envseg  dw      ?               ; environment selector
  52. cmdoffs dw      ?               ; command tail offset
  53.  
  54. _DATA   ends
  55.  
  56.  
  57. _TEXT   segment word public 'CODE'
  58.  
  59.         assume  cs:_TEXT,ds:DGROUP
  60.  
  61.                                 ; parameter for argc
  62. argcnt  equ     [bp+6]          ; receives argument count
  63.  
  64.         public  argc
  65. argc    proc    far             ; count command line arguments
  66.  
  67.         push    bp              ; make arguments addressable
  68.         mov     bp,sp
  69.  
  70.         push    ds              ; save registers
  71.         push    es
  72.         push    bx
  73.         push    cx
  74.  
  75.         mov     ax,seg DGROUP   ; point to instance data
  76.         mov     ds,ax
  77.  
  78.         mov     es,envseg       ; set ES:BX = command line
  79.         mov     bx,cmdoffs
  80.  
  81.         mov     ax,1            ; initialize argument count
  82.  
  83. argc0:  inc     bx              ; ignore useless first field
  84.         cmp     byte ptr es:[bx],0      
  85.         jne     argc0
  86.  
  87. argc1:  mov     cx,-1           ; set flag = outside argument
  88.  
  89. argc2:  inc     bx              ; point to next character 
  90.  
  91.         cmp     byte ptr es:[bx],0
  92.         je      argc3           ; exit if null byte
  93.  
  94.         cmp     byte ptr es:[bx],blank
  95.         je      argc1           ; outside argument if ASCII blank
  96.  
  97.         cmp     byte ptr es:[bx],tab    
  98.         je      argc1           ; outside argument if ASCII tab
  99.  
  100.                                 ; otherwise not blank or tab,
  101.         jcxz    argc2           ; jump if already inside argument
  102.  
  103.         inc     ax              ; else found argument, count it
  104.         not     cx              ; set flag = inside argument
  105.         jmp     argc2           ; and look at next character
  106.  
  107. argc3:                          ; store result into
  108.                                 ; caller's variable...
  109.  
  110.         les     bx,argcnt       ; get address of variable
  111.         mov     es:[bx],ax      ; store argument count
  112.  
  113.         pop     cx              ; restore registers
  114.         pop     bx
  115.         pop     es
  116.         pop     ds
  117.         pop     bp
  118.  
  119.         xor     ax,ax           ; signal success
  120.  
  121.         ret     4               ; return to caller      
  122.                                 ; and discard parameters
  123. argc    endp
  124.  
  125.  
  126.  
  127.                 ; parameters for argv...
  128. argno   equ     [bp+14]         ; argument number
  129. argptr  equ     [bp+10]         ; receives argument pointer
  130. arglen  equ     [bp+6]          ; receives argument length
  131.  
  132.         public  argv
  133. argv    proc    far        ; get address and length of
  134.                                 ; command tail argument
  135.  
  136.         push    bp              ; make arguments addressable
  137.         mov     bp,sp
  138.  
  139.         push    ds              ; save registers
  140.         push    es
  141.         push    bx
  142.         push    cx
  143.         push    di      
  144.  
  145.         mov     ax,seg DGROUP   ; point to instance data
  146.         mov     ds,ax
  147.  
  148.         mov     es,envseg       ; set ES:BX = command line
  149.         mov     bx,cmdoffs
  150.  
  151.         mov     ax,argno        ; get argument number
  152.         or      ax,ax           ; requesting argument 0?
  153.         jz      argv8           ; yes, get program name
  154.  
  155. argv1:  inc     bx              ; scan off first field
  156.         cmp     byte ptr es:[bx],0      
  157.         jne     argv1
  158.  
  159.         xor     ah,ah           ; initialize argument counter
  160.  
  161. argv2:  mov     cx,-1           ; set flag = outside argument
  162.  
  163. argv3:  inc     bx              ; point to next character 
  164.  
  165.         cmp     byte ptr es:[bx],0
  166.         je      argv7           ; exit if null byte
  167.  
  168.         cmp     byte ptr es:[bx],blank
  169.         je      argv2           ; outside argument if ASCII blank
  170.  
  171.         cmp     byte ptr es:[bx],tab    
  172.         je      argv2           ; outside argument if ASCII tab
  173.  
  174.                                 ; if not blank or tab...
  175.         jcxz    argv3           ; jump if inside argument
  176.  
  177.         inc     ah              ; else count arguments found
  178.         cmp     ah,al           ; is this the one?
  179.         je      argv4           ; yes, go find its length
  180.  
  181.         not     cx              ; no, set flag = inside argument
  182.         jmp     argv3           ; and look at next character
  183.  
  184. argv4:                          ; found desired argument, now
  185.                                 ; determine its length...
  186.         mov     ax,bx           ; save param. starting address 
  187.  
  188. argv5:  inc     bx              ; point to next character
  189.  
  190.         cmp     byte ptr es:[bx],0
  191.         je      argv6           ; found end if null byte
  192.  
  193.         cmp     byte ptr es:[bx],blank
  194.         je      argv6           ; found end if ASCII blank
  195.  
  196.         cmp     byte ptr es:[bx],tab    
  197.         jne     argv5           ; found end if ASCII tab
  198.  
  199. argv6:  xchg    bx,ax           ; set ES:BX = argument address
  200.         sub     ax,bx           ; and AX = argument length
  201.         jmp     argv10          ; return to caller
  202.  
  203. argv7:  mov     ax,1            ; set AX != 0 indicating  
  204.                                 ; error, argument not found
  205.         jmp     argv11          ; return to caller
  206.  
  207. argv8:                ; special handling for argv = 0
  208.         xor     di,di           ; find the program name by
  209.         xor     al,al           ; first skipping over all the
  210.         mov     cx,-1           ; environment variables...
  211.         cld
  212.  
  213. argv9:    repne scasb        ; scan for double null (can't use SCASW
  214.     scasb            ; because it might be odd address)
  215.         jne     argv9           ; loop if it was a single null
  216.  
  217.         mov     bx,di           ; save program name address
  218.         mov     cx,-1           ; now find its length... 
  219.         repne scasb             ; scan for another null byte
  220.  
  221.         not     cx              ; convert CX to length 
  222.         dec     cx
  223.         mov     ax,cx           ; return length in AX
  224.  
  225. argv10:                         ; at this point AX = length,
  226.                                 ; ES:BX points to argument
  227.  
  228.         lds     di,argptr       ; address of 1st variable
  229.         mov     ds:[di],bx      ; store argument pointer
  230.         mov     ds:[di+2],es
  231.  
  232.     lds    di,arglen    ; address of second variable
  233.         mov     ds:[di],ax      ; store argument length
  234.  
  235.     xor    ax,ax        ; AX = 0 to signal success
  236.  
  237. argv11:                         ; common exit point
  238.  
  239.         pop     di              ; restore registers
  240.         pop     cx
  241.         pop     bx
  242.         pop     es
  243.         pop     ds
  244.         pop     bp
  245.  
  246.         ret     10              ; return to caller      
  247.                                 ; and discard parameters
  248. argv    endp
  249.  
  250.  
  251. init    proc    far             ; DLL instance initialization
  252.  
  253.                                 ; get environment selector 
  254.                                 ; and offset of command tail
  255.                                 ; for this process...
  256.  
  257.         push    seg DGROUP      ; receives environment selector
  258.         push    offset DGROUP:envseg
  259.         push    seg DGROUP      ; receives command tail offset
  260.         push    offset DGROUP:cmdoffs
  261.         call    DosGetEnv       ; transfer to OS/2      
  262.         or      ax,ax           ; call successful?
  263.         jnz     init1           ; no, initialization error
  264.  
  265.         mov     ax,1            ; initialization OK,
  266.         ret                     ; return AX = 1 for success
  267.  
  268. init1:  xor     ax,ax           ; initialization failed,
  269.         ret                     ; return AX = 0 for error
  270.  
  271. init    endp
  272.  
  273.  
  274. _TEXT   ends
  275.  
  276.         end     init            ; initialization entry point
  277.