home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib21b.dsk
/
ANIMATION.1.bas
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
32 lines
10 REM ***********************
20 REM * ANIMATION.1 *
30 REM * BY ROBERT R. DEVINE *
40 REM * COPYRIGHT (C) 1984 *
50 REM * BY MICROSPARC, INC. *
60 REM * LINCOLN, MA. 01773 *
70 REM ***********************
80 PRINT CHR$(4)"BLOAD DHR.DRIVER": CALL 37999: HIMEM: 37507: REM LOAD/SETUP/PROTECT
90 PRINT CHR$(4)"BLOAD SHAPE-D #143": PRINT CHR$(4)"BLOAD SHAPE-U #144"
100 CALL 37953: REM INIT
110 HGR : CALL 37928: REM CLEAR DHR SCREEN
120 POKE 49153,0: POKE 49234,0: REM 80STORE/FULL SCREEN
130 HCOLOR= 3: CALL 37517: GOTO 160: REM HPLOT MODE ON/EOR FUNCTION OFF
140 POKE 49236,0:C = INT(X/7): IF C/2 = INT(C/2) THEN POKE 49237,0: REM FLIP PAGE2
150 XC = INT(C/2) +X/7 -C:XC = INT(XC *7 +.5): RETURN
160 FOR X1 = 3 TO 559 STEP 4:X = X1 -1: GOSUB 140: HPLOT XC,90 TO XC,105:X = X1: GOSUB 140: HPLOT XC,90 TO XC,105: NEXT : REM DRAW HORIZONTAL ORANGE BARRIER
170 POKE 251,143: POKE 252,0: POKE 253,13: POKE 254,2: POKE 255,0: REM STARTING SHNUM/VT/VB/HR/HL
180 REM *** GOING DOWN ***
190 FOR VB = 13 TO 88: CALL 37708: CALL 37577: NEXT VB: REM DRAWDN/GODOWN TO BARRIER
200 FOR VT = 76 TO 89: POKE 252,VT: CALL 37708: NEXT VT: REM MOVE SHIP BEHIND BARRIER
210 POKE 251,144: REM CHANGE TO NORMAL 'DRAW' SHAPE
220 POKE 252,106: FOR VB = 106 TO 119: POKE 253,VB: CALL 37780: NEXT VB: REM BRING SHIP FROM BEHIND BARRIER
230 FOR VB = 119 TO 191: CALL 37780: CALL 37577: NEXT VB: REM DRAW/GODOWN TO BOTTOM OF SCREEN
240 REM *** GOING UP ***
250 FOR VT = 178 TO 107 STEP -1: CALL 37780: CALL 37568: NEXT VT: REM DRAW/GOUP TO BARRIER
260 FOR VB = 119 TO 106 STEP -1: POKE 253,VB: CALL 37780: NEXT VB: REM MOVE SHIP BEHIND BARRIER
270 POKE 251,143: REM CHANGE TO 'DRAWDN' SHAPE
280 POKE 253,89: FOR VT = 89 TO 76 STEP -1: POKE 252,VT: CALL 37708: NEXT VT: REM BRING SHIP FROM BEHIND BARRIER
290 FOR VT = 88 TO 0 STEP -1: CALL 37708: CALL 37568: NEXT VT: REM DRAWDN/GOUP TO TOP OF SCREEN
300 CALL 37507: CALL 37708: CALL 37517: REM EORON/ERASE/EOROFF
310 CALL 37548: REM MOVERIGHT
320 GOTO 190: REM START DOWN AGAIN