home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advmsdos / chap11 / extmem.asm next >
Encoding:
Assembly Source File  |  1988-10-01  |  4.0 KB  |  180 lines
  1.          title     EXTMEM --- get/put extended memory
  2.          page      55,132
  3.  
  4. ;
  5. ; EXTMEM.ASM --- Demonstration of access to
  6. ;                extended memory using ROM BIOS
  7. ;                Int 15H Function 87H
  8. ;
  9. ; Copyright (C) June 1988 Ray Duncan
  10. ;
  11. ; Build:   MASM EXTMEM;
  12. ;       LINK EXTMEM;
  13. ;
  14. ; Usage:   EXTMEM
  15. ; 
  16.  
  17. stdin    equ    0        ; standard input device
  18. stdout    equ    1        ; standard output device    
  19. stderr    equ    2        ; standard error device
  20.  
  21. cr    equ    0dh        ; ASCII carriage return
  22. lf    equ    0ah        ; ASCII line feed
  23.  
  24.  
  25. DGROUP    group    _DATA,STACK    ; 'automatic data group'
  26.  
  27.  
  28. _DATA    segment    word public 'DATA'
  29.  
  30. bmdt    db    30h dup (0)    ; block move descriptor table    
  31.  
  32. buff1    db    80h dup ('?')    ; source buffer
  33. buff2    db    80h dup (0)    ; destination buffer
  34.  
  35. _DATA    ends
  36.  
  37.  
  38. STACK    segment    para stack 'STACK'
  39.  
  40.     dw    64 dup (?)
  41.  
  42. STACK    ends
  43.  
  44.  
  45. _TEXT    segment    word public 'CODE'
  46.  
  47.     assume    cs:_TEXT,ds:DGROUP,ss:STACK
  48.  
  49. main    proc    far           ; entry point from MS-DOS
  50.  
  51.     mov    ax,DGROUP    ; set DS = our data segment
  52.     mov    ds,ax
  53.     mov    es,ax
  54.  
  55.                 ; copy 'buff1' to extended
  56.                 ; memory address 100000H
  57.     mov    dx,10h        ; DX:AX = destination
  58.     mov    ax,0        ; extended mem. address
  59.     mov    bx,seg buff1    ; DS:BX = source conv.
  60.     mov    ds,bx        ; memory address
  61.     mov    bx,offset buff1
  62.     mov    cx,80h        ; CX = bytes to move
  63.     mov    si,seg bmdt    ; ES:SI = block move 
  64.     mov    es,si        ; descriptor table
  65.     mov    si,offset bmdt
  66.     call    putblk        ; request transfer
  67.  
  68.  
  69.                 ; fill buff2 from extended
  70.                 ; memory address 100000H
  71.     mov    dx,10h        ; DX:AX = source extended 
  72.     mov    ax,0        ; memory address
  73.     mov    bx,seg buff2    ; DS:BX = destination 
  74.     mov    ds,bx        ; conventional mem. address
  75.     mov    bx,offset buff2
  76.     mov    cx,80h        ; CX = bytes to move
  77.     mov    si,seg bmdt    ; ES:SI = block move
  78.     mov    es,si        ; descriptor table
  79.     mov    si,offset bmdt
  80.     call    getblk        ; request transfer
  81.  
  82.     mov    ax,4c00h    ; no error, terminate program 
  83.     int    21h        ; with return code = 0
  84.  
  85. main2:    mov    ax,4c01h    ; error, terminate program
  86.     int    21h        ; with return code = 1 
  87.  
  88. main    endp            ; end of main procedure
  89.  
  90.  
  91.  
  92.  
  93. getblk    proc    near        ; Transfer block from extended
  94.                 ;   memory to real memory
  95.                 ; Call with 
  96.                 ; DX:AX = linear 32-bit 
  97.                 ;         extended memory address
  98.                 ; DS:BX = segment and offset
  99.                 ;         destination address
  100.                 ; CX    = length in bytes
  101.                 ; ES:SI = block move descriptor table
  102.                 ; Returns
  103.                 ; AH    = 0 if transfer OK
  104.  
  105.     mov    es:[si+10h],cx    ; store length into descriptors
  106.     mov    es:[si+18h],cx 
  107.  
  108.                 ; store access rights bytes
  109.     mov    byte ptr es:[si+15h],93h
  110.     mov    byte ptr es:[si+1dh],93h
  111.  
  112.     mov    es:[si+12h],ax    ; source extended memory address
  113.     mov    es:[si+14h],dl
  114.  
  115.                 ; convert destination segment
  116.                 ; and offset to linear address
  117.     mov    ax,ds        ; segment * 16
  118.     mov    dx,16
  119.     mul    dx
  120.     add    ax,bx        ; + offset -> linear address
  121.     adc    dx,0
  122.  
  123.     mov    es:[si+1ah],ax    ; store destination address
  124.     mov    es:[si+1ch],dl
  125.  
  126.     shr    cx,1        ; convert length to words
  127.     mov    ah,87h        ; Int 15H Fxn 87h = block move
  128.     int    15h        ; transfer to ROM BIOS 
  129.  
  130.     ret            ; back to caller
  131.  
  132. getblk    endp
  133.  
  134.  
  135. putblk    proc    near        ; Transfer block from real 
  136.                 ;   memory to extended memory
  137.                 ; Call with 
  138.                 ; DX:AX = linear 32-bit
  139.                 ;         extended memory address
  140.                 ; DS:BX = segment and offset
  141.                 ;         source address
  142.                 ; CX    = length in bytes
  143.                 ; ES:SI = block move descriptor table
  144.                 ; Returns
  145.                 ; AH    = 0 if transfer OK
  146.  
  147.     mov    es:[si+10h],cx    ; store length into descriptors
  148.     mov    es:[si+18h],cx 
  149.  
  150.                 ; store access rights bytes
  151.     mov    byte ptr es:[si+15h],93h
  152.     mov    byte ptr es:[si+1dh],93h
  153.  
  154.     mov    es:[si+1ah],ax    ; store destination extended 
  155.     mov    es:[si+1ch],dl    ; memory address
  156.  
  157.                 ; convert source segment and
  158.                 ; offset to linear address
  159.     mov    ax,ds        ; segment * 16
  160.     mov    dx,16
  161.     mul    dx
  162.     add    ax,bx        ; + offset -> linear address
  163.     adc    dx,0
  164.  
  165.     mov    es:[si+12h],ax    ; store source address
  166.     mov    es:[si+14h],dl
  167.  
  168.     shr    cx,1        ; convert length to words
  169.     mov    ah,87h        ; Int 15H Fxn 87h = block move
  170.     int    15h        ; transfer to ROM BIOS 
  171.  
  172.     ret            ; back to caller
  173.  
  174. putblk    endp
  175.  
  176. _TEXT    ends
  177.  
  178.     end    main        ; defines program entry point
  179.  
  180.