home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib27b.dsk / TIMEHELLO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  47 lines
  1. 10  REM  ***********************
  2. 20  REM  *     TIMEHELLO       *
  3. 30  REM  *  BY PHILIP CHIEN    *
  4. 40  REM  * COPYRIGHT (C) 1986  *
  5. 50  REM  *  MICROSPARC, INC.   *
  6. 60  REM  * CONCORD, MA  01742  *
  7. 70  REM  ***********************
  8. 80 D$ =  CHR$(4)
  9. 90  REM  PUT YOUR SET UP ARRAYS & INIT ROUTINES HERE
  10. 100  GOSUB 30000: REM  FIND CLOCK & UPDATE LASTBOOT
  11. 110  REM  FIND CLOCK, AND PATCH DOS CATALOG ROUTINE
  12. 120  FOR SL = 7 TO 1  STEP  -1
  13. 130  IF  PEEK( -16384 +SL *256 +7) = 5  AND  PEEK( -16384 +SL *256 +5) = 255  THEN 160
  14. 140  NEXT SL
  15. 150  PRINT "NO CLOCK FOUND.": GOTO 230
  16. 160 HEX$ = "BCDF:20 2F AE A9 BE 20 0B C5 20 08 C5 8E FF BC A2 00 BD 00 02 20 ED FD E8 8A CD FF BC D0 F3 4C 2F AE N ADC6:20 DF BC"
  17. 170 HEX$ = HEX$ +" N F328G"
  18. 180  FOR T = 1 TO  LEN(HEX$)
  19. 190  POKE 511 +T, ASC( MID$ (HEX$,T,1)) +128
  20. 200  NEXT 
  21. 210  POKE 72,0: POKE 223, PEEK(248): CALL  -144
  22. 220  POKE 48358,SL +128: POKE 48361,SL +192
  23. 230  REM  PUT YOUR HELLO PROGRAM HERE
  24. 29999  END 
  25. 30000  FOR SL = 7 TO 1  STEP  -1
  26. 30010  IF  PEEK( -16384 +SL *256 +7) = 5  AND  PEEK( -16384 +SL *256 +5) = 255  THEN 30040
  27. 30020  NEXT SL
  28. 30030  IF SL = 0  THEN  RETURN : REM  NO CLOCK!
  29. 30040  PRINT D$;"PR#";SL
  30. 30050  IF  PEEK( -8192) = 32  THEN  PRINT ">": REM  INTEGER BASIC
  31. 30060  IF  PEEK( -8192) = 76  THEN  PRINT " ": REM  APPLESOFT
  32. 30070  PRINT D$;"IN#";SL
  33. 30080  INPUT A$
  34. 30090  PRINT D$;"PR#0"
  35. 30100  PRINT D$;"IN#0"
  36. 30110  PRINT D$;"OPEN LASTBOOT"
  37. 30120  PRINT D$;"READ LASTBOOT"
  38. 30130  INPUT B$
  39. 30140  PRINT D$;"CLOSE"
  40. 30150  POKE 50,63
  41. 30160  TEXT : CALL  -936: PRINT "   LAST BOOT   -";B$;"        PRESENT TIME -";A$;"       "
  42. 30170  POKE 50,255
  43. 30180  PRINT D$;"OPEN LASTBOOT"
  44. 30190  PRINT D$;"WRITE LASTBOOT"
  45. 30200  PRINT A$
  46. 30210  PRINT D$;"CLOSE"
  47. 30220  RETURN