home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advmsdos / chap14 / driver.asm next >
Encoding:
Assembly Source File  |  1988-10-01  |  7.9 KB  |  379 lines
  1.         title   DRIVER.ASM Device Driver Skeleton
  2.         page    55,132
  3.  
  4. ;
  5. ; DRIVER.ASM   MS-DOS device driver skeleton
  6. ;
  7. ; The driver command code routines are stubs only and have
  8. ; no effect but to return a non-error "Done" status.
  9. ; 
  10. ; Copyright (C) 1988 Ray Duncan
  11. ;
  12. ; Build:   MASM DRIVER;
  13. ;          LINK DRIVER;
  14. ;          EXE2BIN DRIVER.EXE DRIVER.SYS
  15. ;          DEL DRIVER.EXE
  16. ; 
  17. ; Usage:   DEVICE=DRIVER.SYS  (in file CONFIG.SYS)
  18. ;
  19.  
  20. _TEXT    segment word public 'CODE'
  21.  
  22.         assume  cs:_TEXT,ds:_TEXT,es:NOTHING
  23.  
  24.         org     0
  25.  
  26. MaxCmd    equ    24        ; maximum allowed command code
  27.                 ; 12 for MS-DOS 2.x
  28.                                 ; 16 for MS-DOS 3.0-3.1
  29.                                 ; 24 for MS-DOS 3.2-3.3
  30.  
  31. cr      equ     0dh             ; ASCII carriage return
  32. lf      equ     0ah             ; ASCII line feed
  33. eom     equ     '$'             ; end of message signal
  34.  
  35.  
  36. Header:                ; device driver header
  37.     dd      -1              ; link to next device driver
  38.         dw      0c840h        ; device attribute word
  39.         dw      Strat           ; "Strategy" routine entry point
  40.         dw      Intr            ; "Interrupt" routine entry point
  41.         db      'SKELETON'    ; logical device name
  42.  
  43.  
  44. RHPtr    dd     ?        ; pointer to request header, passed
  45.                 ; by MS-DOS kernel to Strategy routine
  46.  
  47.  
  48. Dispatch:            ; Interrupt routine command code
  49.                 ; dispatch table.
  50.         dw      Init        ; 0  = initialize driver
  51.         dw      MediaChk    ; 1  = media check
  52.         dw      BuildBPB    ; 2  = build BIOS parameter block
  53.         dw      IoctlRd        ; 3  = I/O control read 
  54.         dw      Read        ; 4  = read
  55.         dw      NdRead        ; 5  = non-destructive read 
  56.         dw      InpStat        ; 6  = input status
  57.         dw      InpFlush    ; 7  = flush input buffers
  58.         dw      Write        ; 8  = write
  59.         dw      WriteVfy    ; 9  = write with verify
  60.         dw      OutStat        ; 10 = output status
  61.         dw      OutFlush    ; 11 = flush output buffers
  62.         dw      IoctlWt        ; 12 = I/O control write 
  63.         dw      DevOpen        ; 13 = device open       (MS-DOS 3.0+)
  64.         dw      DevClose    ; 14 = device close      (MS-DOS 3.0+)
  65.         dw      RemMedia    ; 15 = removeable media  (MS-DOS 3.0+)
  66.     dw    OutBusy        ; 16 = output until busy (MS-DOS 3.0+)    
  67.     dw    Error        ; 17 = not used
  68.     dw    Error        ; 18 = not used
  69.     dw    GenIOCTL    ; 19 = generic IOCTL     (MS-DOS 3.2+) 
  70.     dw    Error        ; 20 = not used
  71.     dw     Error        ; 21 = not used
  72.     dw    Error        ; 22 = not used
  73.     dw    GetLogDev    ; 23 = get logical device (MS-DOS 3.2+)
  74.     dw    SetLogDev    ; 24 = set logical device (MS-DOS 3.2+)
  75.  
  76.     
  77. Strat   proc    far         ; device driver Strategy routine,
  78.                 ; called by MS-DOS kernel with
  79.                 ; ES:BX = address of request header
  80.  
  81.                                 ; save pointer to request header
  82.         mov     word ptr cs:[RHPtr],bx
  83.         mov     word ptr cs:[RHPtr+2],es
  84.  
  85.         ret                     ; back to MS-DOS kernel
  86.  
  87. Strat   endp
  88.  
  89.  
  90. Intr    proc  far        ; device driver Interrupt routine,
  91.                 ; called by MS-DOS kernel immediately 
  92.                 ; after call to Strategy routine
  93.  
  94.         push    ax              ; save general registers 
  95.         push    bx
  96.         push    cx
  97.         push    dx
  98.         push    ds
  99.         push    es
  100.         push    di
  101.         push    si
  102.         push    bp
  103.  
  104.         push    cs              ; make local data addressable
  105.         pop     ds        ; by setting DS = CS
  106.  
  107.         les     di,[RHPtr]    ; let ES:DI = request header
  108.  
  109.                                 ; get BX = command code
  110.         mov     bl,es:[di+2]
  111.         xor     bh,bh
  112.         cmp     bx,MaxCmd    ; make sure it's legal
  113.     jle    Intr1        ; jump, function code is ok
  114.     call    Error        ; set error bit, "Unknown Command" code
  115.     jmp    Intr2
  116.  
  117. Intr1:    shl     bx,1            ; form index to dispatch table
  118.                                 ; and branch to command code routine
  119.         call    word ptr [bx+Dispatch]
  120.  
  121.     les    di,[RHPtr]    ; ES:DI = addr. of request header
  122.  
  123. Intr2:    or    ax,0100h    ; merge 'Done' bit into status, and
  124.         mov     es:[di+3],ax    ; store status into request header 
  125.  
  126.         pop     bp              ; restore general registers
  127.         pop     si
  128.         pop     di
  129.         pop     es
  130.         pop     ds
  131.         pop     dx
  132.         pop     cx
  133.         pop     bx
  134.         pop     ax
  135.         ret                     ; back to MS-DOS kernel
  136.  
  137.  
  138. ; Command code routines are called by the Interrupt routine
  139. ; via the Dispatch table with ES:DI pointing to the request
  140. ; header.  Each routine should return AX=0 if function was
  141. ; completed successfully, or AX = 8000h + error code if
  142. ; function failed.
  143.  
  144.  
  145. MediaChk proc    near        ; function 1 = Media Check
  146.     
  147.     xor    ax,ax
  148.     ret
  149.  
  150. MediaChk endp
  151.  
  152.  
  153. BuildBPB proc     near        ; function 2 = Build BPB
  154.  
  155.     xor    ax,ax
  156.     ret
  157.  
  158. BuildBPB endp
  159.  
  160.  
  161. IoctlRd    proc    near        ; function 3 = I/O Control Read
  162.  
  163.     xor    ax,ax
  164.     ret
  165.  
  166. IoctlRd    endp
  167.  
  168.  
  169. Read    proc    near         ; function 4 = Read (Input)
  170.  
  171.     xor    ax,ax
  172.     ret
  173.  
  174. Read    endp
  175.  
  176.  
  177. NdRead    proc    near        ; function 5 = Non-Destructive Read
  178.  
  179.     xor    ax,ax
  180.     ret
  181.  
  182. NdRead    endp
  183.  
  184.  
  185. InpStat    proc    near        ; function 6 = Input Status
  186.  
  187.     xor    ax,ax
  188.     ret
  189.  
  190. InpStat    endp
  191.  
  192.  
  193. InpFlush proc    near        ; function 7 = Flush Input Buffers
  194.  
  195.     xor    ax,ax
  196.     ret
  197.  
  198. InpFlush endp
  199.  
  200.  
  201. Write    proc    near        ; function 8 = Write (Output)
  202.  
  203.     xor    ax,ax
  204.     ret
  205.  
  206. Write    endp
  207.  
  208.  
  209. WriteVfy proc    near        ; function 9 = Write with Verify
  210.  
  211.     xor    ax,ax
  212.     ret
  213.  
  214. WriteVfy endp
  215.  
  216.  
  217. OutStat    proc    near        ; function 10 = Output Status
  218.  
  219.     xor    ax,ax
  220.     ret
  221.  
  222. OutStat    endp
  223.  
  224.  
  225. OutFlush proc    near        ; function 11 = Flush Output Buffers
  226.  
  227.     xor    ax,ax
  228.     ret
  229.  
  230. OutFlush endp
  231.  
  232.  
  233. IoctlWt proc    near        ; function 12 = I/O Control Write
  234.  
  235.     xor    ax,ax
  236.     ret
  237.  
  238. IoctlWt endp
  239.  
  240.  
  241. DevOpen proc    near        ; function 13 = Device Open
  242.  
  243.     xor    ax,ax
  244.     ret
  245.  
  246. DevOpen endp
  247.     
  248.  
  249. DevClose proc    near        ; function 14 = Device Close
  250.  
  251.     xor    ax,ax
  252.     ret
  253.  
  254. DevClose endp
  255.  
  256.  
  257. RemMedia proc    near        ; function 15 = Removable Media
  258.  
  259.     xor    ax,ax
  260.     ret
  261.  
  262. RemMedia endp
  263.  
  264.  
  265. OutBusy proc    near        ; function 16 = Output Until Busy
  266.  
  267.     xor    ax,ax
  268.     ret
  269.  
  270. OutBusy endp         
  271.  
  272.  
  273. GenIOCTL proc    near        ; function 19 = Generic IOCTL
  274.  
  275.     xor    ax,ax
  276.     ret
  277.  
  278. GenIOCTL endp
  279.  
  280.  
  281. GetLogDev proc    near        ; function 23 = Get Logical Device
  282.  
  283.     xor    ax,ax
  284.     ret
  285.  
  286. GetLogDev endp
  287.  
  288.  
  289. SetLogDev proc    near        ; function 24 = Set Logical Device
  290.  
  291.     xor    ax,ax
  292.     ret
  293.  
  294. SetLogDev endp
  295.  
  296.  
  297. Error    proc    near        ; bad command code in request header
  298.  
  299.     mov    ax,8003h    ; error bit + "Unknown Command" code
  300.     ret
  301.  
  302. Error    endp
  303.  
  304.  
  305. Init    proc    near        ; function 0 = initialize driver
  306.  
  307.         push    es              ; save address of request header 
  308.         push    di
  309.  
  310.     mov    ax,cs        ; convert load address to ASCII
  311.     mov    bx,offset Ident1
  312.     call    hexasc
  313.  
  314.     mov    ah,9        ; display driver sign-on message
  315.         mov     dx,offset Ident
  316.         int     21h
  317.  
  318.         pop     di              ; restore request header address
  319.         pop     es
  320.  
  321.                                 ; set addr. of free memory 
  322.                 ; above driver (break address)
  323.         mov     word ptr es:[di+14],offset Init
  324.         mov     word ptr es:[di+16],cs
  325.  
  326.     xor    ax,ax        ; return status 
  327.     ret
  328.  
  329. Init    endp
  330.  
  331.  
  332. hexasc    proc    near        ; converts word to hex ASCII
  333.                 ; call with AX = value,
  334.                 ; DS:BX = address for string
  335.                 ; returns AX, BX destroyed
  336.  
  337.     push    cx        ; save registers 
  338.     push    dx
  339.  
  340.     mov    dx,4        ; initialize character counter
  341.  
  342. hexasc1:
  343.     mov    cx,4        ; isolate next four bits
  344.     rol    ax,cl
  345.     mov    cx,ax
  346.     and    cx,0fh
  347.     add    cx,'0'        ; convert to ASCII 
  348.     cmp    cx,'9'        ; is it 0-9?
  349.     jbe    hexasc2        ; yes, jump
  350.     add    cx,'A'-'9'-1    ; add fudge factor for A-F
  351.  
  352. hexasc2:            ; store this character
  353.     mov    [bx],cl
  354.     inc    bx        ; bump string pointer
  355.  
  356.     dec    dx        ; count characters converted
  357.     jnz    hexasc1     ; loop, not four yet
  358.  
  359.     pop    dx        ; restore registers
  360.     pop    cx
  361.     ret            ; back to caller
  362.  
  363. hexasc    endp
  364.  
  365.  
  366. Ident   db      cr,lf,lf
  367.         db      'Advanced MS-DOS Example Device Driver'
  368.     db    cr,lf
  369.     db    'Device driver header at: '
  370. Ident1    db    'XXXX:0000'
  371.         db      cr,lf,lf,eom
  372.  
  373. Intr    endp
  374.  
  375. _TEXT    ends
  376.  
  377.     end
  378.  
  379.