home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / david4 / stlstdya.bas < prev    next >
Encoding:
BASIC Source File  |  1987-01-24  |  4.0 KB  |  118 lines
  1. 10 REM STL STUDY PROGRAM
  2. 40 TE=10
  3. 50 DEF FNA(A)=LOG(A)/LOG(TE)
  4. 85 PRINT"THE BROADCASTERS DATABASE PRESENTS:"
  5. 90 PRINT"STL PATH STUDY...TO FIND ANTENNA SIZE NEEDED."
  6. 95 PRINT"ALL WORK IS IN DBW (DBD)...EXCEPT TRANSMITTER"
  7. 97 PRINT"POWER IS IN WATTS."
  8. 100 INPUT"CUSTOMER CALL OR ID";CI$
  9. 110 INPUT"FREQUENCY (mhz)";F
  10. 120 INPUT"PATH LENGTH (mi) ";M
  11. 130 INPUT"COAX LOSS (db/100')";CL
  12. 140 INPUT"COAX LENGTH (ft.)";CF
  13. 150 INPUT"TRANSMITTER OUTPUT POWER (W)";P
  14. 160 INPUT"FADE FACTOR (db, 0 UNKNOWN)";FF:FF=ABS(FF)
  15. 170 INPUT"TRANSMITTER TOWER/ANT HEIGHT (ft.)";HT
  16. 180 INPUT"EXTRA LOSS (ie.3db FOR COMBINER,ETC)";EL:EL=ABS(EL)
  17. 185 :
  18. 190 PRINT"       RECEIVER        606C IS     93.5dbw"
  19. 193 PRINT"                       606  IS      111dbw"
  20. 195 PRINT"      SENSITIVITY      505C IS     94.5dbw"
  21. 197 PRINT"                       505  IS      111dbw"
  22. 200 PRINT"         BELOW         STL-10 IS    114dbw"
  23. 210 PRINT"                       PTS-10N IS 116.8dbw
  24. 220 PRINT"         0 dbw         PTS-10C IS   103dbw"
  25. 230 PRINT"                       M/A COM IS   102dbw"
  26. 240 INPUT SR:SR=ABS(SR)
  27. 250 PRINT"           WORKING.....":PRINT
  28. 260 FO=FNA(F):D=FNA(M):W=FNA(P)
  29. 270 PL=36.6+(20*FO)+(20*D)
  30. 275 CC=CL/100
  31. 280 XL= (CC*CF)+.25
  32. 290 TG=10*W
  33. 300 FC=1316*SQR(((M/2)^2)/F*M)
  34. 350 DH=1.41*SQR(HT)
  35. 400 TL=TG-PL-XL-EL-FF
  36. 900 PRINT:PRINT:PRINT
  37. 1000 PRINT"PATH STUDY FOR ";CI$;" ON ";F;" mhz."
  38. 1010 PRINT:PRINT"FOR A ";M;" MILE PATH THERE IS ";PL;"dbw. LOSS."
  39. 1020 PRINT"FOR ";CF;" FT. COAX RATED AT ";CL;" db/100' EXPECT"
  40. 1025 PRINT XL;" dbw LOSS INCLUDING .25dbw FOR CONNECTORS."
  41. 1030 PRINT:PRINT"WITH ";P;"WATTS TOP AND ";FF;"dbw FADE"
  42. 1035 PRINT"FACTOR AND ";EL;" dbw LOSS, YOU MAY ASSUME"
  43. 1040 PRINT"THE TOTAL RECIEVER SIGNAL WITH NO ANTENNAS"
  44. 1050 PRINT"SHOULD BE ";TL;" dbw. THE GAIN NEEDED FOR THE 2"
  45. 1055 AG=-TL-SR
  46. 1060 PRINT"ANTENNAS IS ";AG;" dbw FOR -";SR;"dbw SENSITIVITY."
  47. 1070 PRINT:PRINT"THIS WOULD BE ABOUT ";AG/2;"dbw PER ANTENNA."
  48. 1080 PRINT"THE DISTANCE TO THE HORIZON IS ";DH;" MILES."
  49. 1090 PRINT"AND THE FATTEST PART OF .6 OF THE 1ST. FRESNEL"
  50. 1094 PRINT"ZONE IS ";FC;" FT."
  51. 1095 IF I=0 THEN GOTO 1097
  52. 1097 PRINT: IF I>0 THEN 3000:
  53. 2000 GOTO 5700
  54. 2010 IF X$="Y" THEN GOSUB 5000
  55. 3000 END
  56. 5000 :
  57. 5060 REM LAT & LONG SUBS
  58. 5070 GOSUB 5190
  59. 5080 PRINT"PLEASE ENTER DEGREES, MINUTES, SECONDS (D,M,S)"
  60. 5100 GOSUB 5280
  61. 5110 GOSUB 5360
  62. 5120 GOSUB 5470
  63. 5130 GOSUB 5520
  64. 5140 GOSUB 5570
  65. 5150 PRINT
  66. 5180 RETURN
  67. 5190 PI=3.141592654#
  68. 5200 REM ARCSINE FUNC
  69. 5210 DEF FN ASN(X)=ATN(X/SQR(-X*X+1))
  70. 5220 REM ARCCOSINE FUNC
  71. 5230 DEF FN ACS(X)=-ATN(X/SQR(-X*X+1))+PI/2
  72. 5240 REM DEG/RADIANS
  73. 5250 DEF FN RAD(D)=D*PI/180
  74. 5260 DEF FN DEG(R)=R/PI*180
  75. 5270 RETURN
  76. 5280 PRINT
  77. 5290 INPUT"FROM LATITUDE (D,M,S): ";D1,M1,S1
  78. 5300 INPUT"FROM LONGITUDE (D,M,S): ";D2,M2,S2
  79. 5330 INPUT"TO LATITUDE (D,M,S): ";D3,M3,S3
  80. 5340 INPUT"TO LONGITUDE (D,M,S): ";D4,M4,S4
  81. 5350 RETURN
  82. 5360 L1=D1+M1/60+S1/3600
  83. 5370 G1=D2+M2/60+S2/3600
  84. 5380 L2=D3+M3/60+S3/3600
  85. 5390 G2=D4+M4/60+S4/3600
  86. 5400 REM CONV TO RADIANS
  87. 5410 L1=FN RAD(L1)
  88. 5420 G1=FN RAD(G1)
  89. 5430 L2=FN RAD(L2)
  90. 5440 G2=FN RAD(G2)
  91. 5450 RETURN
  92. 5460 REM CALC DISTANCE
  93. 5470 ANGLE=COS (L1)*COS(L2)*COS(G1-G2)+SIN(L1)*SIN(L2)
  94. 5480 ARC=FN ACS(ANGLE)
  95. 5490 DIST=FN DEG (ARC)*69.09571
  96. 5500 RETURN
  97. 5510 REM CALC BEARING
  98. 5520 ANGLE=COS (L2)/SIN(ARC)*SIN (G1-G2)
  99. 5530 BEARING = FN DEG (FN ASN (ANGLE))
  100. 5540 IF L2<L1 THEN BEARING=180-BEARING
  101. 5550 IF BEARING<0 THEN BEARING=BEARING+360
  102. 5560 RETURN
  103. 5570 REM RESULTS
  104. 5580 M=DIST+.5:IF X$="Y" THEN PRINT
  105. 5590 PRINT:PRINT"FROM";D1;",";M1;",";S1;" & ";D2;",";M2;",";S2
  106. 5595 PRINT:PRINT"TO ";D3;",";M3;",";S3;" & ";D4;",";M4;",";S4
  107. 5600 PRINT:PRINT"IS ";M;" MILES"
  108. 5610 I=BEARING+.5
  109. 5616 PRINT
  110. 5620 PRINT"AND THE BEARING IS ";I;" DEGREES TRUE."
  111. 5625 PRINT
  112. 5630 RETURN
  113. 5700 PRINT:PRINT:INPUT"ANOTHER STUDY ? - (Y) OR (N) ";E$
  114. 5705 IF E$="Y" OR E$="y" THEN 10
  115. 5710 PRINT"THANK YOU FOR USING THE STL PATH STUDY PROGRAM"
  116. 5720 PRINT"PLEASE WAIT FOR THE SYSTEM TO REBOOT"
  117. 5730 SYSTEM
  118.