home *** CD-ROM | disk | FTP | other *** search
/ Geek Gadgets 1 / ADE-1.bin / ade-bin / lib / gcc-lib / m68k-amigaos / 2.7.2.1 / adainclude / g-hesora.adb < prev    next >
Encoding:
Text File  |  1995-10-17  |  4.9 KB  |  123 lines
  1. ------------------------------------------------------------------------------
  2. --                                                                          --
  3. --                         GNAT RUNTIME COMPONENTS                          --
  4. --                                                                          --
  5. --                     G N A T . H E A P _ S O R T _ A                      --
  6. --                                                                          --
  7. --                                 B o d y                                  --
  8. --                                                                          --
  9. --                            $Revision: 1.3 $                              --
  10. --                                                                          --
  11. --               Copyright (c) 1994 NYU, All Rights Reserved                --
  12. --                                                                          --
  13. -- The GNAT library is free software; you can redistribute it and/or modify --
  14. -- it under terms of the GNU Library General Public License as published by --
  15. -- the Free Software  Foundation; either version 2, or (at your option) any --
  16. -- later version.  The GNAT library is distributed in the hope that it will --
  17. -- be useful, but WITHOUT ANY WARRANTY;  without even  the implied warranty --
  18. -- of MERCHANTABILITY  or  FITNESS FOR  A PARTICULAR PURPOSE.  See the  GNU --
  19. -- Library  General  Public  License for  more  details.  You  should  have --
  20. -- received  a copy of the GNU  Library  General Public License  along with --
  21. -- the GNAT library;  see the file  COPYING.LIB.  If not, write to the Free --
  22. -- Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.        --
  23. --                                                                          --
  24. ------------------------------------------------------------------------------
  25.  
  26. package body GNAT.Heap_Sort_A is
  27.  
  28.    ----------
  29.    -- Sort --
  30.    ----------
  31.  
  32.    --  We are using the classical heapsort algorithm (i.e. Floyd's Treesort3)
  33.    --  as described by Knuth (ref???) with the modification that is mentioned
  34.    --  in excercise ???. For more details on this algorithm, see Robert B. K.
  35.    --  Dewar PhD thesis "The use of Computers in the X-ray Phase Problem".
  36.    --  University of Chicago, 1968.
  37.  
  38.    procedure Sort (N : Positive; Move : Move_Procedure; Lt : Lt_Function) is
  39.  
  40.       Max : Positive := N;
  41.       --  Current Max index in tree being sifted
  42.  
  43.       procedure Sift (S : Positive);
  44.       --  This procedure sifts up node S, i.e. converts the subtree rooted
  45.       --  at node S into a heap, given the precondition that any sons of
  46.       --  S are already heaps. On entry, the contents of node S is found
  47.       --  in the temporary (index 0), the actual contents of node S on
  48.       --  entry are irrelevant. This is just a minor optimization to avoid
  49.       --  what would otherwise be two junk moves in phase two of the sort.
  50.  
  51.       procedure Sift (S : Positive) is
  52.          C      : Positive := S;
  53.          Son    : Positive;
  54.          Father : Positive;
  55.  
  56.       begin
  57.          --  This is where the optimization is done, normally we would do a
  58.          --  comparison at each stage between the current node and the larger
  59.          --  of the two sons, and continue the sift only if the current node
  60.          --  was less than this maximum. In this modified optimized version,
  61.          --  we assume that the current node will be less than the larger
  62.          --  son, and unconditionally sift up. Then when we get to the bottom
  63.          --  of the tree, we check parents to make sure that we did not make
  64.          --  a mistake. This roughly cuts the number of comparisions in half,
  65.          --  since it is almost always the case that our assumption is correct.
  66.  
  67.          --  Loop to pull up larger sons
  68.  
  69.          loop
  70.             Son := 2 * C;
  71.             exit when Son > Max;
  72.  
  73.             if Son < Max and then Lt (Son, Son + 1) then
  74.                Son := Son + 1;
  75.             end if;
  76.  
  77.             Move (Son, C);
  78.             C := Son;
  79.          end loop;
  80.  
  81.          --  Loop to check fathers
  82.  
  83.          while C /= S loop
  84.             Father := C / 2;
  85.  
  86.             if Lt (Father, 0) then
  87.                Move (Father, C);
  88.                C := Father;
  89.             else
  90.                exit;
  91.             end if;
  92.          end loop;
  93.  
  94.          --  Last step is to pop the sifted node into place
  95.  
  96.          Move (0, C);
  97.       end Sift;
  98.  
  99.    --  Start of processing for Sort
  100.  
  101.    begin
  102.       --  Phase one of heapsort is to build the heap. This is done by
  103.       --  sifting nodes N/2 .. 1 in sequence.
  104.  
  105.       for J in reverse 1 .. N / 2 loop
  106.          Move (J, 0);
  107.          Sift (J);
  108.       end loop;
  109.  
  110.       --  In phase 2, we sift node 1 repeatedly, so that it is the largest
  111.       --  node in the remaining heap, and then exchange it with the last node.
  112.  
  113.       while Max > 1 loop
  114.          Sift (1);
  115.          Move (Max, 0);
  116.          Move (1, Max);
  117.          Max := Max - 1;
  118.       end loop;
  119.  
  120.    end Sort;
  121.  
  122. end GNAT.Heap_Sort_A;
  123.