home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / ee3 / magcor.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1989-01-22  |  4.9 KB  |  107 lines
  1. 100  REM "MAGCOR"
  2. 110  REM BY S. TICKNOR (W78LM) REV. FEB 86    FROM "RF DESIGN" MAGAZINE
  3. 120  REM IBM VERSION BY JIM ONDERKO, 4/25/87, FOR RF & MICROWAVE II
  4. 130  COLOR 4,0,1:CLS:KEY OFF:PRINT:PRINT
  5. 140  PRINT "    **************************************
  6. 150  PRINT "    * COMPUTES L, U1, B, AL, XL, FF, WL, *
  7. 160  PRINT "    *   Ect. FOR TOROIDAL, SLEFVE AND    *
  8. 170  PRINT "    *     BINOCULAR MAGNETIC CORES       *
  9. 180  PRINT "    **************************************
  10. 190  REM
  11. 200  PRINT:PRINT:COLOR 2:PRINT TAB(20)"INSTRUCTIONS"
  12. 210  PRINT:PRINT:
  13. 220  PRINT " ENTER EITHER INITIAL PERMIABILITY OR INDUCTANCE BUT NOT BOTH."
  14. 240  PRINT " THEN ENTER 0 FOR THE OTHER VALUE."
  15. 250  PRINT:PRINT" NOTE: RESULTS INDICATED";:COLOR 4:PRINT" (BINO)";:COLOR 2:PRINT " ARE FOR THE SAME CORE,
  16. 260  PRINT " CUT IN HALF BY HEIGHT, AND REARRANGED IN A PARALLER OR
  17. 270  PRINT " BINOCULAR CONFIGURATION.  FOR A SPECIFIC BINOCULAR CORE,
  18. 290  PRINT " APPROX. THE DIMENSIONS AS IF IT WAS  TWO PARALLEL CORES.
  19. 300  PRINT " ENTER THE I.D. AND O.D. OF ONE CORE, AND HT. EQUAL TO 2X
  20. 310  PRINT " ONE CORE.
  21. 326  COLOR 4:PRINT:PRINT
  22. 330  INPUT "PRESS RETURN TO START PROGRAM ";Q$
  23. 350  BEEP:CLS:PRINT:PRINT:PIE=3.14159
  24. 370  INPUT "             INITIAL PERM   [U]";U  :REM     AT APPROPRIATE FREQ. (F)
  25. 380  INPUT "          INDUCTANCE (uH)   [L]";L
  26. 390  INPUT "          NUMBER OF TURNS   [N]";N  :REM     PASSES THROUGH CORE.
  27. 400  INPUT "  HEIGHT OF CORE (inches)  [HT]";HT
  28. 410  INPUT "OUTSIDE DIAMETER (inches)  [OD]";OD
  29. 420  INPUT " INSIDE DIAMETER (inches)  [ID]";ID
  30. 430  INPUT "          FREQUENCY (MHz)   [F]";F
  31. 440  INPUT "                  V (RMS)   [V]";V  :REM    VOLTS ACROSS PRI. WINDING
  32. 450  REM
  33. 460  IF U = 0 THEN 490
  34. 470  L=0.0117*U*N*N*HT*LOG(OD/ID)/LOG(10):AL=L/N^2
  35. 480  GOTO 500
  36. 490  U=L/(0.0117*N*N*HT*LOG(OD/ID)/LOG(10)):AL=L/N^2
  37. 500  XL=2*PIE*F*L:X1=XL/N^2
  38. 510  AS=PIE*HT*(OD+ID)+(PIE/2)*(OD^2-ID^2)
  39. 520  AW=PIE*(ID^2)/4
  40. 530  AE=HT*((OD-ID)/2)
  41. 540  LE=((OD-ID)/(LOG(OD/ID)/LOG(10)))*1.36437
  42. 550  VE=AE*LE
  43. 560  W1=OD-ID+2*HT:B1=2*(OD-ID)+HT
  44. 570  WT=N*(2*HT+OD-ID)-(OD-ID+HT)
  45. 580  BT=N*(2*(OD-ID)+HT)-(OD-ID)
  46. 590  FF=W1*2*PIE/(HT*LOG(OD/ID))
  47. 600  FB=B1*2*PIE/(HT*LOG(OD/ID))
  48. 610  B=V/(0.28645*F*N*AE)
  49. 620  REM
  50. 625  COLOR 1,7,7:CLS:PRINT
  51. 640  PRINT " CORE OD = "OD" IN."TAB(32)"N = "N" TURNS"
  52. 650  PRINT " CORE ID = "ID" IN."TAB(32)"F = "F" MHz"
  53. 660  PRINT " CORE HT = "HT" IN."TAB(32)"V = "V" V (RMS)"
  54. 670  PRINT "__________________________________________________"
  55. 680  PRINT:PRINT " PERMABILITY (U) ="U;TAB(39)"[PERMABILITY AT FREQ (F)]
  56. 690  PRINT "        FLUX (B) ="B"GAUSS"
  57. 700  PRINT "  INDUCTANCE (L) ="L"uH"TAB(39)"[TOTAL INDUCTANCE]
  58. 710  PRINT "  REACTANCE (XL) ="XL"OHMS"TAB(39)"[TOTAL REACTANCE]
  59. 720  PRINT "   IND. 1T (XAL) ="AL"uH"TAB(39)"[INDUCTANCE FOR 1 TURN]
  60. 730  PRINT "     XL 1T (XAL) ="X1"OHMS"TAB(39)"[REACTANCE FOR 1 TURN]
  61. 740  PRINT "  COOLING A (AS) ="AS"SQ.IN."TAB(39)"[TOTAL SURFACE AREA FOR COOLING]
  62. 750  PRINT "   WINDOW A (AW) ="AW"SQ.IN."TAB(39)"[WINDOW AREA (OF INSIDE DIAMETER)]
  63. 770  PRINT "  CRS SEC A (AE) ="AE"SQ.IN."TAB(39)"[EFFECTIVE CROSS SECTIONAL AREA]
  64. 780  PRINT "   MAG PATH (LE) ="LE"IN."TAB(39)"[EFFECTIVE MAGNETIC PATH LENGTH]
  65. 790  PRINT "  EFF. VOL. (VE) ="VE"CU.IN."TAB(39)"[EFFECTIVE VOLUME]
  66. 800  PRINT "    1T WIRE (W1) ="W1"IN."TAB(39)"[LENGTH OF 1 COMPLETE TURN (TOROID)]
  67. 810  PRINT "            (B1) ="B1"IN.(BIO)"TAB(39)"[LENGTH 1 COMP. TURN (BINO. CORE)]
  68. 820  PRINT " TOTAL WIRE (WT) ="WT"IN."TAB(39)"[TOTAL LENGTH OF WITE ON TOROID]
  69. 830  PRINT "            (BT) ="BT"IN.(BIO)"TAB(39)"[TOTAL WIRE LENGTH ON BINO. CORE]
  70. 840  PRINT " FORM FACT. (FF) ="INT((FF+0.05)*10)/10 ;TAB(39)"[TOROID FORM FACTOR VALUE]
  71. 850  PRINT "            (FB) ="INT((FB+0.05)*10)/10"(BIO)"TAB(39)"[BINO. CORE F. FACTOR]
  72. 860  PRINT:COLOR 4:INPUT "WOULD YOU LIKE TO PRINT DATA (P), END (E), OR RUN AGAIN (R)";G$
  73. 870  BEEP
  74. 900  IF G$ = "" THEN 860
  75. 910  IF G$<>"P"AND G$<>"E"AND G$<>"R"AND G$<>"p"AND G$<>"e"AND G$<>"r" THEN 860
  76. 920  IF G$="R" THEN 100
  77. 930  IF G$="r" THEN 100
  78. 940  IF G$="P" THEN 990
  79. 950  IF G$="p" THEN 990
  80. 960  IF G$="E" THEN 2000
  81. 970  IF G$="e" THEN 2000
  82. 990  LPRINT:LPRINT:LPRINT CHR$(27)"W1";"MAGNETIC CORE CALCULATIONS
  83. 995  LPRINT:LPRINT:LPRINT CHR$(27)"W0"
  84. 1000  LPRINT " CORE OD = "OD" IN."TAB(32)"N = "N" TURNS"
  85. 1010  LPRINT " CORE ID = "ID" IN."TAB(32)"F = "F" MHz"
  86. 1020  LPRINT " CORE HT = "HT" IN."TAB(32)"V = "V" V (RMS)"
  87. 1030  LPRINT "__________________________________________________"
  88. 1040  LPRINT:LPRINT " PERMABILITY (U) ="U;TAB(39)"[PERMABILITY AT FREQ (F)]
  89. 1050  LPRINT "        FLUX (B) ="B"GAUSS"
  90. 1060  LPRINT "  INDUCTANCE (L) ="L"uH"TAB(39)"[TOTAL INDUCTANCE]
  91. 1070  LPRINT "  REACTANCE (XL) ="XL"OHMS"TAB(39)"[TOTAL REACTANCE]
  92. 1080  LPRINT "   IND. 1T (XAL) ="AL"uH"TAB(39)"[INDUCTANCE FOR 1 TURN]
  93. 1090  LPRINT "     XL 1T (XAL) ="X1"OHMS"TAB(39)"[REACTANCE FOR 1 TURN]
  94. 1100  LPRINT "  COOLING A (AS) ="AS"SQ.IN."TAB(39)"[TOTAL SURFACE AREA FOR COOLING]
  95. 1110  LPRINT "   WINDOW A (AW) ="AW"SQ.IN."TAB(39)"[WINDOW AREA (OF INSIDE DIAMETER)]
  96. 1120  LPRINT "  CRS SEC A (AE) ="AE"SQ.IN."TAB(39)"[EFFECTIVE CROSS SECTIONAL AREA]
  97. 1130  LPRINT "   MAG PATH (LE) ="LE"IN."TAB(39)"[EFFECTIVE MAGNETIC PATH LENGTH]
  98. 1140  LPRINT "  EFF. VOL. (VE) ="VE"CU.IN."TAB(39)"[EFFECTIVE VOLUME]
  99. 1150  LPRINT "    1T WIRE (W1) ="W1"IN."TAB(39)"[LENGTH OF 1 COMPLETE TURN (TOROID)]
  100. 1160  LPRINT "            (B1) ="B1"IN.(BIO)"TAB(39)"[LENGTH 1 COMP. TURN (BINO. CORE)]
  101. 1170  LPRINT " TOTAL WIRE (WT) ="WT"IN."TAB(39)"[TOTAL LENGTH OF WIRE ON TOROID]
  102. 1180  LPRINT "            (BT) ="BT"IN.(BIO)"TAB(39)"[TOTAL WIRE LENGTH ON BINO. CORE]
  103. 1190  LPRINT " FORM FACT. (FF) ="INT((FF+0.05)*10)/10 ;TAB(39)"[TOROID FORM FACTOR VALUE]
  104. 1200  LPRINT "            (FB) ="INT((FB+0.05)*10)/10"(BIO)"TAB(39)"[BINO. CORE F. FACTOR]
  105. 1210  GOTO 625
  106. 2000  KEY ON:COLOR 7,0,0:CLS:END
  107.