home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advmsdos / chap13 / zerodiv.asm < prev   
Encoding:
Assembly Source File  |  1988-10-01  |  3.8 KB  |  179 lines
  1.          title     ZERODIV --- Divide by zero handler
  2.          page      55,132
  3.  
  4. ; 
  5. ; ZERODIV.ASM --- Terminate-and-stay-resident handler
  6. ;                 for divide-by-zero interrupts
  7. ; 
  8. ; Copyright 1988 Ray Duncan
  9. ; 
  10. ; Build:    C>MASM ZERODIV; 
  11. ;         C>LINK ZERODIV; 
  12. ;         C>EXE2BIN ZERODIV.EXE ZERODIV.COM
  13. ;            C>DEL ZERODIV.EXE
  14. ;
  15. ; Usage:    C>ZERODIV
  16. ;
  17.  
  18. cr    equ     0dh           ; ASCII carriage return
  19. lf      equ     0ah           ; ASCII line feed
  20. beep    equ    07h        ; ASCII bell code
  21. backsp    equ    08h        ; ASCII backspace code
  22.  
  23. _TEXT     segment    word public 'CODE'
  24.  
  25.     org    100H      
  26.  
  27.     assume     cs:_TEXT,ds:_TEXT,es:_TEXT,ss:_TEXT
  28.  
  29.  
  30. init    proc     near          ; entry point at load time    
  31.  
  32.                 ; capture vector for
  33.                 ; interrupt zero ...
  34.     mov    dx,offset zdiv    ; DS:DX = handler address
  35.     mov    ax,2500h    ; Fxn 25H = set vector
  36.                 ; interrupt type = 0
  37.     int    21h        ; transfer to MS-DOS
  38.  
  39.                 ; print sign-on message
  40.     mov    dx,offset msg1    ; DS:DX = message address
  41.     mov    ah,9        ; Fxn 09H = display string
  42.     int    21h        ; transfer to MS-DOS
  43.  
  44.                 ; DX = paragraphs to reserve
  45.     mov    dx,((offset pgm_len+15)/16)+10h
  46.     mov    ax,3100h    ; Fxn 31H = terminate and
  47.                 ; stay resident
  48.     int    21h        ; transfer to MS-DOS
  49.  
  50. init    endp
  51.  
  52.  
  53. zdiv    proc    far        ; this is the divide by 
  54.                 ; zero interrupt handler
  55.  
  56.     sti            ; enable interrupts
  57.  
  58.     push    ax        ; save registers
  59.     push    bx
  60.     push    cx
  61.     push    dx
  62.     push    si
  63.     push    di
  64.     push    bp
  65.     push    ds
  66.     push    es
  67.  
  68.     mov    ax,cs          ; make data addressable
  69.     mov    ds,ax
  70.  
  71.                 ; display message
  72.                 ; "Continue or Quit?"
  73.     mov    dx,offset msg2    ; DS:DX = message address    
  74.     mov    ah,9        ; Fxn 09H = display string
  75.     int    21h        ; transfer to MS-DOS
  76.  
  77. zdiv1:    mov    ah,1        ; Fxn 01H = read keyboard
  78.     int    21h        ; transfer to MS-DOS
  79.  
  80.     or    al,20h        ; fold char. to lower case
  81.  
  82.     cmp    al,'c'        ; is it C or Q?
  83.     je    zdiv3        ; jump, it's a C
  84.  
  85.     cmp    al,'q'
  86.     je    zdiv2        ; jump, it's a Q
  87.  
  88.                 ; illegal entry, send beep
  89.                 ; and erase the character
  90.     mov    dx,offset msg3    ; DS:DX = message address
  91.     mov    ah,9        ; Fxn 09H = display string
  92.     int    21h        ; transfer to MS-DOS
  93.  
  94.     jmp    zdiv1        ; try again
  95.  
  96. zdiv2:                ; user picked "Quit"
  97.     mov    ax,4cffh    ; terminate current program
  98.     int    21h        ; with return code = 255
  99.  
  100. zdiv3:                ; user picked "Continue"
  101.                 ; send CR-LF pair
  102.     mov    dx,offset msg4  ; DS:DX = message address
  103.     mov    ah,9        ; Fxn 09H = print string
  104.     int    21h        ; transfer to MS-DOS
  105.  
  106.                 ; what CPU type is this?
  107.     xor    ax,ax        ; to find out, we'll put
  108.     push    ax        ; zero in the CPU flags
  109.     popf            ; and see what happens
  110.     pushf
  111.     pop    ax
  112.     and    ax,0f000h    ; 8086/88 forces 
  113.     cmp    ax,0f000h    ; bits 12-15 true
  114.           je    zdiv5        ; jump if 8086/88
  115.  
  116.                 ; otherwise we must adjust
  117.                 ; return address to bypass
  118.                 ; the divide instruction...
  119.     mov    bp,sp        ; make stack addressable
  120.  
  121.     lds    bx,[bp+18]    ; get address of the
  122.                 ; faulting instruction
  123.  
  124.     mov    bl,[bx+1]    ; get addressing byte
  125.     and    bx,0c7h        ; isolate mod & r/m fields
  126.  
  127.     cmp    bl,6        ; mod 0, r/m 6 = direct
  128.     jne    zdiv4        ; not direct, jump
  129.  
  130.     add    word ptr [bp+18],4
  131.     jmp    zdiv5
  132.  
  133. zdiv4:    mov    cl,6        ; otherwise isolate mod
  134.     shr    bx,cl        ; field and get instruction
  135.     mov    bl,cs:[bx+itab]    ; size from table
  136.     add    [bp+18],bx
  137.  
  138. zdiv5:    pop    es        ; restore registers
  139.     pop    ds
  140.     pop    bp
  141.     pop    di
  142.     pop    si
  143.     pop    dx
  144.     pop    cx
  145.     pop    bx
  146.     pop    ax
  147.     iret            ; return from interrupt
  148.  
  149. zdiv    endp
  150.  
  151.  
  152. msg1    db       cr,lf        ; load-time signon message
  153.     db    'Divide by Zero Interrupt '
  154.     db    'Handler installed.'
  155.     db    cr,lf,'$'
  156.  
  157. msg2    db    cr,lf,lf    ; interrupt-time message
  158.     db    'Divide by Zero detected: '
  159.     db    cr,lf,'Continue or Quit (C/Q) ? '
  160.     db    '$'
  161.  
  162. msg3    db    beep        ; used if bad entry
  163.     db    backsp,' ',backsp,'$'
  164.  
  165. msg4    db    cr,lf,'$'    ; carriage return-line feed
  166.  
  167.                 ; instruction size table
  168. itab    db    2        ; mod = 0
  169.     db    3        ; mod = 1
  170.     db    4        ; mod = 2
  171.     db    2        ; mod = 3
  172.  
  173. pgm_len    equ    $-init        ; program length
  174.  
  175. _TEXT     ends
  176.  
  177.     end    init
  178.  
  179.