home *** CD-ROM | disk | FTP | other *** search
/ 17 Bit Software 1: Collection A / 17Bit_Collection_A.iso / files / 290.dms / in.adf / quickrif.source / unvcomp.asm < prev    next >
Encoding:
Assembly Source File  |  1989-01-31  |  4.0 KB  |  126 lines
  1.  
  2.  
  3. ; unvcomp.asm  Copyright 1987 Dancing Flame all rights reserved.
  4. ;
  5. ; This file contains a single function which is set up to be called from
  6. ; C.  Ie the parameters are on the stack instead of registers.
  7. ;       decode_vplane(in, out, linebytes)
  8. ; where in is a bit-plane's worth of vertical-byte-run data
  9. ; and out is a bit-plane that gets completely over-written.
  10. ; Linebytes is the number of bytes-per-line in the out bitplane, and it
  11. ; should certainly be noted that the external pointer variable ytable
  12. ; must be initialized to point to a multiplication table of
  13. ; 0*linebytes, 1*linebytes ... n*linebytes  before this routine is called.
  14. ; 
  15. ; The format of "in":
  16. ;   Each column of the bitplane is compressed separately.  A 320x200
  17. ;   bitplane would have 40 columns of 200 bytes each.  The linebytes
  18. ;   parameter is used to count through the columns, it is not in the
  19. ;   "in" data, which is simply a concatenation of columns.
  20. ;
  21. ;   Each columns is an op-count followed by a number of ops.
  22. ;   If the op-count is zero, that's ok, it just means there's no change
  23. ;   in this column from the last frame.
  24. ;   The ops are of two classes, and followed by a varying amount of
  25. ;   data depending on which class.
  26. ;       1. Uniq ops - this is a byte with the hi bit set.  The hi bit is
  27. ;          masked down and the remainder is a count of the number of bytes
  28. ;          of data to copy literally.  It's of course followed by the
  29. ;          data to copy.
  30. ;       2. Same ops - this is a byte with hi bit cleared interpreted as
  31. ;          a count byte.  Its followed by a byte value to repeat count times.
  32. ;   Do bear in mind that the data is compressed vertically rather than
  33. ;   horizontally, so to get to the next byte in the destination (out)
  34. ;   we add linebytes instead of one!
  35. ;
  36.  
  37.  
  38.     public _decode_vplane
  39.  
  40. firstp    set    12
  41. in    set    4+firstp
  42. out    set    8+firstp
  43. linebytes    set    14+firstp
  44.  
  45. _decode_vplane
  46.     movem.l    a2/d4/d5,-(sp) ; save register for aztec.
  47.     move.l    in(sp),a0
  48.     move.l    out(sp),a2
  49.     move.w    linebytes(sp),d2
  50.     move.w    d2,d4  ; make a copy of linebytes to use as a column counter.
  51.     bra    zdcp  ; branch to the end of the column loop.
  52.  
  53. dcp        ; this loop goes through once for each column
  54.     move.l    a2,a1    ; grab a copy of the out column pointer
  55.     clr.w    d0       ; clear hi-byte of op-count for this column
  56.     move.b    (a0)+,d0 ; and get lo-byte from in data stream
  57.     bra    zdcvclp      ; branch to end of op-loop (cause count = 0 is ok!)
  58. dcvclp    clr.w    d1     ;clear hi byte of op
  59.     move.b    (a0)+,d1 ;grab the lo byte from in data stream    
  60.     bmi    dcvuniq      ;if it's a uniq run (yuck!) have to branch
  61. dcvsame    move.b    (a0)+,d3 ;yea! we get to repeat d3 d1 times!
  62.     move.w    d1,d5 ; so set up a "tower" to do it.  
  63.     asr.w    #3,d5 ; d5 is number of loops through tower
  64.     and.w    #7,d1 ; d1 is where in tower to start.
  65.     add.w    d1,d1 ; 4 bytes/tower element means we add to self twice
  66.     add.w    d1,d1
  67.     neg.w    d1
  68.     jmp    34+same_tower(pc,d1) ;why the 34 isn't 32 = 8(els in tower)*4
  69.                              ;is pure pure voodoo.  It's not just the
  70.                              ;jmp instruction....
  71. same_tower
  72.     move.b    d3,(a1)
  73.     adda.w    d2,a1
  74.     move.b    d3,(a1)
  75.     adda.w    d2,a1
  76.     move.b    d3,(a1)
  77.     adda.w    d2,a1
  78.     move.b    d3,(a1)
  79.     adda.w    d2,a1
  80.     move.b    d3,(a1)
  81.     adda.w    d2,a1
  82.     move.b    d3,(a1)
  83.     adda.w    d2,a1
  84.     move.b    d3,(a1)
  85.     adda.w    d2,a1
  86.     move.b    d3,(a1)
  87.     adda.w    d2,a1
  88.     dbra    d5,same_tower
  89.     dbra    d0,dcvclp ; through with decoding one op, go fetch next op
  90.     bra    z1dcp         ; through with this column even.
  91.  
  92. dcvuniq    and.b    #$7f,d1 ;it's a uniq run, so mask down to get count
  93.     move.w    d1,d5       ; and start setting up another tower....
  94.     asr.w    #3,d5
  95.     and.w    #7,d1
  96.     add.w    d1,d1
  97.     add.w    d1,d1
  98.     neg.w    d1
  99.     jmp    34+uniq_tower(pc,d1)
  100. uniq_tower
  101.     move.b    (a0)+,(a1)
  102.     adda.w    d2,a1
  103.     move.b    (a0)+,(a1)
  104.     adda.w    d2,a1
  105.     move.b    (a0)+,(a1)
  106.     adda.w    d2,a1
  107.     move.b    (a0)+,(a1)
  108.     adda.w    d2,a1
  109.     move.b    (a0)+,(a1)
  110.     adda.w    d2,a1
  111.     move.b    (a0)+,(a1)
  112.     adda.w    d2,a1
  113.     move.b    (a0)+,(a1)
  114.     adda.w    d2,a1
  115.     move.b    (a0)+,(a1)
  116.     adda.w    d2,a1
  117.     dbra    d5,uniq_tower
  118. zdcvclp dbra    d0,dcvclp
  119.  
  120.  
  121. z1dcp    addq.l    #1,a2 ;all through with this column, so put a2 to next one
  122. zdcp    dbra    d4,dcp ; maybe we're all done?
  123.     movem.l    (sp)+,a2/d4/d5
  124.     rts
  125.  
  126.