Internet 1996 World Exposition/park.org.s3.amazonaws.com.7z/park.org.s3.amazonaws.com/Japan/Panasonic-/funcity/tokyo/slot.dcr/00065_Coin.ls

Text File | 2017-09-21 | 2.2 KB | 113 lines

on movecoin
  global gcoin, gbet
  if gcoin >= 10 then
    set the puppet of sprite 45 to 1
    set the castNum of sprite 45 to 12
    repeat while stillDown()
      set the locV of sprite 45 to the mouseV - 5
      set the locH of sprite 45 to the mouseH
      if gbet = 0 then
        movelamp(1)
      else
        movelamp(2)
      end if
      updatelamp()
      updateStage()
    end repeat
    set the puppet of sprite 45 to 0
    if (the mouseV > 132) and (the mouseV < 139) and (the mouseH > 256) and (the mouseH < 286) then
      if gbet = 0 then
        resetlamp(2)
      end if
      set gbet to gbet + 1
      if (gcoin / 10) > 14 then
        set gcoin to gcoin - 10
        dspcoin()
      else
        set gcoin to gcoin - 10
        setname()
      end if
      puppetSound("3.coin")
    end if
    updateStage()
  end if
end

on dspcoin
  global gcoin
  setname()
  set i to gcoin / 10
  if i < 15 then
    clearcoin()
    repeat with j = 31 to 44
      if i = 0 then
        exit repeat
      end if
      set the puppet of sprite j to 0
      set the visible of sprite j to 1
      set i to i - 1
    end repeat
  else
    if i < 100 then
      setcoin(31, 4, 232, 209)
    else
      if i < 200 then
        setcoin(31, 5, 232, 209)
      else
        if i < 350 then
          setcoin(31, 6, 230, 208)
        else
          if i < 500 then
            setcoin(31, 7, 231, 209)
          else
            setcoin(31, 8, 229, 207)
          end if
        end if
      end if
    end if
  end if
end

on setcoin i, j, k, l
  clearcoin()
  set the puppet of sprite i to 1
  set the castNum of sprite i to j
  set the locH of sprite i to k
  set the locV of sprite i to l
  set the visible of sprite i to 1
end

on clearcoin
  repeat with i = 31 to 44
    set the visible of sprite i to 0
    set the puppet of sprite i to 0
  end repeat
end

on allcoin
end

on setname
  global gname, gcoin
  if gname = EMPTY then
    set n to "ǏÇÒÇ×Ç•" && "/ "
  else
    set n to gname && "/ "
  end if
  if gcoin = 0 then
    set n to n & "0" && "Pg"
  else
    set n to n & gcoin && "Pg"
  end if
  put n into field "NAME"
end

on setbet
  global gbet, gcoin
  if gcoin >= 10 then
    set gcoin to gcoin - 10
    set gbet to gbet + 1
    dspcoin()
  end if
end