home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch12 / exec3.asm < prev    next >
Encoding:
Assembly Source File  |  1988-12-12  |  4.9 KB  |  124 lines
  1.         title   EXEC3.ASM Demo of DosStartSession
  2.         page    55,132
  3.         .286
  4. ; 
  5. ; EXEC3.ASM  Demonstration of DosStartSession, runs CMD.EXE
  6. ;            in a new background session to display a directory,
  7. ;            then waits for a keypress before exiting.
  8. ;            You can use the Task Manager to switch to the
  9. ;            new session and end that session by entering EXIT.
  10. ;            Child session will also be terminated unilaterally
  11. ;            when you press a key to terminate this process.
  12. ; Copyright (C) 1987 Ray Duncan
  13. ;
  14. ; Build:        MASM EXEC3;
  15. ;               LINK EXEC3,,,OS2,EXEC3
  16. ;
  17. ; Usage:        EXEC3
  18. ;               
  19. ; Note:         File CMD.EXE must be available in PATH.
  20.  
  21. stdin   equ     0                       ; standard input handle
  22. stdout  equ     1                       ; standard output handle
  23. stderr  equ     2                       ; standard error handle
  24.  
  25. cr      equ     0dh                     ; ASCII carriage return
  26. lf      equ     0ah                     ; ASCII line feed
  27.  
  28.         extrn   DosExit:far             ; references to OS/2 API
  29.         extrn   DosStartSession:far
  30.         extrn   DosWrite:far
  31.         extrn   KbdCharIn:far
  32.  
  33. DGROUP  group   _DATA
  34.  
  35. _DATA   segment word public 'DATA'
  36.  
  37. argstr  db      ' /k dir/w',0           ; argument string for child
  38. pname   db      'cmd.exe',0             ; pathname for child
  39. stitle  db      'Child Command Processor',0
  40.  
  41. childID dw      0                       ; child process ID
  42. sesID   dw      0                       ; child session ID
  43.  
  44.                                         ; session data...
  45. sinfo   dw      24                      ; length of structure
  46.         dw      1                       ; 0=unrelated, 1=related
  47.         dw      1                       ; 0=foreground, 1=background
  48.         dw      0                       ; 0=nontraceable, 1=traceable
  49.         dd      stitle                  ; session title
  50.         dd      pname                   ; program pathname
  51.         dd      argstr                  ; argument strings
  52.         dd      0                       ; termination queue (not used)
  53.  
  54. kbdinfo db      10 dup (0)              ; character input data
  55. wlen    dw      ?                       ; receives actual bytes written
  56.  
  57. msg1    db      cr,lf,'Unexpected OS/2 Error',cr,lf
  58. msg1_len equ $-msg1
  59.  
  60. msg2    db      cr,lf,'Press any key to terminate parent...',0
  61. msg2_len equ $-msg2
  62.  
  63. _DATA   ends
  64.  
  65.  
  66. _TEXT   segment word public 'CODE'
  67.  
  68.         assume  cs:_TEXT,ds:DGROUP
  69.  
  70. main    proc    far
  71.  
  72.                                         ; run CMD.EXE in a new
  73.                                         ; session as a child process
  74.         push    ds                      ; address of session data
  75.         push    offset DGROUP:sinfo
  76.         push    ds                      ; receives new session ID
  77.         push    offset DGROUP:sesID
  78.         push    ds                      ; receives child process ID
  79.         push    offset DGROUP:childID
  80.         call    DosStartSession         ; transfer to OS/2
  81.         or      ax,ax                   ; did call succeed?
  82.         jnz     error                   ; jump if function failed
  83.  
  84.                                         ; display message,
  85.                                         ; 'Press any key'...
  86.         push    stdout                  ; standard output handle
  87.         push    ds                      ; address of message
  88.         push    offset msg2
  89.         push    msg2_len                ; length of message
  90.         push    ds                      ; receives bytes written 
  91.         push    offset wlen
  92.         call    DosWrite                ; transfer to OS/2
  93.  
  94.                                         ; now wait for key...
  95.         push    ds                      ; receives keyboard data
  96.         push    offset DGROUP:kbdinfo
  97.         push    0                       ; 0=wait for character
  98.         push    0                       ; keyboard handle
  99.         call    KbdCharIn               ; transfer to OS/2
  100.  
  101. exit:                                   ; final exit to OS/2...
  102.         push    1                       ; terminate all threads
  103.         push    0                       ; return success code
  104.         call    DosExit                 ; exit program
  105.  
  106. error:                                  ; display error message
  107.         push    stdout                  ; standard output handle
  108.         push    ds                      ; message address
  109.         push    offset msg1
  110.         push    msg1_len                ; message length
  111.         push    ds                      ; receives bytes written
  112.         push    offset wlen
  113.         call    DosWrite                ; transfer to OS/2
  114.  
  115.         push    1                       ; terminate all threads
  116.         push    1                       ; return error code
  117.         call    DosExit                 ; exit program
  118.  
  119. main    endp
  120.  
  121. _TEXT   ends
  122.  
  123.         end     main
  124.