home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch09 / volname.asm < prev    next >
Encoding:
Assembly Source File  |  1988-12-12  |  5.8 KB  |  148 lines
  1.         title   VOLNAME - displays volume label
  2.         page    55,132
  3.         .286
  4. ; 
  5. ; VOLNAME.ASM --- displays volume label for current drive,
  6. ;                 demonstrates use of DosQFSInfo.
  7. ; Copyright (C) October 1986 Ray Duncan 
  8. ;
  9. ; Build:        MASM VOLNAME;
  10. ;               LINK VOLNAME,,,OS2,VOLNAME;
  11. ;
  12. ; Usage:        VOLNAME
  13.  
  14. stdin   equ     0                       ; standard input handle
  15. stdout  equ     1                       ; standard output handle
  16. stderr  equ     2                       ; standard error handle
  17.  
  18. cr      equ     0dh                     ; ASCII carriage return
  19. lf      equ     0ah                     ; ASCII line feed
  20.  
  21.         extrn   DosExit:far             ; references to OS/2 API
  22.         extrn   DosQCurDisk:far
  23.         extrn   DosQFSInfo:far  
  24.         extrn   DosWrite:far
  25.  
  26. _vlinfo struc                           ; volume label structure
  27. date    dw      ?                       ; date of creation      
  28. time    dw      ?                       ; time of creation
  29. count   db      ?                       ; length of volume label
  30. vname   db      13 dup (?)              ; volume label text
  31. _vlinfo ends
  32.  
  33. DGROUP  group   _DATA
  34.  
  35. _DATA   segment word public 'DATA'
  36.  
  37. wlen    dw      ?                       ; receives bytes written
  38.  
  39. vlinf   _vlinfo <>                      ; volume label info
  40. vlinf_len equ $-vlinf
  41.  
  42. drive   dw      0                       ; receives drive ID
  43. drvmap  dd      0                       ; receives drive bitmap
  44.  
  45. msg1    db      cr,lf,'Volume in drive '
  46. msg1a   db      'X has no label.',cr,lf
  47. msg1_length equ $-msg1
  48.  
  49. msg2    db      cr,lf
  50. msg2_length equ $-msg2
  51.  
  52. msg3    db      cr,lf,'Volume in drive ' 
  53. msg3a   db      'X is '
  54. msg3_length equ $-msg3
  55.  
  56. _DATA   ends
  57.  
  58.  
  59. _TEXT   segment word public 'CODE'
  60.  
  61.         assume  cs:_TEXT,ds:DGROUP
  62.  
  63. volname proc    far                     ; entry point from OS/2
  64.                                 
  65.                                         ; get current drive...
  66.         push    ds                      ; receives drive code
  67.         push    offset DGROUP:drive
  68.         push    ds                      ; receives bitmap for
  69.         push    offset DGROUP:drvmap    ; available drives
  70.         call    DosQCurDisk             ; transfer to OS/2
  71.         or      ax,ax                   ; did function succeed?
  72.         jz      vol1                    ; yes, proceed
  73.         jmp     vol5                    ; exit if function failed
  74.  
  75. vol1:   mov     al,'A'-1                ; convert drive code to
  76.         add     ax,drive                ; ASCII letter and store
  77.         mov     msg3a,al                ; for output
  78.         mov     msg1a,al
  79.  
  80.                                         ; get volume label...
  81.         push    0                       ; drive = default
  82.         push    2                       ; file info level 2
  83.         push    ds                      ; buffer receives volume
  84.         push    offset DGROUP:vlinf     ; date, time, and name
  85.         push    vlinf_len               ; size of buffer
  86.         call    DosQFSInfo              ; transfer to OS/2
  87.         or      ax,ax                   ; call successful?
  88.         jnz     vol2                    ; jump, got volume label
  89.                                         
  90.         cmp     vlinf.count,0           ; null string?
  91.         jne     vol3                    ; no, go display label
  92.  
  93. vol2:                                   ; volume has no label...
  94.         push    stdout                  ; standard output handle
  95.         push    ds                      ; message address
  96.         push    offset DGROUP:msg1
  97.         push    msg1_length             ; message length
  98.         push    ds                      ; receives actual bytes written
  99.         push    offset DGROUP:wlen
  100.         call    DosWrite                ; transfer to OS/2
  101.         jmp     vol4                    ; now eixt
  102.  
  103. vol3:                                   ; display initial message...
  104.         push    stdout                  ; standard output handle
  105.         push    ds                      ; message address
  106.         push    offset DGROUP:msg3
  107.         push    msg3_length             ; message length
  108.         push    ds                      ; receives actual bytes written
  109.         push    offset DGROUP:wlen      
  110.         call    DosWrite                ; transfer to OS/2
  111.  
  112.                                         ; display actual volume label...
  113.         push    stdout                  ; standard output handle
  114.         push    ds                      ; label address
  115.         push    offset DGROUP:vlinf.vname
  116.         mov     al,vlinf.count          ; label length
  117.         xor     ah,ah
  118.         push    ax
  119.         push    ds                      ; receives bytes written
  120.         push    offset DGROUP:wlen
  121.         call    DosWrite                ; transfer to OS/2
  122.  
  123.                                         ; output CR-LF sequence...
  124.         push    stdout                  ; standard output handle
  125.         push    ds                      ; address of CR-LF
  126.         push    offset DGROUP:msg2
  127.         push    msg2_length             ; length of CR-LF
  128.         push    ds                      ; receives bytes written
  129.         push    offset DGROUP:wlen
  130.         call    DosWrite                ; transfer to OS/2
  131.  
  132. vol4:                                   ; success exit point...
  133.         push    1                       ; terminate all threads
  134.         push    0                       ; return code=0 (success)
  135.         call    DosExit                 ; transfer to OS/2
  136.  
  137. vol5:                                   ; error exit point...
  138.         push    1                       ; terminate all threads
  139.         push    1                       ; return code=1 (error)
  140.         call    DosExit                 ; transfer to OS/2
  141.  
  142. volname endp
  143.  
  144. _TEXT   ends
  145.  
  146.         end     volname
  147.  
  148.