home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / design1 / nucgc.bas (.txt) < prev    next >
Encoding:
GW-BASIC  |  1987-05-24  |  3.0 KB  |  113 lines
  1. 5  REM * RF AND MICROWAVE II COMPUTER PROGRAM BY RONALD L. GEBHARDT JR. *
  2. 10  REM * THIS PROGRAM CALCULATES CONSTANT GAIN CIRCLES FOR THE
  3. 15  REM * NON-UNILATERAL CASE *
  4. 18  CLS
  5. 20  PRINT" This program calculates constant gain circles for the non-unilateral"
  6. 30  PRINT" case. You will be asked to enter in the S parameters of the device"
  7. 35  PRINT" you intend to use. Please do so in polar form. The program will then"
  8. 37  PRINT" ask you for the desired gain. Enter this value in dB. The program will"
  9. 40  PRINT" then return the location of the constant gain circles center and"
  10. 45  PRINT" its radius on the Smith Chart. "
  11. 50  PRINT:PRINT:PRINT:PRINT
  12. 51  PI=4*ATN(1):DG=180/PI
  13. 55  GOSUB 395
  14. 60  INPUT"ENTER IN THE DESIRED GAIN";YG
  15. 63  GOSUB 355
  16. 65  GOSUB 240
  17. 70  GOSUB 100
  18. 75  GOSUB 170
  19. 80  GOSUB 190
  20. 85  GOSUB 255
  21. 90  GOSUB 275
  22. 92  GOSUB 300
  23. 94  GOSUB 330
  24. 95  GOSUB 500
  25. 96  INPUT"WOULD YOU LIKE TO GO AGAIN? (Y OR N)";ANS$
  26. 97  IF ANS$<>"Y" THEN 99
  27. 98  GOTO 18
  28. 99  END
  29. 100  REM ******** CALCULATION OF DS **********
  30. 105  X = MS11*MS22
  31. 110  XA = AS11+AS22
  32. 115  Y=MS12*MS21
  33. 120  YA= AS12+AS21
  34. 121  XA=XA/DG
  35. 122  YA=YA/DG
  36. 125  XR = X*COS(XA)
  37. 130  XI = X*SIN(XA)
  38. 135  YR = Y*COS(YA)
  39. 140  YI = Y*SIN(YA)
  40. 145  XR=XR-YR
  41. 150  XI = XI-YI
  42. 155  DS=SQR(XR*XR+XI*XI)
  43. 160  DSA = DG*(ATN(XI/XR)-(SGN(XR)-1)*PI/2)
  44. 165  RETURN
  45. 170  REM ******* CALCULATION OF D2 *******
  46. 175  D2 = MS22*MS22-DS*DS
  47. 180  RETURN
  48. 190  REM ******* CALCULATION OF C2 *******
  49. 195  X = DS*MS11
  50. 200  XA = DSA-AS11
  51. 201  XA=XA*(PI/180)
  52. 205  XR = X*COS(XA)
  53. 210  XI=X*SIN(XA)
  54. 211  YA=AS22*(PI/180)
  55. 212  YR = MS22*COS(YA)
  56. 213  YI = MS22*SIN(YA)
  57. 215  X=YR-XR
  58. 220  XA=YI-XI
  59. 225  C2=SQR(X*X+XA*XA)
  60. 230  C2A = DG*(ATN(XA/X)-(SGN(X)-1)*PI/2)
  61. 235  RETURN
  62. 240  REM ***** CALCULATION OF G *****
  63. 245  G = GD/(MS21*MS21)
  64. 250  RETURN
  65. 255  REM **** CALCULATE DISTANCE FORM SMITH CHART CENTER ****
  66. 260  RO = (G*C2)/(1+D2*G)
  67. 265  RA = (-1)*C2A
  68. 266  IF RA>(-180) THEN 270
  69. 267  RA=RA+360
  70. 270  RETURN
  71. 275  REM **** CALCULATE STABILITY CONSTANT ******
  72. 280  K=(1+(DS*DS)-(MS11*MS11)-(MS22*MS22))
  73. 290  K=K/(2*MS21*MS12)
  74. 295  RETURN
  75. 300  REM ***** CALCULATE THE RADIUS OF THE CIRCLE *****
  76. 305  X= ABS(MS12*MS21)
  77. 310  Y=(2*K*X*G)-(X*X*G*G)
  78. 315  PO = SQR(1-Y)
  79. 320  PO = PO/(1+D2*G)
  80. 325  RETURN
  81. 330  REM ****** OUTPUT OF DATA ******
  82. 335  PRINT"THE DESIRED GAIN IS ";YG;" DB"
  83. 340  PRINT
  84. 345  PRINT" THE CENTER OF THE DESIRED GAIN CIRCLE IS LOCATED AT: ";RO;" ANGLE ";RA
  85. 346  PRINT"THE CIRCLE RADIUS IS:";PO
  86. 350  RETURN
  87. 355  REM ***** CONVERSION OF DB TO NON DB ******
  88. 360  GD = 10^(YG/10)
  89. 365  RETURN
  90. 395  REM ******* INPUT S-PARAMETERS *********
  91. 400  INPUT"ENTER THE MAGNITUDE OF S11";MS11
  92. 405  INPUT"ENTER THE ANGLE OF S11";AS11
  93. 410  INPUT"ENTER THE MAGNITUDE OF S12";MS12
  94. 415  INPUT"ENTER THE ANGLE OF S12";AS12
  95. 420  INPUT"ENTER THE MAGNITUDE OF S21";MS21
  96. 425  INPUT"ENTER THE ANGLE OF S21";AS21
  97. 430  INPUT"ENTER THE MAGNITUDE OF S22";MS22
  98. 435  INPUT"ENTER THE ANGLE OF S22";AS22
  99. 440  RETURN
  100. 500  REM ******* HARD COPY **************
  101. 505  INPUT"WOULD YOU LIKE A HARD COPY? (Y OR N)";ANS$
  102. 510  IF ANS$<>"Y" THEN 560
  103. 515  LPRINT,"S11 MAG. = ";MS11;" S11 ANGLE = ";AS11
  104. 520  LPRINT,"S12 MAG. = ";MS12;" S12 ANGLE = ";AS12
  105. 525  LPRINT,"S21 MAG. = ";MS21;" S21 ANGLE = ";AS21
  106. 530  LPRINT, "S22 MAG. = ";MS22;" S22 ANGLE = ";AS22
  107. 535  LPRINT:LPRINT:LPRINT
  108. 540  LPRINT"THE DESIRED GAIN IS ";YG;" DB"
  109. 545  LPRINT"THE CIRCLE CENTER IS LOCATED AT: ";RO;" ANGLE ";RA
  110. 550  LPRINT"THE CIRCLE RADIUS IS: ";PO
  111. 555  LPRINT:LPRINT:LPRINT
  112. 560  RETURN
  113.