HAM Radio 1/HamRadio.cdr/misc/pc-hamd3/logadd.prg

Text File | 1985-09-23 | 4.0 KB | 158 lines

*LOGADD VERSION 850910
*CALLED FROM LOGBOOK
* COPYRIGHT JOE KASSER G3ZCZ 1985

USE &LOGBOOK

STORE T TO callflag

GOTO BOTTOM
STORE CALL TO lastcall
STORE # TO lastentry

*initialise new variables
STORE date TO ndate
STORE time TO ntime
STORE band TO nband
STORE power TO npower
STORE mode TO nmode
STORE rx TO nrx
STORE tx TO ntx

SET INDEX TO &logbook

ERASE
*MAIN LOOP
DO WHILE callflag

   STORE "-" TO nqslsent
   STORE "-" TO nqslrx
   STORE "          " TO ncall
   STORE "          " TO ncomments
   STORE " " TO logflag
   STORE T TO dataflag

   DO WHILE dataflag
      @ 19,1  SAY lastentry
      @ 19,12 SAY "LAST CONTACT WAS WITH "
      @ 19,35 SAY lastcall

      @ 21,1  SAY "DATE"
      @ 21,13 SAY "TIME"
      @ 21,19 SAY "CALL"
      @ 21,28 SAY "BAND"
      @ 21,35 SAY "POWER"
      @ 21,43 SAY "MODE"
      @ 21,49 SAY "RX"
      @ 21,54 SAY "TX"
      @ 21,58 SAY "QS"
      @ 21,62 SAY "QR"
      @ 21,70 SAY "COMMENTS"
      @ 23,1  SAY "QRU (*HPL)"

      @ 22,1  GET ndate
      @ 22,11 GET ntime
      @ 22,17 GET ncall
      @ 22,28 GET nband
      @ 22,35 GET npower
      @ 22,41 GET nmode
      @ 22,48 GET nrx
      @ 22,53 GET ntx
      @ 22,58 GET nqslsent
      @ 22,62 GET nqslrx
      @ 22,68 GET ncomments
      @ 23,13 GET logflag

      READ

      DO CASE
         CASE logflag = 'H'
            GOTO TOP
            STORE 1 TO linecount
            STORE TRIM(ncall) TO fcall
            FIND &fcall
            IF # = 0
               ERASE
               @ 5,1 SAY ncall
               @ 5,12 SAY "Does not appear to be in the log"
               WAIT
               ERASE
            ELSE
               DO WHILE  CALL = fcall .AND. (.NOT.EOF)
                  IF linecount = 1
                     ERASE
                     @ 1,10 SAY "PREVIOUS CONTACTS ARE "
                  ENDIF
                  ? #,date,time,call,band,tx,rx,mode,power
                  ?? qslsent,qslrx,comments
                  STORE linecount + 1 TO linecount
                  IF linecount = 20
                     ?
                     WAIT
                     STORE 1 TO linecount
                  ENDIF
                  SKIP
               ENDDO
               ?
               WAIT
               IF linecount > 16
                  ERASE
               ENDIF
            ENDIF

         CASE  logflag = "L"
            *LOG ENTRY
            APPEND BLANK
            STORE F TO dataflag
            REPLACE qslsent WITH nqslsent
            REPLACE qslrx WITH nqslrx
            REPLACE date WITH ndate
            REPLACE time WITH ntime
            REPLACE call WITH ncall
            REPLACE band WITH nband
            REPLACE power WITH npower
            REPLACE mode WITH nmode
            REPLACE rx WITH nrx
            REPLACE tx WITH ntx
            REPLACE comments WITH ncomments
            STORE call TO lastcall
            STORE # TO lastentry
            STORE "          " TO ncall
            STORE "          " TO ncomments

         CASE logflag = 'P'
            USE &logbook
            GOTO BOTTOM
            SKIP -5
            ERASE
            @ 1,1  SAY '5 ENTRIES BEFORE'
            @ 1,18 SAY lastcall
            @ 1,30 SAY 'IN LOG, ARE'
            ?
            DO WHILE .NOT. EOF
               ? #,date,time,call,band,tx,rx,mode
               ?? power,qslsent,qslrx,comments
               SKIP
            ENDDO
            SET INDEX TO &logbook

         CASE logflag = "*"
            STORE F TO callflag
            STORE F TO dataflag

      ENDCASE
   ENDDO
ENDDO

* GET READY TO EXIT
RELEASE lastcall,lastentry,ndate,ntime,ncall,nband,npower,nmode
RELEASE nqslsent,nqslrx,nrx,ntx,ncomments,fcall,linecount
RETURN
  
*MAIN LOOP
DO WHILE callflag

   STORE "-" TO nqslsent
   STORE "-" TO nqslrx
   STORE "          " TO ncall
   STORE "