home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / eepub03 / smath-i.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1986-08-17  |  11.7 KB  |  335 lines
  1. 10  CLS: PRINT "FLOW GRAPH NODE REDUCTION PROGRAM V1.0M (8/18/86)
  2. 20  PRINT "Written by David Love for the TSC Electronics Program and
  3. 30  PRINT "      *********************************************
  4. 40  PRINT "      *                                           *
  5. 50  PRINT "      *  DR. ALLEN KATZ, CHAIRMAN                 *
  6. 60  PRINT "      *  DEPT ELECTRONICS ENGINEERING TECHNOLOGY  *
  7. 70  PRINT "      *  TRENTON STATE COLLEGE, CN550             *
  8. 80  PRINT "      *  TRENTON, NEW JERSEY 8625                 *
  9. 90  PRINT "      *                                           *
  10. 100  PRINT "      *  THE AUTHOR RESERVES THE RIGHTS TO THIS   *
  11. 110  PRINT "      *  PROGRAM; HOWEVER, COPYING AND USE FOR    *
  12. 120  PRINT "      *  EDUCATIONAL PURPOSES IS ENCOURAGED.      *
  13. 130  PRINT "      *                                           *
  14. 140  PRINT "      *  PLEASE REPORT ANY ERRORS OR PROBLEMS     *
  15. 150  PRINT "      *  WITH THIS PROGRAM TO THE AUTHOR.         *
  16. 160  PRINT "      *  TEL (609) 771 2487                       *
  17. 170  PRINT "      *                                           *
  18. 180  PRINT "      *********************************************
  19. 190  DIM L$(4): PI=4*ATN(1)
  20. 200  PRINT: INPUT "WANT AN EXPANATION (Y/N)"; Q$
  21. 210  IF Q$<>"Y" THEN GOSUB 1970: GOTO 240
  22. 220  CLS:
  23. 230  GOSUB 1750
  24. 240  INPUT"DATA OR COMMAND";U$
  25. 250  IF U$="ME" OR U$="HELP" THEN GOSUB 1970: GOTO 240
  26. 260  IF U$="LO" OR U$="LOAD" THEN 2510
  27. 270  IF U$="EX" THEN 2220
  28. 280  IF U$="EN" OR U$="END" THEN END
  29. 290  IF U$="HC" THEN GOSUB 2920: PRINT: GOTO 240
  30. 300  REM INPUT DATA SECTION ****************************************
  31. 310  INPUT"INPUT NUMBER OF LINES";MC
  32. 320  INPUT "INPUT NUMBER OF NODES";NI
  33. 330  PRINT:DIM M(3,5*MC),A(3,4*MC)
  34. 340  FOR N=1 TO MC
  35. 350  PRINT "LINE NUMBER";N
  36. 360  INPUT "INPUT SOURCE NODE";A(0,N)
  37. 370  INPUT "INPUT LOAD NODE";A(1,N)
  38. 380  INPUT "INPUT REFLECTION/XMISSION COEF IN ANGULAR FORM";A(2,N),A(3,N)
  39. 390  PRINT  :NEXT
  40. 400  GOSUB 1650                           
  41. 410  REM MAIN DECISION BLOCK ***************************************
  42. 420  INPUT"MODS";U$
  43. 430  IF U$="CH" THEN GOSUB 2640
  44. 440  IF U$="DS" THEN D1=(D1+2)MOD4:PRINT "MATRIX DATA TURNED ";:IF D1=2 THEN PRINT "ON" ELSE PRINT "OFF"
  45. 450  IF U$="NS" THEN GOSUB 2750
  46. 460  IF U$="PR" THEN PR=2: GOSUB 1650: PR=0
  47. 470  IF U$="HC" THEN GOSUB 2920
  48. 480  IF U$="EN" OR U$="END" THEN 2900
  49. 490  IF U$="PP" THEN PS=(PS+2)MOD4 :PRINT "PROCESS TO PRINTER ";:IF PS=2 THEN PRINT "ENABLED" ELSE PRINT "DISABLED"
  50. 500  IF U$="PA" THEN PX=(PX+2)MOD4 :PRINT "ANSWER TO ";:IF PX=2 THEN PRINT "PRINTER" ELSE PRINT "CRT"
  51. 510  IF U$="SA" OR U$="SAVE" THEN GOSUB 2840
  52. 520  IF U$="ME" OR U$="HELP" THEN GOSUB 1970
  53. 530  IF U$="GP" THEN PR=2:PS=2:D1=2:PX=2:GOTO 560
  54. 540  IF U$<>"GO" THEN 420
  55. 550  REM POLAR TO RECTANGULAR *************************************
  56. 560  MD=MC:NJ=NI
  57. 570  IF D1=2 THEN GOSUB 1650
  58. 580  FOR X=1 TO MD
  59. 590  M(0,X)=A(0,X) :M(1,X)=A(1,X)
  60. 600  M(2,X)=A(2,X)*COS(PI*A(3,X)/180)
  61. 610  M(3,X)=A(2,X)*SIN(PI*A(3,X)/180)
  62. 620  NEXT X
  63. 630  IF PS=0 THEN PRINT "POLAR TO RECTANGULAR"
  64. 640  IF PS=2 THEN LPRINT "POLAR TO RECTANGULAR"
  65. 650  IF D1=2 THEN GOSUB 1530
  66. 660  REM PARALLEL LINE REDUCTION SECTION **************************
  67. 670  FOR J=1 TO MD-1
  68. 680  FOR K=J+1 TO MD
  69. 690  IF M(0,J)=0 THEN 800
  70. 700  IF M(0,J)=M(0,K) AND M(1,J)=M(1,K) THEN 730
  71. 710  GOTO 800
  72. 720  REM ADD LINE J TO LINE K
  73. 730  M(2,J)=M(2,J) + M(2,K)
  74. 740  M(3,J)=M(3,J) + M(3,K)
  75. 750  REM CANCEL LINE K
  76. 760  M(0,K)=0 :M(1,K)=0
  77. 770  IF PS=0 THEN PRINT "PARALLEL REDUCTION"
  78. 780  IF PS=2 THEN LPRINT "PARALLEL REDUCTION"
  79. 790  IF D1=2 THEN GOSUB 1530
  80. 800  NEXT :NEXT
  81. 810  IF NJ=2 THEN 1260
  82. 820  REM NODE REDUCTION SECTION **********************************
  83. 830  FOR X=1 TO MD
  84. 840  IF M(0,X)<>NJ THEN 970
  85. 850  AF=0
  86. 860  FOR Y=1 TO MD
  87. 870  IF M(1,Y)<>NJ THEN 950
  88. 880  AF=AF+1
  89. 890  IF M(0,AF)<>0 THEN 880
  90. 900  M(0,AF)=M(0,Y):M(1,AF)=M(1,X)
  91. 910  M(2,AF)=M(2,X)*M(2,Y)-M(3,X)*M(3,Y)
  92. 920  M(3,AF)=M(2,X)*M(3,Y)+M(3,X)*M(2,Y)
  93. 930  IF AF>HT THEN HT=AF  
  94. 940  NK=NJ
  95. 950  NEXT Y
  96. 960  M(0,X)=0:M(1,X)=0
  97. 970  NEXT X
  98. 980  FOR Z=1 TO MD
  99. 990  IF M(1,Z)=NJ THEN M(0,Z)=0:M(1,Z)=0
  100. 1000  NEXT Z
  101. 1010  MD=HT
  102. 1020  IF NJ<>NK THEN PRINT"ILLEGAL FLOWGRAPH":PRINT:GOTO 540
  103. 1030  IF PS=0 THEN PRINT "NODE REDUCTION"
  104. 1040  IF PS=2 THEN LPRINT "NODE REDUCTION"
  105. 1050  IF D1=2 THEN GOSUB 1530
  106. 1060  REM "SELF LOOP REDUCTION" ************************************
  107. 1070  FOR J=1 TO MD
  108. 1080  IF M(0,J)<>M(1,J) OR M(0,J)=0 THEN 1240
  109. 1090  REM SUBTRACT 1
  110. 1100  M(2,J)=1-M(2,J)
  111. 1110  FOR K=1 TO MD
  112. 1120  IF M(1,K)=M(0,J) AND J<>K THEN 1150
  113. 1130  GOTO 1190
  114. 1140  REM COMPLEX DIVISION
  115. 1150  ST=M(2,J)*M(2,J)+M(3,J)*M(3,J)
  116. 1160  MEM=M(2,K)
  117. 1170  M(2,K)=(M(2,K)*M(2,J)+M(3,K)*M(3,J))/ST
  118. 1180  M(3,K)=(M(3,K)*M(2,J)-MEM*M(3,J))/ST
  119. 1190  NEXT K
  120. 1200  M(0,J)=0:M(1,J)=0
  121. 1210  IF PS=0 THEN PRINT "SELF LOOP"
  122. 1220  IF PS=2 THEN LPRINT "SELF LOOP"
  123. 1230  IF D1=2 THEN GOSUB 1530
  124. 1240  NEXT J:NJ=NJ-1:GOTO 670:REM RESTART
  125. 1250  REM "FINAL SECTION ******************************************
  126. 1260  FOR X=1 TO MD
  127. 1270  IF M(0,X)=1 THEN A=X
  128. 1280  IF M(0,X)=2 THEN B=X
  129. 1290  NEXT X
  130. 1300  IF B=0 THEN X=M(2,A):Y=M(3,A):GOTO 1410
  131. 1310  CR=M(2,A)*M(2,B)-M(3,A)*M(3,B)
  132. 1320  CI=M(2,A)*M(3,B)+M(3,A)*M(2,B)
  133. 1330  CR=1-CR
  134. 1340  REM DIVIDE
  135. 1350  IF PS=0 THEN PRINT "REVERSION"
  136. 1360  IF PS=2 THEN LPRINT "REVERSION"
  137. 1370  ST=CR*CR+CI*CI
  138. 1380  X=(M(2,A)*CR+M(3,A)*CI)/ST
  139. 1390  Y=(M(3,A)*CR-M(2,A)*CI)/ST
  140. 1400  IF D1=2 THEN PRINT:PRINT "REAL","IMAGINARY":PRINT X,Y:PRINT
  141. 1410  J=SQR(X*X+Y*Y)
  142. 1420  K=180*ATN(Y/X)/PI
  143. 1430  IF X<0 THEN K=K+180
  144. 1440  IF PX=0 THEN PRINT ELSE LPRINT
  145. 1450  IF PX=0 THEN PRINT "THE ANSWER IS"
  146. 1460  IF PX=2 THEN LPRINT "THE ANSWER IS"
  147. 1470  IF PX=0 THEN PRINT J;"MAGNITUDE",K;"DEGREES"
  148. 1480  IF PX=2 THEN LPRINT J;"MAGNITUDE",K;"DEGREES"
  149. 1490  IF PX=0 THEN PRINT ELSE LPRINT
  150. 1500  PR=0
  151. 1510  GOTO 420
  152. 1520  REM DEBUGGING SECTION *************************************
  153. 1530  IF PR=0 THEN PRINT ELSE LPRINT
  154. 1540  IF PR=0 THEN PRINT "LINE","SOURCE","LOAD","REAL","IMAGINARY"
  155. 1550  IF PR=2 THEN LPRINT "LINE","SOURCE","LOAD","REAL","IMAGINARY"
  156. 1560  FOR DP=1 TO MD
  157. 1570  IF PR=0 THEN PRINT DP,M(0,DP),M(1,DP),M(2,DP),M(3,DP)
  158. 1580  IF PR=2 THEN LPRINT DP,M(0,DP),M(1,DP),M(2,DP),M(3,DP)
  159. 1590  NEXT
  160. 1600  IF PR=0 THEN PRINT: PRINT: PRINT ELSE LPRINT: LPRINT
  161. 1610  IF PR=2 THEN RETURN
  162. 1620  INPUT U$
  163. 1630  RETURN
  164. 1640  REM ANGULAR MATRIX PRINTOUT **********************************
  165. 1650  IF PR=0 THEN PRINT ELSE LPRINT
  166. 1660  IF PR=0 THEN PRINT "LINE","SOURCE","LOAD","MAGNITUDE","ANGLE"
  167. 1670  IF PR=2 THEN LPRINT "LINE","SOURCE","LOAD","MAGNITUDE","ANGLE"
  168. 1680  FOR DP=1 TO MC
  169. 1690  IF PR=0 THEN PRINT DP,A(0,DP),A(1,DP),A(2,DP),A(3,DP)
  170. 1700  IF PR=2 THEN LPRINT DP,A(0,DP),A(1,DP),A(2,DP),A(3,DP)
  171. 1710  NEXT
  172. 1720  IF PR=0 THEN PRINT: PRINT: PRINT ELSE LPRINT: LPRINT
  173. 1730  RETURN
  174. 1740  REM MENU SECTION ***********************************************
  175. 1750  PRINT "                        MENU   PAGE 1"
  176. 1760  PRINT
  177. 1770  PRINT "THIS PROGRAM WILL TAKE A MULTIPORT S PARAMETER NETWORK AND REDUCE"
  178. 1780  PRINT "IT THRU FLOW GRAPH TECNIQUES TO A SINGLE S PARAMETER BETWEEN"
  179. 1790  PRINT "NODES 1 AND 2. *"
  180. 1800  PRINT
  181. 1810  PRINT "THE PROGRAM REQUIRES THAT REFLECTION/XMISSION COEF DATA BE IN POLAR"
  182. 1820  PRINT ,"FORM, WITH A MAGNITUDE BETWEEN 0 AND 1, AND AN ANGLE BETWEEN 0 AND"
  183. 1830  PRINT "360 DEGREES. (INCIDENTALLY COMPUTATION IS DONE RECTANGULARLY.)"
  184. 1840  PRINT
  185. 1850  PRINT "MODIFICATIONS MAY BE MADE TO THE INPUTTED DATA AT THE APPROPRIATE"
  186. 1860  PRINT "POINTS DURING THE PROGRAM THRU THE USE OF THE KEY SYMBOLS LISTED"
  187. 1870  PRINT "BELOW."
  188. 1880  PRINT
  189. 1890  PRINT ,"ADDITIONALLY, MATRIX DATA MAY BE SAVED AND RECALLED TO THE DISC"
  190. 1900  PRINT "USING THE PROPER KEY SYMBOLS LISTED BELOW."
  191. 1910  PRINT :PRINT ,
  192. 1920  PRINT "  * EACH S PARAMETER IS DEFINED IN THE MATRIX BY A LINE NUMBER"
  193. 1930  PRINT "    WHICH SPECIFIES THE SOURCE NODE, LOAD NODE, AND REFLECTION/XMISSION
  194. 1940  PRINT "    COEFFICIENT MAGNITUDE AND ANGLE."
  195. 1950  PRINT :PRINT
  196. 1960  INPUT "             TO CONTINUE PRESS <RETURN>";U$
  197. 1970  CLS
  198. 1980  PRINT "                   MENU   PAGE 2
  199. 1990  PRINT :PRINT
  200. 2000  PRINT "SYMBOL                     EXPLANATION"
  201. 2010  PRINT "------                     -----------"
  202. 2020  PRINT "  EX    WILL CAUSE THE COMPUTER TO EXECUTE EXAMPLE PROGRAM."
  203. 2030  PRINT "        (ONLY POSSIBLE AFTER THE FIRST MENUE LISTING.)"
  204. 2040  PRINT "  CH    CHANGE LINE DATA. "
  205. 2050  PRINT "  NS    NODE SWITCH, THIS SUBROUTINE MAKES IT POSSIBLE TO"
  206. 2060  PRINT "        REDEFINE NODES 1 AND 2."
  207. 2070  PRINT "  PR    PRINT MODIFIED MATRIX DATA (LINE PRINTER).
  208. 2080  PRINT "  HC    HARD COPY OF MENU.
  209. 2090  PRINT "  DS    MATRIX DISPLAY OF COMPUTATIONS. PROMPTING IS REQUIRED"
  210. 2100  PRINT "        TO ADVANCE IN THIS MODE."
  211. 2110  PRINT "  EN    EXIT PROGRAM. (ALSO END)
  212. 2120  PRINT "  PP    CAUSES REDUCTION PROCESSES TO LIST TO LINE PRINTER.
  213. 2130  PRINT "  PA    CAUSES ANSWER TO LIST TO LINE PRINTER.
  214. 2140  PRINT "  GO    INITIATES COMPUTATION.
  215. 2150  PRINT "  SA    MATRIX STORE TO DISC. (ALSO SAVE)
  216. 2160  PRINT "  LO    MATRIX LOAD FROM DISC. (ONLY POSSIBLE AFTER THE FIRST"
  217. 2170  PRINT "        MENU LISTING. - ALSO LOAD)"
  218. 2180  PRINT "  ME    REDISPLAY MENU TO CRT. (ALSO HELP)
  219. 2190  PRINT:PRINT
  220. 2200  RETURN
  221. 2210  REM EXAMPLE SECTION *******************************************
  222. 2220  CLS
  223. 2230  PRINT "THIS EXAMPLE IS FOR A 3 PORT DIRECTIONAL COUPLER. THE COUPLING"
  224. 2240  PRINT "IS 10 dB, INSERTION LOSS IS 1.2 dB, DIRECTIVITY IS 25 dB. THE"
  225. 2250  PRINT "PHASE ANGLES WERE ARBITRARILY CHOSEN. THE LOAD AND DEVICE"
  226. 2260  PRINT "VSWR'S ARE 1.5 AND 1.25 RESPECTIVELY. PRESS THE CARRIAGE"
  227. 2270  PRINT "RETURN TO PROMPT THE EXAMPLE PROGRAM TO CONTINUE."
  228. 2280  L$(0)="INPUT NUMBER OF LINES  "
  229. 2290  L$(1)="INPUT NUMBER OF NODES  "
  230. 2300  L$(2)="INPUT SOURCE NODE  "
  231. 2310  L$(3)="INPUT LOAD NODE  "
  232. 2320  L$(4)="INPUT REFLECTION/XMISSION COEF IN POLAR FORM  "
  233. 2330  PRINT
  234. 2340  PRINT L$(0);12 :MC=12
  235. 2350  PRINT L$(1);6 :NI=6
  236. 2360  INPUT U$
  237. 2370  DIM A(3,48),M(3,60)
  238. 2380  FOR X=1 TO 12
  239. 2390  PRINT 
  240. 2400  PRINT "LINE NUMBER";X
  241. 2410  READ DA :PRINT L$(2);DA :A(0,X)=DA
  242. 2420  READ DA :PRINT L$(3);DA :A(1,X)=DA
  243. 2430  READ DA,DB :PRINTL$(4);DA;DB :A(2,X)=DA :A(3,X)=DB
  244. 2440  INPUT U$
  245. 2450  NEXT X
  246. 2460  GOTO 400
  247. 2470  DATA 6,1,.80,10,1,6,.89,20,1,2,.48,30,3,6,.48,30
  248. 2480  DATA 2,3,.80,50,3,2,.89,60,1,4,.93,70,5,6,.93,70
  249. 2490  DATA 3,4,.10,90,5,2,.10, 90,5,4,.89,110,4,5,.80,120
  250. 2500  REM FILE LOAD FROM DISC **********************************
  251. 2510  PRINT:INPUT "FILE NAME, FILES OR QUIT"; F$
  252. 2520  IF F$="FILES" THEN FILES "*.SMA":GOTO 2510
  253. 2530  IF F$="QUIT" THEN 420
  254. 2540  F$=F$+".SMA": ERASE A,M
  255. 2550  OPEN"I",#1,F$
  256. 2560  INPUT#1,MC,NI
  257. 2570  DIM A(3,4*MC),M(3,5*MC)
  258. 2580  FOR X=1 TO MC:FOR Y=0 TO 3
  259. 2590  INPUT#1,A(Y,X):NEXT:NEXT
  260. 2600  PRINT"FILE LOADED INTO MATRIX"
  261. 2610  CLOSE#1
  262. 2620  GOSUB 1640:GOTO 420
  263. 2630  REM CHANGE SECTION *****************************************
  264. 2640  PRINT:INPUT "INPUT LINE NUMBER TO BE CHANGED";LN
  265. 2650  IF LN>MC THEN MC=LN
  266. 2660  PRINT:PRINTA(0,LN),A(1,LN),A(2,LN),A(3,LN)
  267. 2670  PRINT:PRINT
  268. 2680  INPUT "INPUT SOURCE NODE";A(0,LN)
  269. 2690  IF A(0,LN)>NI THEN NI=A(0,LN)
  270. 2700  INPUT "INPUT LOAD NODE";A(1,LN)
  271. 2710  IF A(1,LN)>NI THEN NI=A(1,LN)
  272. 2720  INPUT "INPUT REFLECTION/XMISSION COEF IN POLAR FORM";A(2,LN),A(3,LN)
  273. 2730  GOSUB 1650:RETURN
  274. 2740  REM NODE SWITCH SUB ************************************
  275. 2750  PRINT:INPUT "INPUT NODE # TO REPLACE NODE 1";NA
  276. 2760  INPUT "INPUT NODE # TO REPLACE NODE 2";NB
  277. 2770  FOR X=1 TO MC:FOR Y=0 TO 1
  278. 2780  IF A(Y,X)=1 THEN A(Y,X)=NA:GOTO 2820
  279. 2790  IF A(Y,X)=2 THEN A(Y,X)=NB:GOTO 2820
  280. 2800  IF A(Y,X)=NA THEN A(Y,X)=1
  281. 2810  IF A(Y,X)=NB THEN A(Y,X)=2
  282. 2820  NEXT: NEXT:GOSUB 1640:RETURN
  283. 2830  REM SAVE TO DISC ******************************************
  284. 2840  PRINT:INPUT"FILE NAME";F$:F$=F$+".SMA"
  285. 2850  OPEN"O",#1,F$
  286. 2860  PRINT#1,MC,NI
  287. 2870  FOR X=1 TO MC:FOR Y=0 TO 3
  288. 2880  PRINT#1,A(Y,X):NEXT:NEXT
  289. 2890  CLOSE#1:RETURN
  290. 2900  END
  291. 2910  REM HARDCOPY OF MENU **********************************************
  292. 2920  LPRINT "                        MENU   PAGE 1"
  293. 2930  LPRINT
  294. 2940  LPRINT "THIS PROGRAM WILL TAKE A MULTIPORT S PARAMETER NETWORK AND REDUCE"
  295. 2950  LPRINT "IT THRU FLOW GRAPH TECNIQUES TO A SINGLE S PARAMETER BETWEEN"
  296. 2960  LPRINT "NODES 1 AND 2. *"
  297. 2970  LPRINT
  298. 2980  LPRINT "THE PROGRAM REQUIRES THAT REFLECTION/XMISSION COEF DATA BE IN POLAR"
  299. 2990  LPRINT "FORM, WITH A MAGNITUDE BETWEEN 0 AND 1, AND AN ANGLE BETWEEN 0 AND"
  300. 3000  LPRINT "360 DEGREES. (INCIDENTALLY COMPUTATION IS DONE RECTANGULARLY.)"
  301. 3010  LPRINT
  302. 3020  LPRINT "MODIFICATIONS MAY BE MADE TO THE INPUTTED DATA AT THE APPROPRIATE"
  303. 3030  LPRINT "POINTS DURING THE PROGRAM THRU THE USE OF THE KEY SYMBOLS LISTED"
  304. 3040  LPRINT "BELOW."
  305. 3050  LPRINT
  306. 3060  LPRINT "ADDITIONALLY, MATRIX DATA MAY BE SAVED AND RECALLED TO THE DISC"
  307. 3070  LPRINT "USING THE PROPER KEY SYMBOLS LISTED BELOW."
  308. 3080  LPRINT :PRINT ,
  309. 3090  LPRINT "  * EACH S PARAMETER IS DEFINED IN THE MATRIX BY A LINE NUMBER"
  310. 3100  LPRINT "    WHICH SPECIFIES THE SOURCE NODE, LOAD NODE, AND REFLECTION/XMISSION
  311. 3110  LPRINT "    COEFFICIENT MAGNITUDE AND ANGLE."
  312. 3120  LPRINT :LPRINT
  313. 3130  LPRINT :LPRINT
  314. 3140  LPRINT "SYMBOL                     EXPLANATION"
  315. 3150  LPRINT "------                     -----------"
  316. 3160  LPRINT "  EX    WILL CAUSE THE COMPUTER TO EXECUTE EXAMPLE PROGRAM."
  317. 3170  LPRINT "        (ONLY POSSIBLE AFTER THE FIRST MENUE LISTING.)"
  318. 3180  LPRINT "  CH    CHANGE LINE DATA. "
  319. 3190  LPRINT "  NS    NODE SWITCH, THIS SUBROUTINE MAKES IT POSSIBLE TO"
  320. 3200  LPRINT "        REDEFINE NODES 1 AND 2."
  321. 3210  LPRINT "  PR    PRINT MODIFIED MATRIX DATA.(LINE PRINTER)
  322. 3220  LPRINT "  HC    HARD COPY OF MENU.
  323. 3230  LPRINT "  DS    MATRIX DISPLAY OF COMPUTATIONS. PROMPTING IS REQUIRED"
  324. 3240  LPRINT "        TO ADVANCE IN THIS MODE."
  325. 3250  LPRINT "  EN    EXIT PROGRAM. (ALSO END)
  326. 3260  LPRINT "  PP    CAUSES REDUCTION PROCESSES TO LIST TO LINE PRINTER.
  327. 3270  LPRINT "  PA    CAUSES ANSWER TO LIST TO LINE PRINTER.
  328. 3280  LPRINT "  GO    INITIATES COMPUTATION.
  329. 3290  LPRINT "  SA    MATRIX STORE TO DISC. (ALSO SAVE)
  330. 3300  LPRINT "  LO    MATRIX LOAD FROM DISC. (ONLY POSSIBLE AFTER THE FIRST"
  331. 3310  LPRINT"        MENU LISTING. - ALSO LOAD)"
  332. 3320  LPRINT"  ME    REDISPLAY MENU TO CRT. (ALSO HELP)
  333. 3330  LPRINT:LPRINT
  334. 3340  RETURN
  335.