Přidání uživatele do systému

Private Function AddUser(UserName As String, Password As _
String, Optional GroupName = "Domain Users", _
Optional FullName As String) As Boolean

   'PARAMETRY: UserName: Přihlašovací jméno
   ' Password: Heslo
   ' GroupName (Optional): Skupina, do které se uživatel přidá
   ' Defaultní je "Domain Users"
   ' FullName (Optional): Plné jméno uživatele

   'Požadavky: -- Active Directory
   ' -- Odkaz na Active DS Type Library
   ' -- Práva uživatele programu pro přidávání uživatelů

   Dim oContainer As IADsContainer

   Dim oUser As IADsUser
   Dim oGroup As IADsGroup
   Dim oSysInfo As New WinNTSystemInfo

   Dim oRoot As IADs
   Dim oDomain As IADsDomain
   Dim sDomain As String

   On Error GoTo ErrHandler

   sDomain = oSysInfo.DomainName
   Set oContainer = GetObject("WinNT://" & sDomain)
   Set oUser = oContainer.Create("User", UserName)
   
   If FullName <> "" Then oUser.FullName = FullName
   oUser.SetInfo
   oUser.SetPassword Password

   Set oGroup = GetObject("WinNT://" & sDomain & "/" & GroupName)
   oGroup.Add "WinNT://" & sDomain & "/" & UserName
   oGroup.SetInfo

   AddUser = True

ErrHandler:
   Set oContainer = Nothing
   Set oUser = Nothing
   Set oGroup = Nothing

End Function

Příklad volání:
AddUser "Bozena", "12345678", "Administrators", "The Bozena"

Rád bych upozornil na to, že lze samozřejmě tuto funkci rozšířit o další parametry s informacemi o uživateli. Podívejte se na vlastnosti objektů.

Zpět