home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / engprog / nonres.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1987-08-09  |  3.1 KB  |  116 lines
  1. 0   CLS
  2. 10  'THIS PROGRAM IS FROM ARRL DEP'T PX #122 AND IS IN THE PUBLIC DOMAIN
  3. 15  'MODIFICATIONS AND COLOR ADDED BY:
  4. 20  '                     |-------------------|
  5. 25  '                     |  R. W. THWING Sr. |
  6. 30  '                     |      K4EDE        |
  7. 35  '                     |    P.O. BOX 40    |
  8. 40  '                     |   COLUMBUS, NC    |
  9. 45  '                     |      28722        |
  10. 50  '                     |-------------------|
  11. 55  '
  12. 60  '<<<<<<<<<<<<<<<<<<<<<<< PROGRAM BEGINS >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  13. 65  '
  14. 100  KEY OFF:COLOR 0,11,1:CLS
  15. 110  LOCATE 2,25:PRINT"NON RESONANT LENGTHS OF COAXIAL CABLE"
  16. 120  LOCATE 4,2:PRINT STRING$(76,"~")
  17. 121  LOCATE 10,20:PRINT"IN THIS PROGRAM YOU WILL BE ASKED FOR THE"
  18. 122  LOCATE 11,19:PRINT"VELOCITY FACTOR OF THE CABLE YOU WANT TO USE"
  19. 123  LOCATE 13,19:PRINT"IF YOU DON'T KNOW IT......YOU SHOULD HAVE RUN"
  20. 124  LOCATE 14,18:PRINT"THE PROGRAM COAXIAL CABLE CHARACTERISTICS FIRST"
  21. 125  LOCATE 16,25:PRINT"IF YOU WANT TO DO THAT, THEN PRESS [Y] NOW - ELSE PRESS ANY KEY";
  22. 126  ZZ$=INKEY$:IF ZZ$= "" THEN 126
  23. 127  IF ZZ$= "Y" OR ZZ$="y" THEN COLOR 15,0,0:CLS:LOCATE 12,38:PRINT"WAIT":RUN"COAXCABL
  24. 128  LOCATE 18,30:PRINT"CONTINUE AS YOU WERE"
  25. 130  LOCATE 22,35:COLOR 20:PRINT"[ENTER]"
  26. 140  ZZ$=INKEY$:IF ZZ$="" THEN 140
  27. 150  COLOR 15,1,9:CLS
  28. 505  DIM F(10,2),M9(10)
  29. 525  PRINT
  30. 530  PRINT"    FREQUENCY BANDS FOR RESONANCE TEST (LOWEST FREQUENCY BAND TO HIGHEST)"
  31. 535  PRINT:PRINT"     <<<<<<<<<<< TEN BANDS MAX. >>>>>>>>>>>":PRINT:PRINT:PRINT"        ENTER 0 TO END ENTRY OF BANDS):":PRINT
  32. 540  B9=0
  33. 545  I=1
  34. 550  J=1
  35. 555  PRINT"     BAND";I;": LOWER";
  36. 556  GOTO 565
  37. 560  PRINT TAB(15);"UPPER";
  38. 565  PRINT" BOUND (MHZ)";
  39. 570  INPUT F(I,J)
  40. 575  IF F(I,J)=0 THEN GOTO 605
  41. 580  J=J+1
  42. 585  IF J=2 THEN GOTO 560
  43. 590  B9=B9+1
  44. 595  I=I+1
  45. 600  IF I<=10 THEN GOTO 550
  46. 605  PRINT:PRINT"     SHORTEST CABLE LENGTH TO TRY (FEET)";:PRINT;
  47. 610  INPUT C1
  48. 615  PRINT:PRINT"     LONGEST CABLE LENGTH TO TRY (FEET)";
  49. 620  INPUT C2
  50. 625  PRINT:PRINT"     VELOCITY FACTOR OF CABLE";
  51. 626  PRINT;:PRINT"      NORMAL .66 Yes/No ";
  52. 627  INPUT ZZ$:IF ZZ$= "Y" OR ZZ$= "y" THEN V= 0.66:GOTO 635
  53. 628  IF ZZ$= "N" OR ZZ$= "n" THEN 630
  54. 629  GOTO 626
  55. 630  PRINT:PRINT"     ENTER DIFFERENT VELOCITY FACTOR";
  56. 634  INPUT V
  57. 635  PRINT:PRINT"     NUMBER OF SAMPLES PER FOOT OF CABLE";
  58. 640  INPUT S:PRINT
  59. 645  REM
  60. 665  Y=C2/(234*V)
  61. 670  FOR I=1 TO B9
  62. 675  M9(I)=INT(F(I,2)*Y)
  63. 680  NEXT I
  64. 685  REM
  65. 700  PRINT
  66. 705  PRINT;:PRINT"      NON RESONANT CABLE LENGTHS (FEET):";
  67. 735  C=C1
  68. 740  GOSUB 1065
  69. 745  R1=R2
  70. 750  IF R1=1 THEN L=C1
  71. 775  FOR I=C1*S+1 TO C2*S
  72. 780  C=I/S
  73. 785  GOSUB 1065
  74. 790  IF R2=1 THEN GOTO 875
  75. 820  IF R1=0 THEN GOTO 890
  76. 825  Y=C-(1/S)
  77. 830  IF L=Y THEN COLOR 14:PRINT TAB(42);L
  78. 835  IF L<>Y THEN COLOR 14:PRINT TAB(42);L;"TO";Y
  79. 840  R1=0
  80. 845  GOTO 890
  81. 875  IF R1=1 THEN GOTO 890
  82. 880  R1=1
  83. 885  L=C
  84. 890  NEXT I
  85. 915  IF R1=0 THEN STOP
  86. 920  IF L=C THEN COLOR 14:PRINT TAB(42);L
  87. 925  IF L<>C THEN COLOR 14:PRINT TAB(42);L;"TO";C
  88. 930  COLOR 0,15,0:GOTO 2000
  89. 1065  Y=234*V/C
  90. 1070  M=1
  91. 1075  T=M*Y
  92. 1130  IF T>F(B9,2) THEN GOTO 1185
  93. 1135  B=1
  94. 1140  IF M>M9(B) THEN GOTO 1165
  95. 1145  IF T<F(B,1) THEN GOTO 1165
  96. 1150  IF T>F(B,2) THEN GOTO 1165
  97. 1155  R2=0
  98. 1160  RETURN
  99. 1165  B=B+1
  100. 1170  IF B<=B9 THEN GOTO 1140
  101. 1175  M=M+1
  102. 1180  IF M<=M9(B9) THEN GOTO 1075
  103. 1185  R2=1
  104. 1190  RETURN
  105. 2000  LOCATE 23,55:COLOR 20:PRINT"[ENTER]"
  106. 2010  ZZ$=INKEY$:IF ZZ$="" THEN 2010
  107. 2020  COLOR 0,15,0:CLS:LOCATE 12,25:PRINT"WHAT NOW? "
  108. 2030  LOCATE 14,25:PRINT"DO ANOTHER LENGTH OR BANDS?.................A"
  109. 2035  LOCATE 16,25:PRINT"RETURN TO MAIN MENU?........................M"
  110. 2040  LOCATE 18,25:PRINT"RETURN TO BASIC?............................B";
  111. 2050  ZZ$=INKEY$:IF ZZ$="" THEN 2050
  112. 2060  IF ZZ$= "A" OR ZZ$= "a" THEN RUN 100
  113. 2070  IF ZZ$= "B" OR ZZ$= "b" THEN COLOR 15,0,0:CLS:KEY ON:END
  114. 2075  IF ZZ$= "M" OR ZZ$= "m" THEN COLOR 15,0,0:CLS:RUN"MAINMENU"
  115. 2080  GOTO 2020
  116.