home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib23a.dsk / JANUARY.1985 / WINDER.bas < prev   
BASIC Source File  |  2023-02-26  |  2KB  |  59 lines
  1. 10  REM  ************************
  2. 20  REM  *       WINDER         *
  3. 30  REM  *    BY MIKE SEEDS     *
  4. 40  REM  *  COPYRIGHT (C) 1985  *
  5. 50  REM  *  BY MICROSPARC, INC  *
  6. 60  REM  *  CONCORD, MA. 01742  *
  7. 70  REM  ************************
  8. 80  DIM WS$(24)
  9. 90  HOME : PRINT : PRINT  TAB( 9)"FOR WHOM THE BELL BONGS"
  10. 100  PRINT : PRINT  TAB( 15)"BY A. MONKEY": PRINT : PRINT 
  11. 110  FOR J = 1 TO 8
  12. 120  FOR K = 1 TO 40: PRINT  CHR$(64 +26 * RND(1));: NEXT K: PRINT 
  13. 130  NEXT J
  14. 140  VTAB 23: PRINT "PRESS ANY KEY TO HALT."
  15. 150 WL = 12:WT = 10:WW = 10:WB = 5: GOSUB 390: REM  OPEN WINDOW
  16. 160  PRINT : PRINT "GOT IT?"
  17. 170  GOSUB 350: REM  DELAY
  18. 180  GOSUB 560: REM  CLOSE WINDOW
  19. 190  IF  PEEK(49152) >128  THEN  TEXT : HOME : END 
  20. 200 WL = 5:WT = 1:WW = 25:WB = 7
  21. 210  GOSUB 390: REM  OPEN WINDOW
  22. 220  VTAB WT +2: HTAB 4: PRINT "NOTICE THE TEXT IS": HTAB 4: PRINT "RESTORED CORRECTLY."
  23. 230  GOSUB 350: REM  DELAY
  24. 240  GOSUB 560: REM  CLOSE WINDOW
  25. 250  IF  PEEK(49152) >128  THEN  TEXT : HOME : END 
  26. 260 WT = 10:WB = 10: GOSUB 390
  27. 270  FOR J = 1 TO 25: PRINT "  ";J,J *J: NEXT J
  28. 280  PRINT : PRINT "SCROLLING IS AUTOMATIC"
  29. 290  GOSUB 350: GOSUB 560
  30. 300  IF  PEEK(49152) >128  THEN  TEXT : HOME : END 
  31. 310  GOTO 150
  32. 320  REM  ==========
  33. 330  REM    DELAY
  34. 340  REM  ==========
  35. 350  FOR J = 1 TO 1500: NEXT : RETURN 
  36. 360  REM  ===================
  37. 370  REM   SUBROUTINE WINDOW
  38. 380  REM  ===================
  39. 390 WA = 1024 +128 *(WT -1 -8 * INT((WT -1)/8)) +40 * INT(WT/8.5)
  40. 400 WS = WA
  41. 410  FOR WJ = WT TO WT +WB -1:WS$(WJ) = ""
  42. 420  FOR WK = 1 TO WW:WS$(WJ) = WS$(WJ) + CHR$( PEEK(WA +WL +WK -1)): NEXT WK
  43. 430  POKE WA +WL,32: POKE WA +WL +WW -1,32
  44. 440 WA = WA +128: IF WA = 2088  THEN WA = 1104
  45. 450  IF WA = 2048  THEN WA = 1064
  46. 460  NEXT WJ
  47. 470  FOR WJ = 1 TO WW: POKE WS +WL +WJ -1,32: POKE WA -128 +984 *(WA = 1064  OR WA = 1104) +WL +WJ -1,32: NEXT WJ
  48. 480  REM  SET TEXT SCREEN
  49. 490  POKE 32,WL +1: POKE 33,WW -2
  50. 500  POKE 34,WT: POKE 35,WT +WB -2
  51. 510  HOME 
  52. 520  RETURN 
  53. 530  REM  ================
  54. 540  REM  SUBROUTINE CLOSE
  55. 550  REM  ================
  56. 560  POKE 32,0: POKE 33,40
  57. 570  POKE 34,0: POKE 35,24
  58. 580  FOR WJ = WT TO WT +WB -1: VTAB WJ: HTAB WL +1: PRINT WS$(WJ): NEXT WJ
  59. 590  RETURN