home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advos2 / ch03 / argc.asm next >
Encoding:
Assembly Source File  |  1988-12-12  |  2.6 KB  |  91 lines
  1.     title    ARGC -- Return Argument Count
  2.         page    55,132
  3.         .286
  4.  
  5. ;
  6. ; ARGC.ASM
  7. ;
  8. ; Return count of command line arguments.  Treats blanks and
  9. ; tabs as whitespace.
  10. ;
  11. ; Assemble with:  C> masm argc.asm;
  12. ; 
  13. ; Call with:    N/A
  14. ;
  15. ; Returns:    AX    = argument count (always >= 1)
  16. ;
  17. ; Uses:         nothing (other registers preserved)
  18. ;
  19. ; Copyright (C) 1987 Ray Duncan
  20. ;
  21.  
  22. tab     equ     09h             ; ASCII tab
  23. blank   equ     20h             ; ASCII space character
  24.  
  25.         extrn   DosGetEnv:far
  26.  
  27. _TEXT   segment word public 'CODE'
  28.  
  29.         assume  cs:_TEXT
  30.  
  31.         public  argc            ; make ARGC available to Linker
  32.  
  33.                                 ; local variables
  34. envseg  equ     [bp-2]          ; environment segment
  35. cmdoffs equ     [bp-4]          ; command line offset   
  36.  
  37. argc    proc    near
  38.  
  39.         enter   4,0             ; make room for local variables
  40.  
  41.     push    es        ; save original ES, BX, and CX
  42.         push    bx
  43.         push    cx
  44.  
  45.         push    ss              ; get selector for environment 
  46.         lea     ax,envseg       ; and offset of command line 
  47.         push    ax
  48.         push    ss
  49.         lea     ax,cmdoffs
  50.         push    ax
  51.         call    DosGetEnv       ; transfer to OS/2      
  52.         or      ax,ax           ; check operation status
  53.         mov     ax,1            ; force argc >= 1
  54.         jnz     argc3           ; inexplicable failure
  55.  
  56.         mov     es,envseg       ; set ES:BX = command line
  57.         mov     bx,cmdoffs
  58.  
  59. argc0:  inc     bx              ; ignore useless first field
  60.         cmp     byte ptr es:[bx],0      
  61.         jne     argc0
  62.  
  63. argc1:  mov     cx,-1           ; set flag = outside argument
  64.  
  65. argc2:  inc     bx              ; point to next character 
  66.         cmp     byte ptr es:[bx],0
  67.         je      argc3           ; exit if null byte
  68.         cmp     byte ptr es:[bx],blank
  69.         je      argc1           ; outside argument if ASCII blank
  70.         cmp     byte ptr es:[bx],tab    
  71.         je      argc1           ; outside argument if ASCII tab
  72.  
  73.                                 ; otherwise not blank or tab,
  74.         jcxz    argc2           ; jump if already inside argument
  75.  
  76.         inc     ax              ; else found argument, count it
  77.         not     cx              ; set flag = inside argument
  78.         jmp     argc2           ; and look at next character
  79.  
  80. argc3:  pop     cx              ; restore original BX, CX, ES
  81.         pop     bx
  82.         pop     es
  83.         leave                   ; discard local variables
  84.         ret                     ; return AX = argument count
  85.  
  86. argc    endp
  87.  
  88. _TEXT   ends
  89.  
  90.         end     
  91.