home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / pspce1-2 / example1.cir next >
Encoding:
Text File  |  1987-12-23  |  5.7 KB  |  133 lines
  1. EXAMPLE1 - An Illustration of all Commands
  2. * 
  3. * This circuit, a differential pair, uses all possible commands to create
  4. * the maximum amount of output possible from such a small circuit.  Normally,
  5. * only a few kinds of output, such as transient analysis, would be run.
  6. * 
  7. * This command sets options for the run.
  8. .OPT ACCT LIST NODE OPTS NOPAGE RELTOL=.001
  9.  
  10. * Sets the width of the output to 80 columns.
  11. .WIDTH OUT=80
  12.  
  13. * Sets the temperature for the run to 35 degrees celsius.
  14. .TEMP 35
  15.  
  16. * This command does a DC sweep.  The voltage source VIN is swept from
  17. *   -0.25 volts to 0.25 volts in steps of 0.005 volts.  The non-linear
  18. *   device equations are used.
  19. .DC VIN -0.25 0.25 0.005
  20.  
  21. * There is no command to do a small-signal bias point calculation.  It
  22. *   is done automatically after the DC sweep is finished.  The non-linear
  23. *   device equations are used to find the bias point.  Then, the linearized,
  24. *   small-signal equivalent circuit at the bias point is saved for the .TF,
  25. *   .SENS, .AC, and .NOISE analysis.
  26.  
  27. * This command does a small-signal transfer function calculation assuming
  28. *   VIN is the input and V(5), the voltage at node 5, is the output.
  29. .TF V(5) VIN
  30.  
  31. * This does a sensitivity analysis of V(5) at the bias point with respect
  32. *   to the component values and model parameter values in the circuit.
  33. .SENS V(5)
  34.  
  35. * This does an AC analysis.  The real and imaginary response of the circuit
  36. *   is calculated as the inputs are swept from 1 hertz to 10 gigahertz by
  37. *   decades with 10 points per decade.  The only AC input this circuit has
  38. *   is VIN.  This is a linear analysis.
  39. .AC DEC 10 1 10GHZ
  40.  
  41. * This command does noise calculations during the AC analysis.  Each
  42. *   device's noise contribution is calculated and propogated to node 5.
  43. *   All the contributions are rms-summed at node 5.  Besides the total
  44. *   output noise printout done for every frequency, a detailed table of
  45. *   each device's contribution is done every 20'th frequency.
  46. .NOISE V(5) VIN 20
  47.  
  48. * This command does a transient analysis.  It first re-calculates the
  49. *   circuit's bias point, then calculates the circuit's time response
  50. *   from 0 nanoseconds to 500 nanoseconds using the full, non-linear device
  51. *   equations, including non-linear capacitances.  PSpice uses a variable
  52. *   time step for the calculations, but this command causes the results
  53. *   to be interpolated onto a 5 nanosecond print interval.  Transient
  54. *   analysis is the most frequently used analysis in PSpice.
  55. .TRAN/OP 5NS 500NS
  56.  
  57. * This does a harmonic decomposition on the waveform V(5) calculated
  58. *   during transient analysis.  It calculates the magnitude and phase
  59. *   of the fundamental (5 megahertz) and the first eight harmonics.
  60. .FOUR 5MEG V(5)
  61.  
  62. * This command does a Monte Carlo analysis of the circuit.  It runs
  63. *   transient analysis 5 times using the tolerances in .MODEL statements
  64. *   and compares the waveform V(5) from each run against the nominal
  65. *   V(5).  It then lists a table of each run's deviation from the 
  66. *   nominal.
  67. .MC 5 TRAN V(5) YMAX
  68.  
  69. * The following statements describe the circuit to PSpice.  It is a
  70. *   simple differential pair, with +12 and -12 volts as the supplies.
  71.  
  72. * VIN is the input for this circuit.  It has an amplitude during AC analysis
  73. *   of 1 volt and a sine waveform during transient of .1 volt at 5 megahertz.
  74. VIN 100 0 AC 1 SIN(0 0.1 5MEG)
  75.  
  76. * The power supplies are +12 volts and -12 volts.
  77. VCC 101 0 DC 12
  78. VEE 102 0 -12 
  79.  
  80. * The transistors' nodes are in the order collector - base - emitter.
  81. *   All transistors must refer to a model (QNL in this case).
  82. Q1 4 2 6 QNL
  83. Q2 5 3 6 QNL
  84.  
  85. * Models for resistors are optional.  If used they can specify such things
  86. *   as scaling, temperature coefficients, and tolerances.
  87. RS1 100 2 1K 
  88. RS2 3 0 1K
  89. RC1 4 101 CRES 10K
  90. RC2 5 101 CRES 10K
  91. Q3 6 7 102 QNL
  92. Q4 7 7 102 QNL
  93. RBIAS 7 101 20K
  94. CLOAD 4 5 5PF
  95.  
  96. * This statement describes the CRES resistor by giving the values for
  97. *   the parameters.  Each type of model has its own set of parameters.
  98. *   All parameters have default values.  In CRES we have set the scaling
  99. *   factor to 1, the linear temperature coefficient to .02, and the
  100. *   quadratic temperature coefficient to .0045, and given each resistor
  101. *   a 5% tolerance on its value during Monte Carlo analysis.
  102. .MODEL CRES RES (R=1 DEV=5% TC1=.02 TC2=.0045)
  103.  
  104. * The bipolar transistor model is the Gummel-Poon model.  It uses the
  105. *   same equations as in the UC Berkeley Spice program.  There are
  106. *   actually 55 model parameters, but most of these are for second-order
  107. *   effects that are rarely used.  Most bipolar models for realistic
  108. *   circuits specify between 12 and 25 parameters and default the rest.
  109. *   Here, we have set the forward beta to 80, the base resistance to
  110. *   100 ohms, the collector-substrate capacitance to 2 picofarads, the
  111. *   forward transit time to 0.3 nanoseconds, the reverse transit time to
  112. *   6 nanoseconds, the base-emitter capacitance to 3 picofarads, the
  113. *   base-collector capacitance to 2 picofarads, and the forward Early
  114. *   voltage to 50 volts.  The capacitances are actually voltage dependent.
  115. *   These numbers are the zero-bias values.
  116. .MODEL QNL NPN (BF=80 RB=100 CCS=2PF TF=0.3NS TR=6NS CJE=3PF CJC=2PF
  117. +   VA=50)
  118.  
  119. * These commands provide print and plot output for selected voltages
  120. *   and currents.  The plots are the so-called "line printer" plots.
  121. *   That is, plots made out of characters.  To get real, high-resolution
  122. *   plots you need to use Probe.
  123. .PRINT DC V(4) V(5)
  124. .PLOT DC IC(Q2) 
  125. .PRINT AC VM(5) VP(5) 
  126. .PLOT AC VCM(Q2) VCP(Q2)
  127. .PRINT NOISE INOISE ONOISE
  128. .PLOT NOISE INOISE ONOISE 
  129. .PRINT TRAN V(4) V(5)
  130. .PLOT TRAN V(4) V(5) I(CLOAD)
  131. *.PROBE
  132. .END
  133.