home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib19b.dsk / MAIN.VERSION.2.bas < prev    next >
BASIC Source File  |  2023-02-26  |  1KB  |  37 lines
  1. 10  REM  ---MAIN PROGRAM
  2. 20  PRINT  CHR$(4);"BLOAD OVLY.OBJ": CALL 37088
  3. 30  DIM D%(100)
  4. 40  HOME : PRINT "** COPYRIGHT 1984 BY MICROSPARC, INC. **": PRINT : PRINT "OVERLAYS WILL OVERWRITE": PRINT "LINES 300-399": PRINT 
  5. 50  GOSUB 200
  6. 60  PRINT "READING DATA.."
  7. 70  GOSUB 300: REM  GOSUB THE READ ROUTINE
  8. 80  PRINT "OVERLAYING SORT.."
  9. 90  & OVERLAY,300 -399,"SORT"
  10. 100  GOSUB 200
  11. 110  PRINT "SORTING DATA.."
  12. 120  GOSUB 300: REM  GOSUB THE SORT ROUTINE
  13. 130  PRINT "OVERLAYING OUTPUT.."
  14. 140  & OVERLAY,300 -399,"OUTPUT"
  15. 150  GOSUB 200
  16. 160  PRINT "PRINTING DATA.."
  17. 170  GOSUB 300: REM  GOSUB THE OUTPUT ROUTINE
  18. 180  PRINT "NO ERRORS. NORMAL TERMINATION."
  19. 190  END 
  20. 200  REM  ---THIS ROUTINE TO OPTIONALLY
  21. 210  REM  ---LIST LINES 300-399
  22. 220  PRINT "<RETURN> TO CONTINUE OR"
  23. 230  PRINT "TYPE 'L' TO LIST LINES 300-399"
  24. 240  GET A$: IF A$ = "L"  THEN  LIST 300 -399: GOTO 260
  25. 250  IF A$ =  CHR$(13)  THEN  PRINT : RETURN 
  26. 260  PRINT : GOTO 220
  27. 300  REM  ---READ DATA INTO D%()
  28. 310 N = 0: RESTORE 
  29. 320  READ T
  30. 330  IF T <0  THEN  RETURN 
  31. 340 N = N +1
  32. 350 D%(N) = T
  33. 360  GOTO 320
  34. 500  REM  ---DATA TO SORT
  35. 510  DATA  11,2345,45,234,6,68,556,56,75,345
  36. 520  DATA  234,233,3978,7768,678,79,6,56,7
  37. 530  DATA  -1