home *** CD-ROM | disk | FTP | other *** search
/ Microsoft Programmer's Library 1.3 / Microsoft-Programers-Library-v1.3.iso / sampcode / advmsdos / chap05 / break.asm next >
Encoding:
Assembly Source File  |  1988-10-01  |  4.7 KB  |  164 lines
  1.         title   Ctrl-C & Ctrl-Break Handlers
  2.         page    55,132
  3.  
  4. ;
  5. ; Ctrl-C and Ctrl-Break handler for Microsoft C 
  6. ; programs running on IBM PC compatibles
  7. ; 
  8. ; by Ray Duncan
  9. ;
  10. ; Assemble with:  C>MASM /Mx BREAK;
  11. ;
  12. ; This module allows C programs to retain control
  13. ; when the user enters a Ctrl-Break or Ctrl-C.  
  14. ; It uses Microsoft C parameter passing conventions
  15. ; and assumes the C small memory model.
  16. ;
  17. ; The procedure _capture is called to install
  18. ; a new handler for the Ctrl-C and Ctrl-Break
  19. ; interrupts (1BH and 23H).  _capture is passed
  20. ; the address of a static variable, which will be
  21. ; set to True by the handler whenever a Ctrl-C 
  22. ; or Ctrl-Break is detected.  The C syntax is:
  23. ; 
  24. ;               static int flag;
  25. ;               capture(&flag);
  26. ;
  27. ; The procedure _release is called by the C program
  28. ; to restore the original Ctrl-Break and Ctrl-C
  29. ; handler.  The C syntax is:
  30. ;
  31. ;               release();
  32. ;
  33. ; The procedure ctrlbrk is the actual interrupt 
  34. ; handler.  It receives control when a software 
  35. ; Int 1BH is executed by the ROM BIOS or Int 23H 
  36. ; is executed by MS-DOS.  It simply sets the C 
  37. ; program's variable to True (1) and returns.
  38. ;
  39.  
  40. args    equ     4               ; stack offset of arguments, 
  41.                                 ; C small memory model
  42.  
  43. cr      equ     0dh             ; ASCII carriage return
  44. lf      equ     0ah             ; ASCII line feed
  45.  
  46.  
  47. _TEXT   segment word public 'CODE'
  48.  
  49.         assume cs:_TEXT
  50.  
  51.  
  52.         public  _capture
  53. _capture proc   near            ; take over Control-Break 
  54.                                 ; and Ctrl-C interrupt vectors
  55.  
  56.         push    bp              ; set up stack frame
  57.         mov     bp,sp
  58.  
  59.         push    ds              ; save affected registers
  60.         push    di
  61.         push    si
  62.  
  63.                                 ; save address of 
  64.                                 ; calling program's "flag"
  65.         mov     ax,word ptr [bp+args]
  66.         mov     word ptr cs:flag,ax
  67.         mov     word ptr cs:flag+2,ds
  68.  
  69.                                 ; save address of original
  70.         mov     ax,3523h        ; Int 23H handler
  71.         int     21h
  72.         mov     word ptr cs:int23,bx
  73.         mov     word ptr cs:int23+2,es
  74.  
  75.         mov     ax,351bh        ; save address of original
  76.         int     21h             ; Int 1BH handler
  77.         mov     word ptr cs:int1b,bx
  78.         mov     word ptr cs:int1b+2,es
  79.  
  80.         push    cs              ; set DS:DX = address
  81.         pop     ds              ; of new handler
  82.         mov     dx,offset _TEXT:ctrlbrk
  83.  
  84.         mov     ax,02523H       ; set Int 23H vector
  85.         int     21h
  86.  
  87.         mov     ax,0251bH       ; set Int 1BH vector
  88.         int     21h
  89.  
  90.         pop     si              ; restore registers     
  91.         pop     di
  92.         pop     ds
  93.  
  94.         pop     bp              ; discard stack frame
  95.         ret                     ; and return to caller
  96.  
  97. _capture endp
  98.  
  99.  
  100.         public  _release
  101. _release proc   near            ; restore original Ctrl-C
  102.                                 ; and Ctrl-Break handlers
  103.  
  104.         push    bp              ; save registers
  105.         push    ds
  106.         push    di
  107.         push    si
  108.  
  109.         lds     dx,cs:int1b     ; get address of previous
  110.                                 ; Int 1BH handler
  111.  
  112.         mov     ax,251bh        ; set Int 1BH vector
  113.         int     21h
  114.  
  115.         lds     dx,cs:int23     ; get address of previous
  116.                                 ; Int 23H handler
  117.  
  118.         mov     ax,2523h        ; set Int 23H vector
  119.         int     21h
  120.  
  121.         pop     si              ; restore registers     
  122.         pop     di              ; and return to caller
  123.         pop     ds
  124.         pop     bp
  125.         ret
  126.  
  127. _release endp
  128.  
  129.  
  130. ctrlbrk proc    far             ; Ctrl-C and Ctrl-Break
  131.                                 ; interrupt handler
  132.  
  133.         push    bx              ; save registers
  134.         push    ds
  135.  
  136.                                 
  137.         lds     bx,cs:flag      ; get address of C program's
  138.                                 ; "flag variable"
  139.  
  140.                                 ; and set the flag "true"
  141.         mov     word ptr ds:[bx],1
  142.         
  143.         pop     ds              ; restore registers
  144.         pop     bx
  145.  
  146.         iret                    ; return from handler
  147.  
  148. ctrlbrk endp
  149.  
  150.  
  151. flag    dd      0               ; far pointer to caller's
  152.                                 ; Ctrl-Break or Ctrl-C flag
  153.  
  154. int23   dd      0               ; address of original 
  155.                                 ; Ctrl-C handler
  156.         
  157. int1b   dd      0               ; address of original
  158.                                 ; Ctrl-Break handler
  159.  
  160. _TEXT   ends
  161.  
  162.         end
  163.  
  164.