home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / antmatch / antmatch.bas
Encoding:
BASIC Source File  |  1988-05-06  |  4.0 KB  |  86 lines
  1. 10 REM ANTENNA MATCHING/TRANSMISSION LINE EVALUATION PROGRAM
  2. 20 REM BY KC6A AND N6NB; (C) 1983 BY HAYDEN BOOK CO.,INC.
  3. 30 CLS:REM CLEAR SCREEN
  4. 32 PRINT:PRINT TAB(6)"ANTENNA MATCHING EVALUATOR"
  5. 40 REM THIS IS FOR APPLE, VIC AND CP/M; CHANGE '^' TO '[' FOR TRS-80
  6. 50 PRINT:PRINT:PRINT 
  7. 60 BL$=CHR$(7)
  8. 70 DEF FNL(X)=LOG(X)/LOG(10)
  9. 80 DEF FNA(X)=INT(X*100+.5)/100
  10. 90 PRINT:PRINT "NOTE:  ALL POWER LEVELS ARE IN WATTS"
  11. 100 PRINT:PRINT "WHAT IS YOUR FORWARD POWER READING"
  12. 102 INPUT "AT THE TRANSMITTER? ";FP
  13. 110 IF FP<=0 THEN PRINT BL$:GOTO 100
  14. 120 PRINT:PRINT "YOU'LL NEED TO ENTER THE REFLECTED"
  15. 122 PRINT "POWER OR THE VSWR.  WHICH DO YOU WISH--"
  16. 130 PRINT "REFLECTED POWER (R) OR VSWR (V)? ":INPUT A$
  17. 140 IF A$="R" THEN 190
  18. 150 IF A$<>"V" THEN PRINT BL$;"ENTER R OR V":GOTO 130
  19. 160 PRINT:PRINT "WHAT IS THE VSWR AT THE TRANSMITTER? ":INPUT VS
  20. 170 IF VS<1 THEN PRINT BL$:GOTO 160
  21. 180 RP=(((VS-1)/(VS+1))^2)*FP
  22. 185 GOTO 250
  23. 190 PRINT:PRINT "WHAT IS THE REFLECTED POWER AT THE"
  24. 192 INPUT "TRANSMITTER? ";RP
  25. 200 IF RP<0 THEN PRINT BL$;"ERROR":GOTO 190
  26. 210 IF RP>FP THEN PRINT BL$;"MUST BE LESS THEN FWD POWER":GOTO 190
  27. 220 V=SQR(RP/FP):VS=(1+V)/(1-V)
  28. 250 PRINT:PRINT "NOW YOU CAN ENTER EITHER THE TRANS-"
  29. 252 PRINT "MISSION LINE LOSS OR THE TYPE OF LINE"
  30. 254 PRINT "AND ITS LENGTH. "
  31. 260 PRINT:PRINT "WANT THE LINE LOSS CALCULATED? (Y/N) ":INPUT A$
  32. 270 IF A$="Y" THEN 310
  33. 280 PRINT:PRINT "WHAT IS THE TRANSMISSION LINE LOSS IN DB"
  34. 282 PRINT "NOTE--MUST BE MATHEMATICALLY POSSIBLE"
  35. 284 PRINT "WITH OTHER VALUES ENTERED.":INPUT LL
  36. 290 IF LL<0 THEN PRINT BL$;"ERROR": GOTO 280
  37. 300 GOTO 500
  38. 310 PRINT:INPUT "TRANSMISSION LINE= RG-";C$
  39. 315 REM FIND TRANSMISSION LINE LOSS
  40. 320 READ NM
  41. 330 FOR J = 1 TO NM
  42. 340 READ X$:READ LL
  43. 350 IF C$=X$ THEN 400
  44. 360 NEXT J
  45. 390 PRINT BL$;"INVALID LINE TYPE.  TRY AGAIN":GOTO 260
  46. 400 PRINT:INPUT "WHAT IS THE FREQUENCY IN MHZ? ";F
  47. 410 IF F<=0 THEN PRINT BL$:GOTO 400
  48. 420 PRINT:PRINT "HOW LONG IS THE TRANSMISSION LINE"
  49. 422 INPUT "IN FEET? ";LN
  50. 430 IF LN<0 THEN PRINT BL$;"ERROR":GOTO 420
  51. 440 LL=LL*SQR(F/100)*LN/100
  52. 500 REM CALC VSWR AT LOAD
  53. 505 IF VS=1 THEN VL=1:B=10^(LL/10):GOTO 530
  54. 510 A=(VS+1)/(VS-1):B=10^(LL/10)
  55. 520 VL=(A+B)/(A-B):REM VSWR AT LOAD
  56. 522 IF VL>=1 THEN 530
  57. 523 PRINT:PRINT "THE VSWR AT THE TRANSMITTER AND THE"
  58. 524 PRINT"CABLE LOSS INDICATE A VSWR EXCEEDING INFINITY"
  59. 525 PRINT "AT THE LOAD.  EITHER THE LINE IS BAD OR THE"
  60. 526 PRINT "READING AT THE TRANSMITTER IS WRONG.":END
  61. 530 REM CALC LOSS IN CABLE
  62. 540 C=(VL-1)/(VL+1)
  63. 550 CL=10*FNL((B^2-C^2)/(B*(1-C^2))):REM CABLE LOSS
  64. 560 FL=FP/(10^(CL/10)):REM FWD POWER AT LOAD
  65. 570 RL=(((VL-1)/(VL+1))^2)*FL:REM REFL PWR AT LOAD
  66. 580 PR=FL-RL:REM POWER TO LOAD
  67. 600 PC=FP-RP-PR:REM POWER LOST IN CABLE
  68. 700 PRINT:PRINT 
  69. 710 PRINT "VSWR AT TRANSMITTER=";TAB(30)FNA(VS)
  70. 720 PRINT "VSWR AT LOAD=";TAB(30)FNA(VL)
  71. 730 PRINT "FORWARD PWR AT XMTR=";TAB(30)FNA(FP)
  72. 740 PRINT "REVERSE PWR AT XMTR="; TAB(30)FNA(RP)
  73. 750 PRINT "TRUE POWER INTO XMSN LINE=";TAB(30)FNA(FP-RP)
  74. 760 PRINT "FORWARD POWER AT LOAD=";TAB(30)FNA(FL)
  75. 770 PRINT "REFLECTED PWR FROM LOAD=";TAB(30)FNA(RL)
  76. 780 PRINT "TRUE PWR INTO LOAD=";TAB(30)FNA(PR)
  77. 790 PRINT "LINE LOSS (INCL VSWR EFFECTS)=";TAB(30)FNA(CL);" DB"
  78. 1000 END 
  79. 2000 REM TRANSMISSION LINE LOSS TABLE
  80. 2010 DATA 11:REM NUMBER OF ENTRIES
  81. 2020 REM TO EXPAND THIS TABLE, ENTER A TYPE OF LINE FOLLOWED BY
  82. 2022 REM ITS LOSS IN DB/100 FEET AT 100 MHZ
  83. 2030 DATA "8",2.3,"9",2.3,"11",2.3,"213",2.3,"214",2.3
  84. 2040 DATA "8FOAM",1.7,"17",.85,"1/2HARD",.85,"3/4HARD",.6
  85. 2050 DATA "58",5,"58FOAM",3.5
  86. 9",2.3