home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch15 / clock.asm next >
Encoding:
Assembly Source File  |  1988-12-12  |  6.5 KB  |  178 lines
  1.         title   CLOCK - asynchronous periodic timer example
  2.         page    55,132
  3.         .286
  4. ; 
  5. ; CLOCK.ASM --- Example of an asynchronous periodic 
  6. ; timer.  Displays the current time at one-second 
  7. ; intervals in the upper-right corner of the screen.
  8. ;
  9. ; Copyright (C) 1987 Ray Duncan 
  10. ;
  11. ; Build:        MASM CLOCK;
  12. ;               LINK CLOCK,,,OS2,CLOCK  
  13. ;
  14. ; Usage:        CLOCK
  15. ;
  16. ; Terminate program with Ctrl-C or Ctrl-Break
  17.  
  18. stdin   equ     0
  19. stdout  equ     1
  20. stderr  equ     2
  21.  
  22. cr      equ     0dh                     ; ASCII carriage return
  23. lf      equ     0ah                     ; ASCII line feed
  24. escape  equ     01bh                    ; ASCII escape code
  25.  
  26.         extrn   DosExit:far
  27.         extrn   DosCreateSem:far
  28.         extrn   DosGetInfoSeg:far
  29.         extrn   DosSemWait:far
  30.         extrn   DosSemSet:far
  31.         extrn   DosTimerStart:far
  32.         extrn   DosWrite:far
  33.  
  34. jerr    macro   target                  ;; Macro to test return code
  35.         local   zero                    ;; in AX and jump if non-zero
  36.         or      ax,ax                   ;; Uses JMP16 to avoid
  37.         jz      zero                    ;; branch out of range errors
  38.         jmp     target
  39. zero:
  40.         endm
  41.  
  42. DGROUP  group   _DATA
  43.  
  44. _DATA   segment word public 'DATA'
  45.  
  46. sname   db      '\SEM\CLOCK.SEM',0      ; name of semaphore
  47. shandle dd      ?                       ; handle of semaphore
  48. semflag dw      0                       ; <>0 if creator of semaphore
  49.  
  50. thandle dw      ?                       ; handle of periodic timer
  51.  
  52. wlen    dw      ?                       ; receives actual length written
  53.  
  54. ten     db      10                      ; used by b2a conversion routine 
  55.  
  56. ginfseg dw      ?                       ; global information segment
  57. linfseg dw      ?                       ; local information segment
  58.  
  59. msg1    db      cr,lf,'Unexpected OS/2 Error',cr,lf
  60. msg1_length equ $-msg1
  61.  
  62. msg2    db      escape,'[s'             ; save cursor position
  63.         db      escape,'[0;70H'         ; move to 0,70
  64. msg2a   db      '00:'                   ; hours
  65. msg2b   db      '00:'                   ; minutes
  66. msg2c   db      '00'                    ; seconds
  67.         db      escape,'[u'             ; restore cursor position
  68. msg2_length equ $-msg2
  69.  
  70. _DATA   ends
  71.  
  72.  
  73. _TEXT   segment word public 'CODE'
  74.  
  75.         assume  cs:_TEXT,ds:DGROUP
  76.  
  77. main    proc    far
  78.  
  79.                                         ; get selectors for info segments
  80.         push    ds                      ; receives global selector
  81.         push    offset DGROUP:ginfseg
  82.         push    ds                      ; receives local selector
  83.         push    offset DGROUP:linfseg
  84.         call    DosGetInfoSeg           ; transfer to OS/2      
  85.         jerr    main2                   ; jump if couldn't get selectors
  86.  
  87.                                         ; create system semaphore...
  88.         push    1                       ; exclusive ownership not needed
  89.         push    ds                      ; variable to receive semaphore handle
  90.         push    offset DGROUP:shandle
  91.         push    ds                      ; address of semaphore name
  92.         push    offset DGROUP:sname
  93.         call    DosCreateSem            ; transfer to OS/2
  94.         jerr    main2                   ; jump if sem already exists
  95.  
  96.         push    0                       ; now create periodic timer...
  97.         push    1000                    ; double word for 1000 msec.
  98.         push    word ptr shandle+2      ; handle of our system semaphore
  99.         push    word ptr shandle
  100.         push    ds                      ; variable to receive timer handle
  101.         push    offset DGROUP:thandle
  102.         call    DosTimerStart           ; transfer to OS/2      
  103.         jerr    main2                   ; jump if timer create failed
  104.  
  105. main1:                                  ; display time at 1-sec intervals
  106.  
  107.                                         ; first set our semaphore...
  108.         push    word ptr shandle+2      ; system semaphore handle
  109.         push    word ptr shandle
  110.         call    DosSemSet               ; transfer to OS/2      
  111.         jerr    main2                   ; terminate if set failed
  112.  
  113.         call    display                 ; display current time
  114.  
  115.         push    word ptr shandle+2      ; wait for 1 second timer
  116.         push    word ptr shandle        ; to be triggered
  117.         push    -1                      ; timeout = -1 = wait indefinitely
  118.         push    -1
  119.         call    DosSemWait              ; transfer to OS/2
  120.         or      ax,ax                   ; did wait fail?
  121.         jz      main1                   ; no, loop to display again
  122.  
  123. main2:                                  ; display error message...
  124.         push    stdout                  ; standard output handle
  125.         push    ds                      ; message address
  126.         push    offset msg1
  127.         push    msg1_length             ; message length
  128.         push    ds                      ; receives actual length written        
  129.         push    offset wlen
  130.         call    DosWrite                ; transfer to OS/2
  131.  
  132.         push    1                       ; terminate all threads
  133.         push    1                       ; return error code
  134.         call    DosExit                 ; final exit to OS/2
  135.  
  136. main    endp
  137.  
  138.  
  139. display proc    near                    ; display current time
  140.  
  141.         mov     es,ginfseg              ; get selector for global
  142.                                         ; read-only information segment 
  143.  
  144.         mov     al,byte ptr es:[8]      ; convert hours to ASCII
  145.         cbw
  146.         div     ten
  147.         add     ax,'00'
  148.         mov     word ptr msg2a,ax
  149.  
  150.         mov     al,byte ptr es:[9]      ; convert minutes to ASCII
  151.         cbw
  152.         div     ten
  153.         add     ax,'00'
  154.         mov     word ptr msg2b,ax
  155.  
  156.         mov     al,byte ptr es:[0ah]    ; convert seconds to ASCII
  157.         cbw
  158.         div     ten
  159.         add     ax,'00'
  160.         mov     word ptr msg2c,ax
  161.  
  162.                                         ; display time...
  163.         push    stdout                  ; standard output handle
  164.         push    ds                      ; address of message
  165.         push    offset msg2
  166.         push    msg2_length             ; length of message
  167.         push    ds                      ; receives bytes written
  168.         push    offset wlen
  169.         call    DosWrite                ; transfer to OS/2
  170.  
  171.         ret                             ; back to caller
  172.  
  173. display endp
  174.  
  175. _TEXT   ends
  176.  
  177.         end     main
  178.