home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch12 / exec1.asm < prev    next >
Encoding:
Assembly Source File  |  1988-12-12  |  4.2 KB  |  112 lines
  1.         title   EXEC1.ASM Demo of synchronous child process
  2.         page    55,132
  3.         .286
  4. ; 
  5. ; EXEC1.ASM   Demonstrates use of DosExecPgm to run
  6. ;             CHKDSK as a synchronous child process.
  7. ; Copyright (C) 1987 Ray Duncan
  8. ;
  9. ; Build:        MASM EXEC1;
  10. ;               LINK EXEC1,,,OS2,EXEC1
  11. ;
  12. ; Usage:        EXEC1 
  13. ;               
  14. ; Note:         File CHKDSK.COM must be available in PATH.
  15.  
  16. stdin   equ     0                       ; standard input handle
  17. stdout  equ     1                       ; standard output handle
  18. stderr  equ     2                       ; standard error handle
  19.  
  20. cr      equ     0dh                     ; ASCII carriage return
  21. lf      equ     0ah                     ; ASCII line feed
  22.  
  23.         extrn   DosExecPgm:far          ; reference to OS/2 API
  24.         extrn   DosExit:far
  25.         extrn   DosWrite:far
  26.  
  27. DGROUP  group   _DATA
  28.  
  29. _DATA   segment word public 'DATA'
  30.  
  31. objbuff db      64 dup (0)      ; receives name of dynamic link
  32. objbuff_len equ $-objbuff       ; causing DosExecPgm failure    
  33.  
  34.                                 ; argument strings for child
  35. argblk  db      'chkdsk',0      ; simple filename of child
  36.         db      ' *.*',0        ; simulated command tail
  37.         db      0               ; extra null byte terminates block
  38.  
  39.                                 ; receives return codes from child...
  40. retcode dw      0               ; termination code for child
  41.         dw      0               ; result code from child's DosExit
  42.  
  43. pname   db      'chkdsk.com',0  ; pathname of child program
  44.  
  45. wlen    dw      ?
  46.  
  47. msg1    db      cr,lf,'Unexpected OS/2 Error',cr,lf
  48. msg1_len equ $-msg1
  49.  
  50. msg2    db      cr,lf,'Exec function successful',cr,lf
  51. msg2_len equ $-msg2
  52.  
  53. _DATA   ends
  54.  
  55.  
  56. _TEXT   segment word public 'CODE'
  57.  
  58.         assume  cs:_TEXT,ds:DGROUP
  59.  
  60. main    proc    far
  61.  
  62.                                         ; run CHKDSK as a syn-
  63.                                         ; chronous child process...
  64.         push    ds                      ; receives module/entry
  65.         push    offset DGROUP:objbuff   ; point if dynlink fails
  66.         push    objbuff_len             ; length of object buffer
  67.         push    0                       ; 0=execute synchronously
  68.         push    ds                      ; address of argument block
  69.         push    offset DGROUP:argblk
  70.         push    0                       ; address of environment
  71.         push    0                       ; (0 = inherit parent's) 
  72.         push    ds                      ; receives child's exit
  73.         push    offset DGROUP:retcode   ; and termination codes
  74.         push    ds                      ; name of child program
  75.         push    offset DGROUP:pname
  76.         call    DosExecPgm              ; transfer to OS/2
  77.         or      ax,ax                   ; did child process run?
  78.         jnz     error                   ; jump if function failed
  79.  
  80. exit:                                   ; display success message...
  81.         push    stdout                  ; standard output handle
  82.         push    ds                      ; message address
  83.         push    offset msg2
  84.         push    msg2_len                ; message length
  85.         push    ds                      ; receives bytes written
  86.         push    offset wlen
  87.         call    DosWrite                ; transfer to OS/2
  88.  
  89.         push    1                       ; terminate all threads
  90.         push    0                       ; return success code
  91.         call    DosExit                 ; exit program
  92.  
  93. error:                                  ; display error message...
  94.         push    stdout                  ; standard output handle
  95.         push    ds                      ; message address
  96.         push    offset msg1
  97.         push    msg1_len                ; message length
  98.         push    ds                      ; receives bytes written
  99.         push    offset wlen               
  100.         call    DosWrite                ; transfer to OS/2
  101.  
  102.         push    1                       ; terminate all threads
  103.         push    1                       ; return error code
  104.         call    DosExit                 ; exit program
  105.  
  106. main    endp
  107.  
  108. _TEXT   ends
  109.  
  110.         end     main
  111.  
  112.