Mandare una e-mail quando un backup si ├¿ concluso

Di seguito troverete un esempio di uno script .BAT che chiama Abakt e manda una e-mail contenente informazioni utili.
Voi dovrete, probabilmente, modificare un po' lo script perchè funzioni sul vostro sistema.

Lo script usa blat, una utility da linea di comando per inviare e-mail. Scaricate blat.zip ed estraetene i file in "C:\Programmi\blat\".

Esempio:



set BLAT="C:\Programmi\blat\smtp\blat.exe"
set ABAKT="C:\Programmi\Abakt.exe"
set PROFILE=MyProfile
set HOME=C:\Documents and Settings\erik
set LOGFILE="%HOME%\Application Data\Abakt\Log\%PROFILE%.log"
set EMAIL=mioNome@mioProvider.net

@rem == Prepare blat:
%BLAT% -install smtp.mioprovider.net %EMAIL%

@rem == Call Abakt:
%ABAKT% -b -x -l -m "%PROFILE%.abp"

goto result%ERRORLEVEL%
:result0
    @rem OK (0x00)
    %BLAT% %LOGFILE% -s "%PROFILE% Ok" -to %EMAIL%
    @goto end
:result2
    @rem OK+WARNING (0x02)
    %BLAT% %LOGFILE% -s "%PROFILE% Ok + Warnings" -to %EMAIL%
    @goto end
:result1
    @rem ERROR (0x01)
:result3
    @rem ERROR+WARNING (0x03)
    %BLAT% %LOGFILE% -s "%PROFILE% Failed!" -to %EMAIL%
    @goto end

:end