home *** CD-ROM | disk | FTP | other *** search
/ Magazyn Amiga Shareware Floppies / ma87a.dms / ma87a.adf / pov3c_1.lha / pov3demo / showoff / blobloop.pov next >
Encoding:
Text File  |  1996-11-08  |  3.7 KB  |  134 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File: BlobLoop.POV
  3. // Vers: 3
  4. // Desc: Shows off the while loop for creating complex blob objects.
  5. // Date: 10/1/95
  6. // Auth: Eduard Schwan
  7.  
  8. #version 3.0
  9. global_settings { assumed_gamma 1.0 }
  10.  
  11. // ------------------------------------------------------------------
  12. // Look down at an angle at our creation
  13. camera
  14. { 
  15.   location  <0, 10, -8>
  16.   direction 1*z
  17.   look_at   <0, 0, 0>
  18. } 
  19.  
  20.  
  21. // ------------------------------------------------------------------
  22. // Light source # 1
  23. light_source { <30, 20, -30> color rgb 1 }
  24.  
  25. // Light source # 2
  26. light_source { <-10, 30, -30> color rgb 0.5 }
  27.  
  28.  
  29. // ------------------------------------------------------------------
  30. // Simple dark background for a simple scene
  31. background { color rgb <0.0, 0.1, 0.2> }
  32.  
  33.  
  34. // ------------------------------------------------------------------
  35. // A white marble floor
  36. plane
  37. {
  38.   y, -0.1
  39.   texture
  40.   {
  41.     pigment
  42.     {
  43.       marble
  44.       turbulence 0.5 omega 0.7 rotate -40*y scale 6
  45.       color_map
  46.       {
  47.         [0.50 color rgb 1.0]
  48.         [0.57 color rgb 0.8]
  49.         [0.60 color rgb <0.9,0.8,0.7>]
  50.         [0.63 color rgb 1.0]
  51.       }
  52.     }
  53.     finish {ambient 0.2 reflection 0.3}
  54.   }
  55. }
  56.  
  57.  
  58. // ------------------------------------------------------------------
  59. // Set up the loop variables:
  60. // the Counter variable will go from 0.0 to 1.0 in NumIterations loops.
  61. #declare NumIterations = 60     // You can change this, try 20, 40, 60 too
  62.  
  63. // leave these next calculations alone
  64. #declare Increment     = 1.0/NumIterations
  65. #declare NumTwists     = 360*2  // # of full twists
  66. #declare Height        = 5      // total height of object
  67.  
  68.  
  69. // ------------------------------------------------------------------
  70. // Here is the large loop-generated blob
  71. blob
  72. {
  73.   threshold 0.1
  74.  
  75.   // create a series of components, using a while-loop
  76.   #declare Counter = 0.001
  77.   #while (Counter<=1.0)
  78. // #debug concat("Cnt=",str(Counter,2,4)," Inc=",str(Increment,5,8),"\n")
  79.  
  80.     // put a rod across axis
  81.     cylinder
  82.     {
  83.       <-5*(1-Counter), Counter*Height, 0>,  // <xyz> of one end
  84.       < 5*(1-Counter), Counter*Height, 0>,  // <xyz> of other end
  85.       Increment*20,                         // radius
  86.       2                                     // blob component strength
  87.       // put down the texture AFTER the component is in place
  88.       // so it lines up across them
  89.       texture
  90.       {
  91.         // make the color change as we wind our way up the shape
  92.         pigment { color rgb Counter/2 }
  93.         finish { ambient 0.2 specular 0.6 reflection 0.3 roughness 0.01 }
  94.       }
  95.       rotate Counter*NumTwists*y
  96.     }
  97.  
  98.     // now add a ball on each end of the rod
  99.     sphere
  100.     {
  101.       <-5*(1-Counter), Counter*Height, 0>, Increment*30, 2
  102.       rotate Counter*NumTwists*y
  103.       // put down the texture AFTER the component is in place
  104.       // so it lines up across them
  105.       texture
  106.       {
  107.         // make the color change as we wind our way up the shape
  108.         pigment { color rgb <Counter, 0, 1> }
  109.         finish { ambient 0.2 specular 0.6 reflection 0.3 roughness 0.01 }
  110.       }
  111.     }
  112.  
  113.     sphere
  114.     {
  115.       < 5*(1-Counter), Counter*Height, 0>, Increment*30, 2
  116.       rotate Counter*NumTwists*y
  117.       // put down the texture AFTER the component is in place
  118.       // so it lines up across them
  119.       texture
  120.       {
  121.         // make the color change as we wind our way up the shape
  122.         pigment { color rgb <1, 0, Counter> }
  123.         finish { ambient 0.2 specular 0.6 reflection 0.3 roughness 0.01 }
  124.       }
  125.     }
  126.     // manually increment our counter inside the loop
  127.     #declare Counter=Counter+Increment
  128.   #end
  129.  
  130.   rotate -30*y // view from a better angle
  131. }
  132.  
  133.  
  134.