home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / circuit / lcres / lcres.bas next >
Encoding:
BASIC Source File  |  1989-04-04  |  6.8 KB  |  218 lines
  1. 10 REM:THIS PROGRAM IS FOR THE ANALYSIS & DESIGN OF L/C RESONANT CIRCUITS
  2. 20 REM:THIS PROGRAM IS FILED AS LCRES.BAS
  3. 30 CLS
  4. 40 PRINT TAB(20);"ANALYSIS AND DESIGN OF L/C CIRCUITS (FILE LCRES)"
  5. 50 PRINT TAB(33);"REMETAYER 8/01/83"
  6. 60 PRINT
  7. 70 PRINT
  8. 80 PRINT
  9. 90 PRINT TAB(32);"DEFINITIONS"
  10. 100 PRINT
  11. 110 PRINT
  12. 120 PRINT TAB(20);"CAP=CAPACITANCE IN PICOFARADS"
  13. 130 PRINT
  14. 140 PRINT TAB(20);"IND=INDUCTANCE IN MICROHENRIES"
  15. 150 PRINT
  16. 160 PRINT TAB(20);"FREQ=FREQUENCY IN MEGAHERTZ"
  17. 170 PRINT
  18. 180 PRINT TAB(20);"MAX=THE MAXIMUM VALUE OF THE VARIABLE"
  19. 190 PRINT
  20. 200 PRINT TAB(20);"MIN=THE MINIMUM VALUE OF THE VARIABLE"
  21. 210 PRINT
  22. 220 PRINT TAB(20);"OTHER VARIABLES OBVIOUS OR DEFINED LATER
  23. 230 PRINT
  24. 240 PRINT
  25. 250 INPUT  "PRESS RETURN TO CONTINUE",A$
  26. 260 CLS
  27. 270 PRINT
  28. 280 PRINT
  29. 290 PRINT
  30. 300 PRINT
  31. 310 PRINT TAB(38);"MENU"
  32. 320 PRINT
  33. 330 PRINT
  34. 340 PRINT TAB(15);"(A) KNOWN VALUES ARE MAXCAP,MINCAP,MAXFREQ,MINFREQ"
  35. 350 PRINT TAB(19);"UNKNOWN VALUES ARE MAXIND,MININD"
  36. 360 PRINT
  37. 370 PRINT TAB(15);"(B) KNOWN VALUES ARE MAXCAP,MINCAP,IND
  38. 380 PRINT TAB(19);"UNKNOWN VALUES ARE MAXFREQ,MINFREQ
  39. 390 PRINT
  40. 400 PRINT TAB(15);"(C) KNOWN IS IND,COILENGTH,COILDIA
  41. 410 PRINT TAB(19);"UNKNOWN IS NUMTURNS OF WIRE(CONV.COIL)
  42. 420 PRINT
  43. 430 PRINT TAB(15);"(D) KNOWN IS IND,TOROIDCHAR
  44. 440 PRINT TAB(19);"UNKNOWN IS NUMTURNS OF WIRE(TOROID COIL)
  45. 450 PRINT
  46. 460 PRINT TAB(15);"(E) KNOWN IS CAP,IND,,CIRQ
  47. 470 PRINT TAB(19);"CIRQ BASED ON A COIL WITH A SERIES RESISTER"
  48. 480 PRINT TAB(19);"UNKNOWN IS BEHAVIOR NEAR RESONANCE-PARALLEL CIRCUIT"
  49. 490 PRINT
  50. 500 PRINT
  51. 510 PRINT
  52. 520 PRINT
  53. 530 INPUT "SELECT ONE OF A THRU E";PGRM$
  54. 540 IF PGRM$="A" OR PGRM$="a" THEN 660
  55. 550 IF PGRM$="B" OR PGRM$="b" THEN 950
  56. 560 IF PGRM$="C" OR PGRM$="c" THEN 1190
  57. 570 IF PGRM$="D" OR PGRM$="d" THEN 1430
  58. 580 IF PGRM$="E" OR PGRM$="e" THEN 1660
  59. 590 CLS
  60. 600 PRINT "GO BACK AND TRY AGAIN"
  61. 610 PRINT
  62. 620 PRINT
  63. 630 PRINT
  64. 640 PRINT
  65. 650 GOTO 530
  66. 660 CLS
  67. 670 REM:SUBRTNE WHEN MAXCAP,MINCAP,MAXFREQ,MINFREQ ARE KNOWN
  68. 680 REM:UNKNOWN ARE MAXIND,MININD
  69. 690 INPUT "INPUT MAXIMUM VALUE OF CAPACITANCE IN PFDS!    ",MAXCAP
  70. 700 PRINT
  71. 710 INPUT "INPUT MINIMUM VALUE OF CAPACITANCE IN PFDS!    ",MINCAP
  72. 720 PRINT
  73. 730 INPUT "INPUT MAXIMUM DESIGN FREQUENCY IN MEGAHERTZ!    ",MAXFREQ
  74. 740 PRINT
  75. 750 INPUT "INPUT MINIMUM DESIGN FREQUENCY IN MEGAHERTZ!    ",MINFREQ
  76. 760 PRINT
  77. 770 PRINT
  78. 780 PRINT
  79. 790 PRINT
  80. 800 MAXIND=(159.15494#)^2/((MAXFREQ)^2*MINCAP)
  81. 810 MININD=(159.15494#)^2/((MINFREQ)^2*MAXCAP)
  82. 820 IF MAXIND<MININD GOTO  930
  83. 830 PRINT "MAXIMUM INDUCTOR TO MEET DESIGN REQUIREMENT IS ";MAXIND;"MICROH."
  84. 840 PRINT
  85. 850 PRINT "MINIMUM INDUCTOR TO MEET DESIGN REQUIREMENT IS ";MININD;"MICROH."
  86. 860 PRINT
  87. 870 PRINT
  88. 880 PRINT
  89. 890 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N) ";A$
  90. 900 CLS
  91. 910 IF A$="Y" OR A$="y" THEN GOTO  660
  92. 920 END
  93. 930 PRINT "CANNOT MEET THE DESIGN RANGE REQUIRED"
  94. 940 GOTO 860
  95. 950 CLS
  96. 960 REM:SUBRTNE WHEN MAXCAP,MINCAP,IND ARE KNOWN
  97. 970 REM:UNKNOWN ARE MAXFREQ,MINFREQ
  98. 980 INPUT "INPUT MAXIMUM VALUE OF CAPACITANCE IN PFDS!    ",MAXCAP
  99. 990 PRINT
  100. 1000 INPUT "INPUT MINIMUM VALUE OF CAPACITANCE IN PFDS!    ",MINCAP
  101. 1010 PRINT
  102. 1020 INPUT "INPUT VALUE OF THE INDUCTANCE IN MICROHENRIES!    ",IND
  103. 1030 PRINT
  104. 1040 PRINT
  105. 1050 PRINT
  106. 1060 PRINT
  107. 1070 MAXFREQ=159.15494#/((IND*MINCAP)^.5)
  108. 1080 MINFREQ=159.15494#/((IND*MAXCAP)^.5)
  109. 1090 PRINT "MAXIMUM FREQUENCY WITH THIS L/C CIRCUIT IS ";MAXFREQ;"MEGAHERTZ"
  110. 1100 PRINT
  111. 1110 PRINT "MINIMUM FREQUENCY WITH THIS L/C CIRCUIT IS ";MINFREQ;"MEGAHERTZ"
  112. 1120 PRINT
  113. 1130 PRINT
  114. 1140 PRINT
  115. 1150 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N)";A$
  116. 1160 CLS
  117. 1170 IF A$="Y" OR A$="y" THEN GOTO 950
  118. 1180 END
  119. 1190 CLS
  120. 1200 REM:SUBRTNE WHEN IND, COILENGTH, COILDIA ARE KNOWN
  121. 1210 REM:UNKNOWN IS NUMTURNS
  122. 1220 REM:REF. ARRL HNDBK FOR COILENGTH >= .4COILDIA
  123. 1230 INPUT "INPUT VALUE OF DESIGN INDUCTANCE IN MICROHENRIES!    ",IND
  124. 1240 PRINT
  125. 1250 INPUT "INPUT COIL LENGTH IN INCHES!    ",COILENGTH
  126. 1260 PRINT
  127. 1270 INPUT "INPUT COIL DIAMETER IN INCHES!    ",COILDIA
  128. 1280 PRINT
  129. 1290 PRINT
  130. 1300 PRINT
  131. 1310 PRINT
  132. 1320 NUMTURNS=(IND*(18*COILDIA+40*COILENGTH))^.5/(COILDIA)
  133. 1330 NUMTURNS=INT(100*(NUMTURNS+.005))/100
  134. 1340 PRINT "NUMBER OF TURNS FOR THE DESIGN INDUCTANCE IS  ";NUMTURNS
  135. 1350 PRINT "NOTE:  COILENGTH SHOULD BE >= .4*COILDIA."
  136. 1360 PRINT
  137. 1370 PRINT
  138. 1380 PRINT
  139. 1390 INPUT "DO YOU WANT TO TRY AGAIN?   (Y/N)";A$
  140. 1400 CLS
  141. 1410 IF A$="Y" OR A$="y" THEN GOTO 1190
  142. 1420 END
  143. 1430 CLS
  144. 1440 REM:SUBRTNE WHEN IND, TOROIDCHAR ARE KNOWN
  145. 1450 REM:UNKNOWN IS NUMTURNS
  146. 1460 REM:REF. ARRL HNDBK  COILCHAR=INDUCTANCE INDEX
  147. 1470 REM:LEAVE 30 DEGREES OF FORM OPEN TO MINIMIZE CAPACITANCE
  148. 1480 INPUT "INPUT VALUE OF DESIGN INDUCTANCE IN MICROHENRIES!    ",IND
  149. 1490 PRINT
  150. 1500 INPUT "INPUT VALUE OF THE INDUCTANCE INDEX IN MICROHENRIES/100 TURNS    ",COILCHAR
  151. 1510 PRINT
  152. 1520 PRINT
  153. 1530 PRINT
  154. 1540 PRINT
  155. 1550 NUMTURNS=100*((IND/COILCHAR)^.5)
  156. 1560 NUMTURNS=INT(100*(NUMTURNS+.005))/100
  157. 1570 PRINT "NUMBER OF TURNS FOR THE DESIGN INDUCTANCE IS   ";NUMTURNS
  158. 1580 PRINT "NOTE:  LEAVE 30 DEGREES OF TOROID OPEN"
  159. 1590 PRINT
  160. 1600 PRINT
  161. 1610 PRINT
  162. 1620 INPUT "DO YOU WANT TO TRY AGAIN?   (Y/N)";A$
  163. 1630 CLS
  164. 1640 IF A$="Y" OR A$="y" THEN GOTO 1430
  165. 1650 END
  166. 1660 CLS
  167. 1670 REM:SUBRTNE WHEN CAP,IND,CIRQ ARE KNOWN
  168. 1680 REM:UNKNOWN IS BEHAVIOR NEAR RESONANCE-PARALLEL CIRCUIT (COIL WITH SERIES RESISTANCE)
  169. 1690 PRINT
  170. 1700 PRINT
  171. 1710 PRINT
  172. 1720 PRINT
  173. 1730 PRINT TAB(38);"DEFINITIONS"
  174. 1740 PRINT
  175. 1750 PRINT
  176. 1760 PRINT TAB(20);"RESFREQ=RESONANT FREQUENCY IN MEGAHERTZ"
  177. 1770 PRINT
  178. 1780 PRINT TAB(20)"CAPREACT=CAPACATIVE REACTANCE"
  179. 1790 PRINT
  180. 1800 PRINT TAB(20);"INDREACT=INDUCTIVE REACTANCE"
  181. 1810 PRINT
  182. 1820 PRINT TAB(20);"IMPEDANCE=IMPEDANCE OF THE PARALLEL CIRCUIT"
  183. 1830 PRINT
  184. 1840 PRINT
  185. 1850 INPUT "PRESS RETURN TO CONTINUE";A$
  186. 1860 CLS
  187. 1870 INPUT "INPUT VALUE OF CAPACITANCE IN PICOFARADS!    ",CAP
  188. 1880 PRINT
  189. 1890 INPUT "INPUT VALUE OF INDUCTOR IN MICROHENRIES!    ",IND
  190. 1900 PRINT
  191. 1910 INPUT "INPUT VALUE OF CIRCUIT Q!    ",CIRQ
  192. 1920 PRINT
  193. 1930 PRINT
  194. 1940 PRINT
  195. 1950 PRINT
  196. 1960 RESFREQ=159.15494#/(CAP*IND)^.5
  197. 1970 FREQ=I*RESFREQ/100
  198. 1980 PRINT "RESFREQ= ";RESFREQ;"MEGAHERTZ";TAB(33);"CIRQ= ";CIRQ
  199. 1990 PRINT "IND= ";IND;"MICROH.";TAB(33);"CAP= ";CAP;"PFDS."
  200. 2000 PRINT
  201. 2010 PRINT
  202. 2020 FOR I=90 TO 110  STEP 5
  203. 2030 FREQ=I*RESFREQ/100
  204. 2040 CAPREACT=1/(2*3.14159*FREQ*.000001*CAP)
  205. 2050 INDREACT=2*3.14159*FREQ*IND
  206. 2060 INDIMP=((2*3.14159*RESFREQ*IND/CIRQ)^2+(2*3.14159*FREQ*IND)^2)^.5
  207. 2070 COMBIMP=((2*3.14159*RESFREQ*IND/CIRQ)^2+(INDREACT-CAPREACT)^2)^.5
  208. 2080 IMPEDANCE=CAPREACT*INDIMP/COMBIMP
  209. 2090 PRINT "FREQ= ";FREQ;"MH";TAB(33);"INDREACT= ";INDREACT;"OHMS"
  210. 2100 PRINT "IMPEDANCE= ";IMPEDANCE;"OHMS";TAB(33);"CAPREACT";CAPREACT;"OHMS"
  211. 2110 PRINT
  212. 2120 NEXT I
  213. 2130 PRINT
  214. 2140 PRINT
  215. 2150 INPUT "DO YOU WANT TO TRY AGAIN?(Y/N)";A$
  216. 2160 IF A$="Y" OR A$="y" THEN GOTO 1860
  217. 2170 END
  218.