home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch12 / exec2.asm < prev    next >
Encoding:
Assembly Source File  |  1988-12-12  |  5.0 KB  |  131 lines
  1.         title   EXEC2.ASM Demo of asynchronous child process
  2.         page    55,132
  3.         .286
  4. ; 
  5. ; EXEC2.ASM   Demonstrates use of DosExecPgm and DosCwait to 
  6. ;             run CHKDSK as an asynchronous child process.
  7. ; Copyright (C) 1987 Ray Duncan
  8. ;
  9. ; Build:        MASM EXEC2;
  10. ;               LINK EXEC2,,,OS2,EXEC2
  11. ;
  12. ; Usage:        EXEC2
  13. ;
  14. ; Note:         File CHKDSK.COM must be available in PATH.
  15.  
  16. stdin   equ     0                       ; standard input handle
  17. stdout  equ     1                       ; standard output handle
  18. stderr  equ     2                       ; standard error handle
  19.  
  20. cr      equ     0dh                     ; ASCII carriage return
  21. lf      equ     0ah                     ; ASCII line feed
  22.  
  23.         extrn   DosCwait:far            ; reference to OS/2 API
  24.         extrn   DosExecPgm:far          
  25.         extrn   DosExit:far
  26.         extrn   DosWrite:far
  27.  
  28. DGROUP  group   _DATA
  29.  
  30. _DATA   segment word public 'DATA'
  31.  
  32. objbuff db      64 dup (0)      ; receives name of dynamic link
  33. objbuff_len equ $-objbuff       ; causing DosExecPgm failure    
  34.  
  35.                                 ; argument strings for child
  36. argblk  db      'chkdsk',0      ; simple filename of child
  37.         db      ' *.*',0        ; simulated command tail
  38.         db      0               ; extra null byte terminates block
  39.  
  40.                                 ; receives DosExecPgm info
  41. cinfo   dw      0               ; PID of child process
  42.         dw      0               ; not used
  43.  
  44.                                 ; receives DosCwait info
  45. retcode dw      0               ; termination code for child
  46.         dw      0               ; result code from child's DosExit
  47.  
  48. pname   db      'chkdsk.com',0  ; pathname of child program
  49.  
  50. wlen    dw      ?
  51.  
  52. msg1    db      cr,lf,'Unexpected OS/2 Error',cr,lf
  53. msg1_len equ $-msg1
  54.  
  55. msg2    db      cr,lf,'Exec function successful',cr,lf
  56. msg2_len equ $-msg2
  57.  
  58. _DATA   ends
  59.  
  60.  
  61. _TEXT   segment word public 'CODE'
  62.  
  63.         assume  cs:_TEXT,ds:DGROUP
  64.  
  65. main    proc    far
  66.  
  67.                                         ; run CHKDSK as an asyn-
  68.                                         ; chronous child process...
  69.         push    ds                      ; receives module/entry
  70.         push    offset DGROUP:objbuff   ; point if dynlink fails
  71.         push    objbuff_len             ; length of object buffer
  72.         push    2                       ; 2 = execute asynchronously
  73.         push    ds                      ; address of argument block
  74.         push    offset DGROUP:argblk
  75.         push    0                       ; address of environment
  76.         push    0                       ; (0 = inherit parent's) 
  77.         push    ds                      ; receives child's PID
  78.         push    offset DGROUP:cinfo
  79.         push    ds                      ; name of child program
  80.         push    offset DGROUP:pname
  81.         call    DosExecPgm              ; transfer to OS/2
  82.         or      ax,ax                   ; did child process run?
  83.         jnz     error                   ; jump if function failed
  84.  
  85.                                         ; we could do other 
  86.                                         ; other processing here...
  87.  
  88.                                         ; now resynchronize with
  89.                                         ; child process...
  90.         push    0                       ; 0=immediate child only
  91.         push    0                       ; 0=wait till child ends
  92.         push    ds                      ; receives termination info
  93.         push    offset DGROUP:retcode
  94.         push    ds                      ; receives PID (N/A here)
  95.         push    offset DGROUP:cinfo+2
  96.         push    cinfo                   ; PID of process to wait for
  97.         call    DosCwait                ; transfer to OS/2
  98.  
  99. exit:                                   ; display success message...
  100.         push    stdout                  ; standard output handle
  101.         push    ds                      ; message address
  102.         push    offset msg2
  103.         push    msg2_len                ; message length
  104.         push    ds                      ; receives bytes written
  105.         push    offset wlen
  106.         call    DosWrite                ; transfer to OS/2
  107.  
  108.         push    1                       ; terminate all threads
  109.         push    0                       ; return success code
  110.         call    DosExit                 ; exit program
  111.  
  112. error:                                  ; display error message...
  113.         push    stdout                  ; standard output handle
  114.         push    ds                      ; message address
  115.         push    offset msg1
  116.         push    msg1_len                ; message length
  117.         push    ds                      ; receives bytes written
  118.         push    offset wlen               
  119.         call    DosWrite                ; transfer to OS/2
  120.  
  121.         push    1                       ; terminate all threads
  122.         push    1                       ; return error code
  123.         call    DosExit                 ; exit program
  124.  
  125. main    endp
  126.  
  127. _TEXT   ends
  128.  
  129.         end     main
  130.  
  131.